P_MNGJRNLENTRYENTRYVIEWAMOUNT

CDS View

Journal Entry Entry View Amount

P_MNGJRNLENTRYENTRYVIEWAMOUNT is a CDS View in S/4HANA. Journal Entry Entry View Amount. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_MngJrnlEntryEntryViewAmount view_entity from COMPOSITE Journal Entry 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Journal Entry'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #MIXED
}

@VDM: {
  viewType: #COMPOSITE,
  private: true
}

define view entity P_MngJrnlEntryEntryViewAmount
  as select from R_ManageJournalEntryItem
  
{
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  
  AccountingDocumentCategory,
  AccountingDocumentType,
  
  CompanyCodeCurrency,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  sum(CreditAmountInCoCodeCrcy) as CreditAmountInCoCodeCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  sum(DebitAmountInCoCodeCrcy) as DebitAmountInCoCodeCrcy,
    
  TransactionCurrency,
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  sum(CreditAmountInTransCrcy) as CreditAmountInTransCrcy,
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  sum(DebitAmountInTransCrcy) as DebitAmountInTransCrcy,
    
  FunctionalCurrency,
  @Semantics.amount.currencyCode: 'FunctionalCurrency'
  sum(CreditAmountInFunctionalCrcy) as CreditAmountInFunctionalCrcy,
  @Semantics.amount.currencyCode: 'FunctionalCurrency'
  sum(DebitAmountInFunctionalCrcy) as DebitAmountInFunctionalCrcy  
  
}
group by
  CompanyCode, 
  FiscalYear, 
  AccountingDocument,
  
  AccountingDocumentCategory,
  AccountingDocumentType,
  
  CompanyCodeCurrency, 
  TransactionCurrency,
  FunctionalCurrency

Learn More