P_MAINTENANCESINGLECYCLE

CDS View

Maintenance Single Cycle Private View

P_MAINTENANCESINGLECYCLE is a CDS View in S/4HANA. Maintenance Single Cycle Private View. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_MaintenanceSingleCycleTP view from TRANSACTIONAL Maintenance Single Cycle (Transactional Processing)
P_MaintPlanLastMsmtDoc view from COMPOSITE Last Measurement Doc. of Single Cycle/Strategy Maint. Plans 
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view entity P_MaintenanceSingleCycle
  as select from I_MaintenanceCycle
  association [1..1] to I_MaintenancePlan as _MaintenancePlan on _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan
{
  key MaintenancePlan,

      NumberOfControlTableEntities,

      ComparisonOperator,

      cast ( unit_conversion(
        quantity => MaintPlanCycleIntervalCount,
        source_unit => I_MaintenanceCycle._UnitOfMeasure._Dimension.UnitOFMeasureSiUnit,
        target_unit => MaintenanceTaskPerformanceUnit,
        error_handling=> 'KEEP_UNCONVERTED'
      ) as abap.dec(22,0) ) as MaintPlanCycleIntervalCount,

      MaintenanceTaskPerformanceUnit,

      MaintPlanCycleDesc,

      Language,

      cast ( unit_conversion(
        quantity => MaintPlanCycleStartOffsetValue,
        source_unit => I_MaintenanceCycle._UnitOfMeasure._Dimension.UnitOFMeasureSiUnit,
        target_unit => MaintenanceTaskPerformanceUnit,
        error_handling=> 'KEEP_UNCONVERTED'
      ) as abap.dec(22,0) ) as MaintPlanCycleStartOffsetValue,

      MeasuringPoint,

      MaintCycleNextPlndCntrRdng,

      EventSchedulingIsInactive,

      CycleSetSequence,

      CycleSetSequenceRepeatFactor,

      /* Associations - locally defined */
      _MaintenancePlan,

      /* Associations - inherited */
      _Language,
      _MeasuringPoint,
      _UnitOfMeasure
}
where
  _MaintenancePlan.MaintPlanSchedgIndicator <> '4'

Learn More