P_ML_COCODE_LEDGER_BCF

CDS View

BCF per Ledger/CoCode for Balance Summary

P_ML_COCODE_LEDGER_BCF is a CDS View in S/4HANA. BCF per Ledger/CoCode for Balance Summary. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_ML_Balance_Bcf view_entity inner COMPOSITE Balance Summary for ML 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM: {
  viewType: #COMPOSITE,
  private:true }

define view entity P_ML_CoCode_Ledger_BCF 
   with parameters
    P_CalendarDate : calendardate
  as select from            I_LedgerCompanyCodeCrcyRoles as f
   

    left outer to one join  I_Distinct_Postingdate       as dp      on  dp.FiscalYearVariant = f.FiscalYearVariant
                                                                    and dp.CalendarDate      = $parameters.P_CalendarDate
                                                                    and dp.IsSpecialPeriod = ' '

    left outer to one join  I_LastBalanceCarryForward    as bcf     on  bcf.CompanyCode = f.CompanyCode
                                                                    and bcf.Ledger      = f.Ledger

{
  key f.CompanyCode,
  key f.Ledger,
      f.FiscalYearVariant,

      case
        when bcf.BalanceCarryforwardToYear is null
          then '0000'
        when dp.FiscalYear is null
          then bcf.BalanceCarryforwardToYear
        when bcf.BalanceCarryforwardToYear > dp.FiscalYear
          then dp.FiscalYear
        else bcf.BalanceCarryforwardToYear
      end                  as FromFiscalYear
}

Learn More