P_IRM_REFINT_DATE_CYCLE

CDS View

Calculate calendar frequency view

P_IRM_REFINT_DATE_CYCLE is a CDS View in S/4HANA. Calculate calendar frequency view. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_IRM_REFINT_HIST_KEYDATE view from COMPOSITE Calculate term date view 
@AbapCatalog.sqlViewName: 'PIRDATECYCLE'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #B
@VDM.private:true
define view P_IRM_REFINT_DATE_CYCLE 
    with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_EndDate                 : vdm_v_end_date,
    P_CrdtLineReportingFrequency : ftr_date_granularity
  as select from P_ASGN_FIRST_DATE_TERM(P_EndDate: $parameters.P_EndDate, P_CrdtLineReportingFrequency: $parameters.P_CrdtLineReportingFrequency) as CalendarDate
{
  CalendarDate.KeyDate,
  CalendarDate.CreditLineReportingPeriod,
  CalendarDate.CON_DAY,
  left(CalendarDate.CON_WEEK_START,1) as CON_WEEK,
  left(CalendarDate.CON_MONTH_START, 1) as CON_MONTH,
  left(CalendarDate.CON_QUARTER_START, 1) as CON_QUARTER,
  left(CalendarDate.CON_YEAR_START, 1) as CON_YEAR
}
where
     CalendarDate.CON_DAY           = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_WEEK_START    = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_MONTH_START   = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_QUARTER_START = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_YEAR_START    = $parameters.P_CrdtLineReportingFrequency

union all

 select distinct from P_ASGN_LAST_DATE_TERM(P_EndDate: $parameters.P_EndDate, P_CrdtLineReportingFrequency: $parameters.P_CrdtLineReportingFrequency) as CalendarDate
{
  CalendarDate.KeyDate,
  CalendarDate.CreditLineReportingPeriod,
  CalendarDate.CON_DAY,
  left(CalendarDate.CON_WEEK_START,1) as CON_WEEK,
  left(CalendarDate.CON_MONTH_START, 1) as CON_MONTH,
  left(CalendarDate.CON_QUARTER_START, 1) as CON_QUARTER,
  left(CalendarDate.CON_YEAR_START, 1) as CON_YEAR
}
where
     CalendarDate.CON_WEEK_END    = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_MONTH_END   = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_QUARTER_END = $parameters.P_CrdtLineReportingFrequency
  or CalendarDate.CON_YEAR_END    = $parameters.P_CrdtLineReportingFrequency

Learn More