P_EBORDERWIPCOST1

CDS View

Event-Based Order WIP Cost layer 1

P_EBORDERWIPCOST1 is a CDS View in S/4HANA. Event-Based Order WIP Cost layer 1. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_EBOrderWIPCost2 view from COMPOSITE Event-Based Order WIP Cost layer 2 
@AbapCatalog.sqlViewName: 'PEBORDWIPCST1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_EBOrderWIPCost1
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod

  as select from I_JournalEntryItem
{
  key CompanyCode,
  key OrderID,
  key OrderItem,
  key SubLedgerAcctLineItemType,

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCrcy,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8
}
where
  (
       SubLedgerAcctLineItemType   = '09100'
    or SubLedgerAcctLineItemType   = '09110'
  )
  and  BusinessTransactionCategory = 'EBWP'
  and  FiscalYearPeriod            >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod            <= $parameters.P_ToFiscalYearPeriod
  and  Ledger                      = :P_Ledger
group by
  CompanyCode,
  OrderID,
  OrderItem,
  SubLedgerAcctLineItemType

Learn More