P_EBORDERPLANCOST1

CDS View

Event-Based Order Plan Cost layer 1

P_EBORDERPLANCOST1 is a CDS View in S/4HANA. Event-Based Order Plan Cost layer 1. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_EBOrderPlanCost2 view from COMPOSITE Event-Based Order Plan Cost layer 2 
@AbapCatalog.sqlViewName: 'PEBORDPLNCST1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_EBOrderPlanCost1
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod

  as select from I_FinancialPlanningEntryItem
{
  key CompanyCode,
  key OrderID,
  key cast(
        case AccountAssignmentType
          when 'OR' then '0000'
          else OrderItem
        end
      as co_posnr )                     as OrderItem,

      PlanningCategory,

      IsLotSizeIndependent,
 
      ControllingDebitCreditCode,

      // Plan and Standard Amounts from ACDOCP

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCrcy,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8,
      sum(ValuationQuantity) as TotalQuantity
}
where
  (
       AccountAssignmentType =  'OR'
    or AccountAssignmentType =  'OP'
  )
  and  FiscalYearPeriod      >= :P_FromFiscalYearPeriod
  and  FiscalYearPeriod      <= :P_ToFiscalYearPeriod
  and  Ledger                =  :P_Ledger
group by
  CompanyCode,
  OrderID,
  OrderItem,
  AccountAssignmentType,
  PlanningCategory,
  IsLotSizeIndependent,
  ControllingDebitCreditCode

Learn More