P_COLLMGMTRBLSITMFORKEYDTE2

CDS View

Collection Management Receivables items for key date

P_COLLMGMTRBLSITMFORKEYDTE2 is a CDS View in S/4HANA. Collection Management Receivables items for key date. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_CollMgmtRblsItmForKeyDte3 view from COMPOSITE Collection Management Receivables items for key date 
@AbapCatalog.sqlViewName: 'PCMRBLSKDATDUE2'
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private:true

define view P_CollMgmtRblsItmForKeyDte2
  with parameters
    P_KeyDate          : sydate
    
  as select from P_CollMgmtRblsItmForKeyDte1( P_KeyDate: :P_KeyDate) as _CollectionsPartner   

  // Absent Coll Spec in customizing

  association [0..1] to I_CollsSpecialistSubstitute as _UdmSplAbs    on  _UdmSplAbs.CollectionGroup           = _CollectionsPartner.CollectionGroup
                                                                       and _UdmSplAbs.CollectionSpecialist      = _CollectionsPartner.CollectionSpecialist
                                                                       and _UdmSplAbs.CollSpecialistAbsenceFrom <= $parameters.P_KeyDate
                                                                       and _UdmSplAbs.CollSpecialistAbsenceTo   >= $parameters.P_KeyDate
  // Absent Coll Spec in BP

  association [0..1] to I_BPCollectionsSgmtTmpAssgmt as _UdmBPSplAbs on  _UdmBPSplAbs.BusinessPartner              = _CollectionsPartner.BusinessPartner
                                                                       and _UdmBPSplAbs.CollectionSegment            = _CollectionsPartner.CollectionSegment
                                                                       and _UdmBPSplAbs.TmpBPCollSgmtAssgmtValidFrom <= $parameters.P_KeyDate
                                                                       and _UdmBPSplAbs.TmpBPCollSgmtAssgmtValidTo   >= $parameters.P_KeyDate




{
  key _CollectionsPartner.CompanyCode,
  key _CollectionsPartner.CollectionSegment,
  key _CollectionsPartner.BusinessPartner,      
      _CollectionsPartner.CollectionProfile,  
      
      case // determine Coll Group

        when _UdmBPSplAbs.CollectionSpecialist <> '' and _UdmBPSplAbs.CollectionSpecialist <> ' ' and _UdmBPSplAbs.CollectionSpecialist is not null then _UdmBPSplAbs.CollectionGroup
        else _CollectionsPartner.CollectionGroup
       end as CollectionGroup,
       
        case // determine Coll Spec

        when _UdmBPSplAbs.CollectionSpecialist <> '' and _UdmBPSplAbs.CollectionSpecialist <> ' ' and _UdmBPSplAbs.CollectionSpecialist is not null then _UdmBPSplAbs.CollectionSpecialist
        when _UdmSplAbs.CollectionSpecialist <> '' and _UdmSplAbs.CollectionSpecialist <> ' ' and _UdmSplAbs.CollectionSpecialist is not null then _UdmSplAbs.CollectionSpecialistSubstitute
        else _CollectionsPartner.CollectionSpecialist
       end as CollectionSpecialist
}

Learn More