P_COMFGORDEROUTPUTQUANTITIES

CDS View

Output Quantities for Manufacturing Orders Target Costs

P_COMFGORDEROUTPUTQUANTITIES is a CDS View in S/4HANA. Output Quantities for Manufacturing Orders Target Costs. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
P_COMFGOrderTargetCube view inner COMPOSITE Target Costs Cube for Manufacturing Orders
P_PCCTgtCstForMTOOnPlanCost view inner CONSUMPTION Target cost for MTO order based on order plan cost 
@AbapCatalog.sqlViewName: 'PFIMFGOROUTQTY'
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Output Quantities for Manufacturing Orders Target Costs'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true

// Quantities defined in this view is only for calculating target costs

define view P_COMFGOrderOutputQuantities
  with parameters
    P_FromFiscalYearPeriod  : fis_jahrper,
    P_ToFiscalYearPeriod    : fis_jahrper
  as select from I_COActivityTypeTotalsByPeriod
{
  key ControllingObject,
  
      OrderID,
      
      OrderItem,
  
      @Semantics.unitOfMeasure:true
      CostCtrActivityTypeQtyUnit,

      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostCtrActivityTypeQtyUnit'} }
      sum(case when ControllingValueType = '01'
                then CostCtrActivityTypeQty
               else 0 end ) as PlanOutputQuantity,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostCtrActivityTypeQtyUnit'} }
      sum(case when ControllingValueType = '04'
                then CostCtrActivityTypeQty
               else 0 end)  as ActualOutputQuantity

}
where
(
  (
        ControllingValueType =  '04'
    and FiscalYear >= substring($parameters.P_FromFiscalYearPeriod, 1 ,4)
    and FiscalYear <= substring($parameters.P_ToFiscalYearPeriod, 1 ,4)
    and FiscalYearPeriod     >= $parameters.P_FromFiscalYearPeriod
    and FiscalYearPeriod     <= $parameters.P_ToFiscalYearPeriod
  )
  or(
        ControllingValueType =  '01'
  )
 )
  and   OrderID              <> ''
group by
  ControllingObject,
  OrderID,
  OrderItem,
  CostCtrActivityTypeQtyUnit

Learn More