P_AUDIT_AT_ASTTRANSTOKEYFIGS

CDS View

Austrian Audit Asset Transaction to Key Figures

P_AUDIT_AT_ASTTRANSTOKEYFIGS is a CDS View in S/4HANA. Austrian Audit Asset Transaction to Key Figures. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_AUDIT_AT_AssetTransaction view from COMPOSITE Austrian Audit Asset Transaction 
@AbapCatalog.sqlViewName: 'PAUDITATATTOKF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

// expand AmountInDisplayCurrency to columns by key figures

define view P_AUDIT_AT_AstTransToKeyFigs
  with parameters
    P_AssetAccountingKeyFigureSet : faa_key_figure_set,
    P_FiscalYear                  : fis_gjahr,
    P_FiscalPeriod                : fis_poper,
    P_KeyDate                     : fagl_keydate

  as select from P_AUDIT_AT_AstTransByKeyFigs( P_AssetAccountingKeyFigureSet: :P_AssetAccountingKeyFigureSet,  P_FiscalYear: :P_FiscalYear , P_FiscalPeriod: :P_FiscalPeriod, P_KeyDate: :P_KeyDate )
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_DepreciationArea'
  key AssetDepreciationArea,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
  key FixedAsset,
      @ObjectModel.foreignKey.association: '_Ledger'
  key Ledger,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key FiscalYear,
      @ObjectModel.foreignKey.association: '_AssetKeyFigureSet'
  key AssetAccountingKeyFigureSet,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key AccountingDocument,
      @ObjectModel.foreignKey.association: '_CurrencyRole'
  key CurrencyRole,

      // Content from I_FixedAssetLineItem

      PostingDate                                                                                    as PostingDate,
      max(AssetValueDate)                                                                            as AssetValueDate,
      DocumentItemText                                                                               as DocumentItemText,
      ReferenceDocument                                                                              as ReferenceDocument,
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      Quantity                                                                                       as Quantity,
      
      @Consumption.hidden: true
      AssetAuthorizationContext, //Needed for DCL

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      BaseUnit                                                                                       as BaseUnit,
      @ObjectModel.foreignKey.association: '_AssetClass'
      AssetClass,
      @ObjectModel.foreignKey.association: '_AssetAccountDetermination'
      AssetAccountDetermination,

      // for _AcqnProdnCostGLAccount

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_AcqnProdnCostGLAccount'
      AcqnProdnCostGLAccount,

      @ObjectModel.foreignKey.association: '_SelectedCurrencyBranch'
      @Environment.sql.passValue : true
      SelectedCurrencyBranch, // parameter in top view

      @Semantics.currencyCode:true
      DisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000001' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency1,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000002' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency2,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000003' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency3,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000004' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency4,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000005' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency5,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000006' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency6,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000007' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency7,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000008' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency8,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000009' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency9,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000010' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency10,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000011' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency11,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000012' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency12,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000013' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency13,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000014' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency14,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000015' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency15,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000016' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency16,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000017' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency17,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000018' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency18,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000019' then AmountInDisplayCurrency else 0 end )  as AmountInDisplayCurrency19,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000020' then AmountInDisplayCurrency else 0  end ) as AmountInDisplayCurrency20,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000021' then AmountInDisplayCurrency else 0  end ) as AmountInDisplayCurrency21,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000022' then AmountInDisplayCurrency else 0  end ) as AmountInDisplayCurrency22,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum( case AssetAcctgKeyFigureSortSqnc when '000023' then AmountInDisplayCurrency else 0  end ) as AmountInDisplayCurrency23,

      /*Associations */
      _CompanyCode,
      _DepreciationArea,
      _MasterFixedAsset,
      _FixedAsset,
      _Ledger,
      _FiscalYear,
      _AssetKeyFigureSet,
      _JournalEntry,
      _CurrencyRole,
      _AssetClass,
      _AssetAccountDetermination,
      _ChartOfAccounts,
      _AcqnProdnCostGLAccount,
      _SelectedCurrencyBranch,
      _UnitOfMeasure
}
group by
  CompanyCode,
  AssetDepreciationArea,
  MasterFixedAsset,
  FixedAsset,
  Ledger,
  FiscalYear,
  AssetAccountingKeyFigureSet,
  AccountingDocument,
  CurrencyRole,
  PostingDate,
  DocumentItemText,
  ReferenceDocument,
  Quantity,
  AssetAuthorizationContext,
  BaseUnit,
  AssetClass,
  AssetAccountDetermination,
  ChartOfAccounts,
  AcqnProdnCostGLAccount,
  SelectedCurrencyBranch,
  DisplayCurrency

Learn More