I_WBSELEMENTHIERARCHYDATA

CDS View

WBS Element Hierarchy

I_WBSELEMENTHIERARCHYDATA is a CDS View in S/4HANA. WBS Element Hierarchy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_ProjectObject_2 view union_all COMPOSITE Project Object 
@AbapCatalog.sqlViewName: 'IWBSELMNTHIER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'WBS Element Hierarchy'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #A,
    sizeCategory: #XL,
    dataClass: #MASTER
}

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_WBSElementHierarchyData
  as select from v_prhi
  association [1..1] to I_WBSElementData_2 as _WBSElement       on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [1..1] to I_ProjectData_2    as _Project          on $projection.ProjectInternalID = _Project.ProjectInternalID
  association [1..1] to I_WBSElementData_2 as _WBSElementParent on $projection.WBSElementParentInternalID = _WBSElementParent.WBSElementInternalID
{
  key cast ( posnr as ps_s4_pspnr preserving type )      as WBSElementInternalID,
      cast ( psphi as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
      cast ( wbs_up as ps_posnr1 preserving type )       as WBSElementParentInternalID,
      cast ( wbs_down as ps_posnr1 preserving type )     as WBSElementChildInternalID,
      cast ( wbs_left as ps_posnr1 preserving type )     as LeftSiblingWBSElmntInternalID,
      cast ( wbs_right as ps_posnr1 preserving type )    as RightSiblingWBSElmntInternalID,
      _WBSElement,
      _Project,
      _WBSElementParent
}

Learn More