I_VARCONFIGNPRODINSTANCEVALUE2
variant config product instance value
I_VARCONFIGNPRODINSTANCEVALUE2 is a CDS View in S/4HANA. variant config product instance value. It contains 9 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_BusSolnOrdItmConfiguration | view_entity | from | COMPOSITE | Solution Order Item Configuration |
| I_SrvcTransMstrAgrmtItmConfign | view_entity | from | COMPOSITE | Master Agreement Item Variant Config |
| I_SubscrpnOrdItemConfign | view_entity | from | COMPOSITE | Item Variant Config |
| R_BusSolnOrdItmConfigurationTP | view_entity | from | TRANSACTIONAL | Solution Order Item Configuration - TP |
Fields (9)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CharcFromNumericValue | CharcFromNumericValue | 1 |
| KEY | CharcInternalID | CharcInternalID | 1 |
| KEY | CharcToNumericValue | CharcToNumericValue | 1 |
| KEY | CharcValue | CharcValue | 1 |
| KEY | VarConfignInstceBusObjectKey | VarConfignInstceBusObjectKey | 1 |
| KEY | VarConfignInstceBusObjectType | VarConfignInstceBusObjectType | 1 |
| KEY | VariantConfigurationInstance | VariantConfigurationInstance | 1 |
| Characteristic | Characteristic | 1 | |
| VariantConfigurationDate | VariantConfigurationDate | 1 |
@AbapCatalog.sqlViewName: 'IVARCNPRODINSTV2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'variant config product instance value'
@Metadata.ignorePropagatedAnnotations: true
//@ObjectModel.supportedCapabilities: [ ]
define view I_VarConfignProdInstanceValue2
as select from P_VARCONFIGNPRODINSTCEVALUE_2 as ConfValue
// Technically, the cardinality is [0..*], but we know that the data should lead to up to one entry
association [0..1] to I_ClfnCharacteristic as _Characteristic on ConfValue.CharcInternalID = _Characteristic.CharcInternalID
and ConfValue.VariantConfigurationDate >= _Characteristic.ValidityStartDate
and ConfValue.VariantConfigurationDate < _Characteristic.ValidityEndDate
and _Characteristic.IsDeleted = ''
// Technically, the cardinality is [0..*], but we know that the data should lead to up to one entry
association [0..1] to I_ClfnCharcValue as _CharacteristicValue on _CharacteristicValue.CharcInternalID = ConfValue.CharcInternalID
and _CharacteristicValue.CharcValue = ConfValue.CharcValue
and _CharacteristicValue.CharcFromNumericValue = ConfValue.CharcFromNumericValue
and _CharacteristicValue.CharcToNumericValue = ConfValue.CharcToNumericValue
and _CharacteristicValue.CharcValueIntervalType = ConfValue.CharcValueIntervalType
and ConfValue.VariantConfigurationDate >= _CharacteristicValue.ValidityStartDate
and ConfValue.VariantConfigurationDate < _CharacteristicValue.ValidityEndDate
and _CharacteristicValue.IsDeleted = ''
// Technically, the cardinality is [0..*], but we know that the data should lead to up to one entry
association [0..1] to I_ClfnCharcDesc as _CharacteristicDesc on ConfValue.CharcInternalID = _CharacteristicDesc.CharcInternalID
and ConfValue.VariantConfigurationDate >= _CharacteristicDesc.ValidityStartDate
and ConfValue.VariantConfigurationDate < _CharacteristicDesc.ValidityEndDate
and _CharacteristicDesc.IsDeleted = ''
and _CharacteristicDesc.Language = $session.system_language
// Technically, the cardinality is [0..*], but we know that the data should lead to up to one entry
association [0..1] to I_ClfnCharcValueDesc as _CharacteristicValueDesc on _CharacteristicValueDesc.CharcInternalID = ConfValue.CharcInternalID
and _CharacteristicValueDesc.CharcValuePositionNumber = $projection.charcvaluepositionnumber
and _CharacteristicValueDesc.ValidityStartDate <= ConfValue.VariantConfigurationDate
and _CharacteristicValueDesc.ValidityEndDate > ConfValue.VariantConfigurationDate
and _CharacteristicValueDesc.IsDeleted = ''
and _CharacteristicValueDesc.Language = $session.system_language
{
key VarConfignInstceBusObjectKey, // IBINOBS-objkey OR IBINOWN-objkey
key VarConfignInstceBusObjectType, // ( T371D-objtyp ) derived from ( IBINOWN-inttyp OR IBINOBS-inttyp )
key VariantConfigurationInstance, // IBIN-instance
key ConfValue.CharcInternalID, // IBSYMBOL-atinn
key ConfValue.VariantConfigurationValueID, // IBINVALUES-in_segmcnt
ConfValue.CharcValue, // IBSYMBOL-atwrt
ConfValue.CharcFromNumericValue, // IBSYMBOL-atflv
ConfValue.CharcToNumericValue, // IBSYMBOL-atflb
ConfValue.CharcValueIntervalType, // IBSYMBOL-atcod
VariantConfignInstanceProduct, // IBIN-objnr
_Characteristic.Characteristic, // CABN-atnam
ConfValue.VarConfignValueAssignmentType, // IBINVALUES-ataut mapped to vch_hl_assignment_type
ConfValue.CharcFromNumericValueUnit, // IBINVALUES-msehi_low
ConfValue.CharcToNumericValueUnit, // IBINVALUES-msehi_high
ConfValue.CharcFromDate, // IBINVALUES-DATE_FROM
ConfValue.CharcToDate, // IBINVALUES-DATE_TO
ConfValue.CharcFromTime, // IBINVALUES-TIME_FROM
ConfValue.CharcToTime, // IBINVALUES-TIME_TO
@Semantics.amount.currencyCode: 'CharacteristicCurrency'
ConfValue.CharcFromAmount, // IBINVALUES-CURR_VALUE_FROM
@Semantics.amount.currencyCode: 'CharacteristicCurrency'
ConfValue.CharcToAmount, // IBINVALUES-CURR_VALUE_TO
ConfValue.CharacteristicCurrency, // IBINVALUES-CURRENCY
ConfValue.CharcFromDecimalValue, // IBINVALUES-DEC_VALUE_FROM
ConfValue.CharcToDecimalValue, // IBINVALUES-DEC_VALUE_TO
VariantConfigurationDate, // IBIN-datuv
VarConfigurationParentInstance, // IBST-parent
VarConfigurationRootInstance, // IBST-root
BusObjIsVarConfignOwner, // Flag if the business object is the owner of the configuration
_CharacteristicValue.CharcValuePositionNumber, // must be in entity list for technical reasons caused by association keys
// BOM Item
ConfValue.BillOfMaterialCategory,
ConfValue.BillOfMaterial,
ConfValue.InheritedNodeNumberForBOMItem,
ConfValue.BillOfMaterialItemCategory,
ConfValue.BillOfMaterialItemNumber,
/* Associations */
_Characteristic,
_CharacteristicDesc,
_CharacteristicValue,
_CharacteristicValueDesc,
ConfValue._BOMItem
}