I_TEMPGLACCOUNTLINEITEM

@EndUserText.label: 'i cds view for acdoctemp'
@AbapCatalog.sqlViewName: 'ITEMPGLACCTLIT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC

@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@ObjectModel: {
                usageType.serviceQuality: #X,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED }
define view I_TempGLAccountLineItem
  as select from acdoctemp
  association [0..1] to I_Currency as _BalanceTransactionCurrency on $projection.BalanceTransactionCurrency = _BalanceTransactionCurrency.Currency
  association [0..1] to I_Currency as _TransactionCurrency        on $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [1..1] to I_Currency as _CompanyCodeCurrency        on $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency

  association [0..1] to I_Currency as _GlobalCurrency             on $projection.GlobalCurrency = _GlobalCurrency.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency1       on $projection.FreeDefinedCurrency1 = _FreeDefinedCurrency1.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency2       on $projection.FreeDefinedCurrency2 = _FreeDefinedCurrency2.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency3       on $projection.FreeDefinedCurrency3 = _FreeDefinedCurrency3.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency4       on $projection.FreeDefinedCurrency4 = _FreeDefinedCurrency4.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency5       on $projection.FreeDefinedCurrency5 = _FreeDefinedCurrency5.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency6       on $projection.FreeDefinedCurrency6 = _FreeDefinedCurrency6.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency7       on $projection.FreeDefinedCurrency7 = _FreeDefinedCurrency7.Currency
  association [0..1] to I_Currency as _FreeDefinedCurrency8       on $projection.FreeDefinedCurrency8 = _FreeDefinedCurrency8.Currency

{
  key cast(acdoctemp.rldnr       as fins_ledger preserving type) as Ledger,
  key cast(acdoctemp.rbukrs      as fis_bukrs preserving type)   as CompanyCode,
  key cast(acdoctemp.gjahr       as fis_gjahr preserving type)   as FiscalYear,
  key cast(acdoctemp.belnr       as fis_belnr preserving type)   as AccountingDocument,
  key cast(acdoctemp.docln       as fis_docln preserving type)   as LedgerGLLineItem,
  key closing_run_id                                             as JrnlPeriodEndClosingRunLogUUID,
  key temp_appl                                                  as TemporaryDataCreatingAppl,
  key temp_id                                                    as TemporaryJournalEntry,

      cast(racct as fis_racct preserving type)                   as GLAccount,
      cast(gkont as fis_gkont preserving type)                   as OffsettingAccount,
      valobjtype                                                 as FinancialValuationObjectType,
      valobj_id                                                  as FinancialValuationObject,
      valsobj_id                                                 as FinancialValuationSubobject,
      cast(netdt as faedt_fpos preserving type)                  as NetDueDate,
      slalittype                                                 as SubLedgerAcctLineItemType,
      cast(ktopl as fis_ktopl preserving type)                   as ChartOfAccounts,
      cast(budat as fis_budat preserving type)                   as PostingDate,
      cast(bstat as fis_bstat preserving type)                   as AccountingDocumentCategory,
      cast(xopvw as fis_xopvw preserving type)                   as IsOpenItemManaged,
      cast(augdt as fis_augdt preserving type)                   as ClearingDate,
      cast(augbl as fis_augbl preserving type)                   as ClearingAccountingDocument,
      cast(auggj as fis_auggj preserving type )                  as ClearingDocFiscalYear,
      cast(poper as fins_fiscalperiod preserving type)           as FiscalPeriod,

      prec_awtyp                                                 as PredecessorReferenceDocType,
      prec_aworg                                                 as PredecessorReferenceDocCntxt,
      prec_awref                                                 as PredecessorReferenceDocument,
      prec_awitem                                                as PredecessorReferenceDocItem,
      cast( prec_bukrs as fins_prec_bukrs_gfc preserving type )  as PrdcssrJournalEntryCompanyCode,
      cast( prec_gjahr as fins_prec_gjahr_gfc preserving type )  as PrdcssrJournalEntryFiscalYear,
      cast( prec_belnr as fins_prec_belnr_gfc preserving type )  as PredecessorJournalEntry,
      cast( prec_docln as fins_prec_docln_gfc preserving type )  as PredecessorJournalEntryItem,

      cast(rebzz as fis_rebzz preserving type)                   as InvoiceItemReference,
      cast(rebzg as fis_rebzg preserving type)                   as InvoiceReference,
      cast(rebzj as fis_rebzj preserving type)                   as InvoiceReferenceFiscalYear,
      cast(rebzt as farp_rebzt preserving type)                  as FollowOnDocumentType,
      cast(buzei as fis_buzei preserving type)                   as AccountingDocumentItem,

      @ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
      @Semantics.currencyCode:true
      cast(rtcur as fis_rtcur preserving type)                   as BalanceTransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      cast(tsl as fis_tsl preserving type)                       as AmountInBalanceTransacCrcy,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      cast(rwcur as fis_rwcur preserving type)                   as TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      cast(wsl as fis_wsl preserving type)                       as AmountInTransactionCurrency,

      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      cast(rhcur as fis_hwaer preserving type)                   as CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast(hsl as fis_hsl preserving type)                       as AmountInCompanyCodeCurrency,

      @ObjectModel.foreignKey.association: '_GlobalCurrency'
      @Semantics.currencyCode:true
      cast(rkcur as fis_rkcur preserving type)                   as GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast(ksl as fis_ksl preserving type)                       as AmountInGlobalCurrency,

      // Freely Defined Currency 1

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency1'
      @Semantics.currencyCode:true
      cast(rocur as fis_rocur preserving type)                   as FreeDefinedCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      cast(osl as fis_osl preserving type)                       as AmountInFreeDefinedCurrency1,

      // Freely Defined Currency 2

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency2'
      @Semantics.currencyCode:true
      cast(rvcur as fis_rvcur preserving type)                   as FreeDefinedCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      cast(vsl as fis_vsl preserving type)                       as AmountInFreeDefinedCurrency2,

      // Freely Defined Currency 3

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency3'
      @Semantics.currencyCode:true
      rbcur                                                      as FreeDefinedCurrency3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      cast(bsl as fis_bsl preserving type)                       as AmountInFreeDefinedCurrency3,

      // Freely Defined Currency 4

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency4'
      @Semantics.currencyCode:true
      rccur                                                      as FreeDefinedCurrency4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      cast(csl as fis_csl preserving type)                       as AmountInFreeDefinedCurrency4,

      // Freely Defined Currency 5

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency5'
      @Semantics.currencyCode:true
      rdcur                                                      as FreeDefinedCurrency5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      cast(dsl as fis_dsl preserving type)                       as AmountInFreeDefinedCurrency5,

      // Freely Defined Currency 6

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency6'
      @Semantics.currencyCode:true
      recur                                                      as FreeDefinedCurrency6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      cast(esl as fis_esl preserving type)                       as AmountInFreeDefinedCurrency6,

      // Freely Defined Currency 7

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency7'
      @Semantics.currencyCode:true
      cast(rfcur as fis_rfcur preserving type)                   as FreeDefinedCurrency7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      cast(fsl as fis_fsl preserving type)                       as AmountInFreeDefinedCurrency7,

      // Freely Defined Currency 8

      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency8'
      @Semantics.currencyCode:true
      rgcur                                                      as FreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      cast(gsl as fis_gsl preserving type)                       as AmountInFreeDefinedCurrency8,

      rmvct                                                      as FinancialTransactionType,
      prctr                                                      as ProfitCenter,
      cast(kdauf as vdm_sales_order preserving type)             as SalesOrder,
      cast(kdpos as sales_order_item preserving type)            as SalesOrderItem,
      cast(lifnr as md_supplier preserving type)                 as Supplier,
      cast(kunnr as kunnr preserving type)                       as Customer,
      cast(hbkid as farp_hbkid preserving type)                  as HouseBank,
      cast(hktid as fac_hktid preserving type)                   as HouseBankAccount,
      lstar                                                      as CostCtrActivityType,
      cast(aufnr as fis_aufnr preserving type)                   as OrderID,
      cast(ps_psp_pnr as ps_posnr preserving type)               as WBSElementInternalID,
      nplnr                                                      as ProjectNetwork,
      nplnr_vorgn                                                as RelatedNetworkActivity,
      prznr                                                      as BusinessProcess,
      rcntr                                                      as CostCenter,
      rfarea                                                     as FunctionalArea,
      rbusa                                                      as BusinessArea,
      kokrs                                                      as ControllingArea,
      segment                                                    as Segment,
      scntr                                                      as PartnerCostCenter,
      pprctr                                                     as PartnerProfitCenter,
      sfarea                                                     as PartnerFunctionalArea,
      sbusa                                                      as PartnerBusinessArea,
      rassc                                                      as PartnerCompany,
      kstrg                                                      as CostObject,
      psegment                                                   as PartnerSegment,
      vname                                                      as JointVenture,
      egrup                                                      as JointVentureEquityGroup,
      recid                                                      as JointVentureCostRecoveryCode,
      vptnr                                                      as JointVenturePartner,
      pvname                                                     as PartnerVenture,
      swenr                                                      as REBusinessEntity,
      sgenr                                                      as RealEstateBuilding,
      sgrnr                                                      as RealEstateProperty,
      cbttype                                                    as BusinessTransactionType,
      koart                                                      as FinancialAccountType,
      aging                                                      as GeneralLedgerAgingScope,
      aging_incrmnt                                              as GeneralLedgerAgingIncrement,
      _BalanceTransactionCurrency,
      _TransactionCurrency,
      _CompanyCodeCurrency,
      _GlobalCurrency,
      _FreeDefinedCurrency1,
      _FreeDefinedCurrency2,
      _FreeDefinedCurrency3,
      _FreeDefinedCurrency4,
      _FreeDefinedCurrency5,
      _FreeDefinedCurrency6,
      _FreeDefinedCurrency7,
      _FreeDefinedCurrency8
}