I_SUPPROTTIMEBUCKETCNSMPNTP

CDS View

Supply Protection Time Bucket Cnsmpn

I_SUPPROTTIMEBUCKETCNSMPNTP is a CDS View in S/4HANA. Supply Protection Time Bucket Cnsmpn. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_SupProtTimeBucketCnsmpnTP view_entity projection CONSUMPTION Supply Protection Time Bucket Cnsmpn 
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel:   { usageType: { serviceQuality: #C,
                               sizeCategory:   #XL,
                               dataClass:      #MIXED },
                 compositionRoot: true
}

@EndUserText.label: 'Supply Protection Time Bucket Cnsmpn'
define root view entity I_SupProtTimeBucketCnsmpnTP
  as select from I_SupplyProtectionTimeBucket
  association [1..1] to I_SupplyProtectionGroupTP     as _SupplyProtectionGroupTP     on $projection.SupplyProtectionGroupUUID = _SupplyProtectionGroupTP.SupplyProtectionGroupUUID
  association [0..*] to I_SupProtPermConsumptionTP    as _SupProtPermConsumptionTP    on $projection.SupProtTimeBucketUUID = _SupProtPermConsumptionTP.SupProtTimeBucketUUID
  association [1..*] to I_ATPRlvtDocumentCategoryText as _ATPRlvtDocumentCategoryText on $projection.SupplyProtectionDocumentType = _ATPRlvtDocumentCategoryText.ATPRelevantDocumentCategory

{
  key  SupProtTimeBucketUUID,
  key  _SupProtPermConsumptionTP.SupProtPermConsumptionUUID                                                                                                 as SupProtPermConsumptionUUID,

       SupplyProtectionGroupUUID,
       //       cast(tstmp_to_dats( SupProtPeriodStartUTCDateTime, 'UTC', $session.client, 'NULL' ) as vdm_v_start_date) as StartDate,

       //       cast(tstmp_to_dats( SupProtPeriodEndUTCDateTime,'UTC', $session.client, 'NULL' ) as vdm_v_end_date)      as EndDate,

       cast(tstmp_to_dats( cast( SupProtPeriodStartUTCDateTime as abap.dec(15,0) ), 'UTC', $session.client, 'NULL' ) as vdm_v_start_date  preserving type ) as StartDate,
       cast(tstmp_to_dats( cast( SupProtPeriodEndUTCDateTime as abap.dec(15,0) ), 'UTC', $session.client, 'NULL' ) as vdm_v_end_date  preserving type )     as EndDate,

       _SupplyProtectionGroupTP.UnitOfMeasure,
       @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
       SupProtProtectedQuantity,
       @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
       SupProtConsumedQuantity                                                                                                                              as SupProtSumConsumedQuantity,
       @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
       SupProtRemainingProtectedQty,

       _SupProtPermConsumptionTP.SupplyProtectionDocumentType                                                                                               as SupplyProtectionDocumentType,
       _SupProtPermConsumptionTP.SupProtAssignedDocument                                                                                                    as SupProtAssignedDocument,
       _SupProtPermConsumptionTP.SupProtAssignedDocumentItem                                                                                                as SupProtAssignedDocumentItem,
       @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
       _SupProtPermConsumptionTP.SupProtConsumedQuantity                                                                                                    as SupProtConsumedQuantity,

      _SupProtPermConsumptionTP.ATPRelevantDocScheduleLine,
      
       _SupplyProtectionGroupTP.SupplyProtectionUUID,

       /* Associations */
       _SupplyProtectionGroupTP,
       _SupProtPermConsumptionTP,
       _ATPRlvtDocumentCategoryText,
       _SupplyProtectionGroupTP._BaseUnit
}

Learn More