I_SUPPROTRELATEDSUPPROTTP

CDS View

Supply Protection Related Supply Prot

I_SUPPROTRELATEDSUPPROTTP is a CDS View in S/4HANA. Supply Protection Related Supply Prot. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_SupProtRelatedSupProtTP view_entity projection CONSUMPTION Supply Protection Related Supply Prot. 
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel:   { usageType: { serviceQuality: #C,
                               sizeCategory:   #L,
                               dataClass:      #MIXED },
                 compositionRoot: true
}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Supply Protection Related Supply Prot'
define root view entity I_SupProtRelatedSupProtTP
  as select from I_SupplyProtection

  association [1..1] to I_SupProtCharacteristicVH    as _SupProtCoreCharc01VH          on  $projection.SupProtCoreCharc01CtlgPathUUID = _SupProtCoreCharc01VH.ProdAllocCharcCtlgPathUUID
  association [1..1] to I_SupProtCharacteristicVH    as _SupProtCoreCharc02VH          on  $projection.SupProtCoreCharc02CtlgPathUUID = _SupProtCoreCharc02VH.ProdAllocCharcCtlgPathUUID
  association [0..1] to I_Material                   as _Material                      on  $projection.Material = _Material.Material
  association [0..1] to I_UnitOfMeasure              as _BaseUnit                      on  $projection.UnitOfMeasure = _BaseUnit.UnitOfMeasure

  association [0..1] to I_SupProtLifecycleStatusText as _SupProtLifecycleStatusText    on  $projection.SupProtLifecycleStatus   = _SupProtLifecycleStatusText.SupProtLifecycleStatus
                                                                                       and _SupProtLifecycleStatusText.Language = $session.system_language

  association [0..1] to I_SupProtPlanningPeriodTypeT as _SupProtPlanningPeriodTypeText on  $projection.SupProtPlanningPeriodType   = _SupProtPlanningPeriodTypeText.SupProtPlanningPeriodType
                                                                                       and _SupProtPlanningPeriodTypeText.Language = $session.system_language

  association [0..*] to I_SupProtCnsmpnDateTimeTypeT as _SupProtCnsmpnDateTimeTypeT    on  $projection.SupProtCnsmpnDateTimeType = _SupProtCnsmpnDateTimeTypeT.SupProtCnsmpnDateTimeType

  association [1..1] to I_SupplyProtectionTP         as _SupplyProtectionTP            on  $projection.SupplyProtectionUUID = _SupplyProtectionTP.SupplyProtectionUUID
{

  key SupplyProtectionUUID                                                           as SupplyProtectionUUID,

      SupplyProtectionName                                                           as SupplyProtectionName,

      @Consumption.semanticObject: 'Material'
      Material                                                                       as Material,
      Plant                                                                          as Plant,

      @ObjectModel: { text.element: [ 'SupProtLifecycleStatusText'] }
      SupProtLifecycleStatus                                                         as SupProtLifecycleStatus,
      _SupProtLifecycleStatusText.SupProtLifecycleStatusText                         as SupProtLifecycleStatusText,
      case SupProtLifecycleStatus
        when '01' then 2
        when '02' then 3
        else 0
      end                                                                            as Criticality,

      @ObjectModel: { text.element: [ 'SupProtPlanningPeriodTypeText'] }
      SupProtPlanningPeriodType                                                      as SupProtPlanningPeriodType,
      _SupProtPlanningPeriodTypeText.SupProtPlanningPeriodTypeText                   as SupProtPlanningPeriodTypeText,
      SupProtPlanningPeriodStartDate,
      SupProtPlanningPeriodEndDate,

      SupProtCoreCharc01CtlgPathUUID                                                 as SupProtCoreCharc01CtlgPathUUID,
      @Consumption.valueHelp: '_SupProtCoreCharc01VH'
      cast( _SupProtCoreCharc01VH.Characteristic as sup_charc_text preserving type ) as SupProtCoreCharc01Text, //update with the correct data element

      SupProtCoreCharc01ValueID                                                      as SupProtCoreCharc01ValueID,

      SupProtCoreCharc02CtlgPathUUID                                                 as SupProtCoreCharc02CtlgPathUUID,
      @Consumption.valueHelp: '_SupProtCoreCharc02VH'
      cast( _SupProtCoreCharc02VH.Characteristic as sup_charc_text preserving type ) as SupProtCoreCharc02Text, //update with the correct data element

      SupProtCoreCharc02ValueID                                                      as SupProtCoreCharc02ValueID,

      SupProtIsPlanningContextSlsOrd,
      SupProtIsPlanningContextSTO,

      _Material.MaterialBaseUnit                                                     as UnitOfMeasure,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      SupProtProtectedQuantity,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      SupProtConsumedQuantity,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      SupProtRemainingProtectedQty,

      SupplyProtectionIsBlocked,

      SupProtCnsmpnDateTimeType,

      CharcValAuthznGroup,

      StorageLocation,
      
      SupProtPlanningLevel,

      /* Associations */
      _SupProtLifecycleStatusText,
      _SupProtCoreCharc01VH,
      _SupProtCoreCharc02VH,
      _Material,
      _BaseUnit,
      _SupProtPlanningPeriodTypeText,
      _SupProtCnsmpnDateTimeTypeT,
      _SupplyProtectionTP
}

Learn More