I_SUPPROTCHARACTERISTICTP

CDS View

Supply Protection Characteristic

I_SUPPROTCHARACTERISTICTP is a CDS View in S/4HANA. Supply Protection Characteristic. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_SupProtCharacteristic view_entity projection CONSUMPTION Characteristic
A_SupProtCharacteristic_2 view_entity projection CONSUMPTION Characteristic
C_SupProtCharacteristicTP view_entity projection CONSUMPTION Supply Protection Characteristic 
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory:   #L,
                             dataClass:      #MIXED } }
@EndUserText.label: 'Supply Protection Characteristic'
define view entity I_SupProtCharacteristicTP
  as select from I_SupProtCharacteristic
  association        to parent I_SupplyProtectionTP    as _SupplyProtectionTP   on $projection.SupplyProtectionUUID = _SupplyProtectionTP.SupplyProtectionUUID
  association [0..1] to I_ProdAllocCharcCtlgPathPicker as _PrioCharcCatalogText on _PrioCharcCatalogText.ProdAllocCharcCtlgPathIntID = $projection.SupProtCharcCtlgPathIntID
{
  key SupProtCharacteristicUUID,
      SupplyProtectionUUID,
      SupProtOrdinalNumberValue,
      SupProtCharcColumnName,
      SupProtCharcCtlgPathUUID,
      SupProtCharcCtlgPathIntID,
      cast( '' as charccatalogcharacteristicname )                                                              as SupProtCharcName,

      @Semantics.user.createdBy: true
      CreatedByUser,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,

      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      @Consumption.valueHelpDefinition: [{ entity.name:         'I_SupProtCharacteristicVH',
                                           entity.element:      'Characteristic',
                                           additionalBinding:   [{ element:      'ProdAllocCharcCtlgPathUUID',
                                                                   localElement: 'SupProtCharcCtlgPathUUID',
                                                                   usage:        #RESULT},
                                                                 { element:      'ProdAllocCharcCtlgPathIntID',
                                                                   localElement: 'SupProtCharcCtlgPathIntID',
                                                                   usage:        #RESULT},
                                                                 { element:      'ProdAllocCharcCatalogType',
                                                                   localElement: 'SupProtCharcCatalogType',
                                                                   usage:        #FILTER}]
                                        }]
      cast( _PrioCharcCatalogText(P_HasText:'X').ProdAllocCharcCtlgPathDesc as sup_charc_text preserving type ) as Characteristic,
      cast( _PrioCharcCatalogText(P_HasText:'X').ProdAllocCharcCtlgPathDesc as sup_charc_text preserving type ) as SupProtCharcText,

      _SupplyProtectionTP.SupProtCharcCatalogType,

      /* Associations */
      _SupplyProtectionTP
}

Learn More