I_SUBSTANCEVOLUME

CDS View

Aggregation for substance

I_SUBSTANCEVOLUME is a CDS View in S/4HANA. Aggregation for substance. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_SubstanceVolume view_entity from CONSUMPTION Aggregation for Substance 
@EndUserText.label: 'Aggregation for substance'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType:{ serviceQuality: #C,
                         sizeCategory:   #L,
                         dataClass:      #TRANSACTIONAL }
@VDM: {
  viewType: #COMPOSITE
}
define view entity I_SubstanceVolume
  as select from I_SVTAggrgnItmByBusProcess
{
  key    SVTAggregationItemUUID,
  key    SubstanceUUID,
         PolymerCompositionIntID,
         SourceSubstanceUUID,

         @Semantics.quantity.unitOfMeasure: 'ConfirmedSubstanceVolumeUnit'
         cast( sum(ConfirmedSubstanceVolume) as ehpma_svt_subst_vol_ui ) as ConfirmedSubstanceVolume, -- OData 2 service definition doesn't support dec34 that is why casting
         ConfirmedSubstanceVolumeUnit,

         @Semantics.quantity.unitOfMeasure: 'PlannedSubstanceVolumeUnit'
         cast( sum(PlannedSubstanceVolume) as ehpma_svt_subst_vol_ui )   as PlannedSubstanceVolume, -- OData 2 service definition doesn't support dec34 that is why casting
         PlannedSubstanceVolumeUnit,

         //For DCL need

         SVTAggregationHeaderUUID,

         //Associations

         _SVTAggregationHeader,
         _SVTAggregationItem
}
group by
  SVTAggregationItemUUID,
  SubstanceUUID,
  SourceSubstanceUUID,
  PolymerCompositionIntID,
  SVTAggregationHeaderUUID, // Only needed so that the DCL can use it.

  ConfirmedSubstanceVolumeUnit,
  PlannedSubstanceVolumeUnit

Learn More