I_STRPTAXRETURNBOXCUBE

@AbapCatalog.sqlViewName: 'ISRTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cube View to Return Tax Details with TaxBox configuration'
@VDM.viewType: #COMPOSITE
@Analytics: { dataCategory: #CUBE }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking:#BLOCKED_DATA_INCLUDED
@Consumption.dbHints: [ 'NO_CS_JOIN' , 'USE_HEX_PLAN' ]
define view I_StRpTaxReturnBoxCube 

  with parameters

    P_TaxIsDeferredRelevant : figen_deferred_check,
    P_TaxIsMossRelevant     : figen_moss_check,
    P_StatryRptgEntity      : srf_reporting_entity,
    P_StatryRptCategory     : srf_rep_cat_id,
    P_StatryRptRunID        : srf_report_run_id,
    P_ReportingCountry      : land1,
    P_TaxBoxConfiguration   : figen_tdt_taxbox_config
    
  as select from P_StRpCalTaxReturnBox (
                                                 P_TaxIsDeferredRelevant : $parameters.P_TaxIsDeferredRelevant,
                                                 P_TaxIsMossRelevant     : $parameters.P_TaxIsMossRelevant,
                                                 P_StatryRptgEntity      : $parameters.P_StatryRptgEntity , 
                                                 P_StatryRptCategory     : $parameters.P_StatryRptCategory,
                                                 P_StatryRptRunID        : $parameters.P_StatryRptRunID,
                                                 P_ReportingCountry      : $parameters.P_ReportingCountry,
                                                 P_TaxBoxConfiguration   : $parameters.P_TaxBoxConfiguration
                                                 
                                                )
{

      //P_StRpCalTaxReturnBox

  key P_StRpCalTaxReturnBox.CompanyCode,
  key P_StRpCalTaxReturnBox.AccountingDocument,
  key P_StRpCalTaxReturnBox.FiscalYear,
  key P_StRpCalTaxReturnBox.TaxItem,
  key P_StRpCalTaxReturnBox.TransactionTypeDetermination,
  key P_StRpCalTaxReturnBox.DebitCreditCode,
  key P_StRpCalTaxReturnBox.AccountingDocumentType,
  key cast( P_StRpCalTaxReturnBox.SupplierAccountGroup as farp_supplier_account_group ) as SupplierAccountGroup,  
  key P_StRpCalTaxReturnBox.TaxBox,
  key P_StRpCalTaxReturnBox.TaxDeclnAmountType,
  key P_StRpCalTaxReturnBox.TaxBoxStrucValidityStartDate,
  key P_StRpCalTaxReturnBox.UnifiedTaxBoxStructureType,  
  key P_StRpCalTaxReturnBox.TaxGroup,
  key P_StRpCalTaxReturnBox.TaxItemGrpgDebitCreditCode,
  key cast( P_StRpCalTaxReturnBox.TaxItemGrpgAcctgDocumentType as glo_tax_item_grpg_acc_doc_type ) as TaxItemGrpgAcctgDocumentType,
  key cast( P_StRpCalTaxReturnBox.TaxItemGrpgSupplierAcctGroup as glo_tax_itm_grpg_suplr_acc_grp ) as TaxItemGrpgSupplierAcctGroup,
  key P_StRpCalTaxReturnBox.TaxItemGrpgSpecialGLCode,
  key P_StRpCalTaxReturnBox.StatryRptgEntity,
  key P_StRpCalTaxReturnBox.StatryRptCategory,
  key P_StRpCalTaxReturnBox.StatryRptRunID,
  key cast( P_StRpCalTaxReturnBox.Country as glo_country ) as Country,
  key P_StRpCalTaxReturnBox.TaxCode,
  key P_StRpCalTaxReturnBox.TaxItemGroupingVersion,
  key P_StRpCalTaxReturnBox.TaxBoxStructureType,
  key TaxRateValidityStartDate,
  key TaxRateValidityEndDate,
      P_StRpCalTaxReturnBox.StatryRptRun,
      P_StRpCalTaxReturnBox.TaxItemAcctgDocItemRef,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'TaxBoxStrucValidityStartDate'
      P_StRpCalTaxReturnBox.ValidFrom, 
      
      
      P_StRpCalTaxReturnBox.TaxItemGroupingAccountNumber,      
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'TaxBoxStrucValidityEndDate'
      ValidTo,
      TaxBoxStrucValidityEndDate,
      TaxCalculationProcedure,
      @DefaultAggregation:#MIN
      TaxRate,
      
      IPITaxRate,
      
      @DefaultAggregation:#MIN
      TaxCodeRatePointer,
     
      /*@DefaultAggregation:#MIN
      AdditionalTax1Rate,*/
      
      /*@DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      ConditionAmount,*/
      Customer,
      GLAccount,
      TaxItemGroup,
      BusinessPlace,
      TaxJurisdiction,
      LowestLevelTaxJurisdiction,
      ReferenceDocumentType,
      AlternativeReferenceDocument,
      ReverseDocument,
      ReverseDocumentFiscalYear,
      ConditionRecord,
      RoundingDecimalPlaces,
      DocumentReferenceID,
      Ledger,
      LedgerGroup,
      PostingDate,
      DocumentDate,
      TaxReportingDate,      
      ReportingDate,
      TaxReportingDocumentDate,
      FiscalPeriod,
      OriginalFiscalPeriod,
      @DefaultAggregation:#MIN
      ExchangeRate,
      IsReversal,
      IsReversed,
      AccountingDocumentHeaderText,
      CompanyCodeCountry,
      cast( ReportingCountry as glo_tax_cntry_or_cocd_cntry ) as ReportingCountry,
      TaxReturnCountry,
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      CountryCurrency,
      @Semantics.currencyCode:true
      DocumentCurrency,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @Semantics.currencyCode: true
      AdditionalCurrency1,
      @Semantics.currencyCode: true
      AdditionalCurrency2,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxBaseAmountInRptgCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxAmountInRptgCrcy,

      
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'

      cast(case TaxDeclnAmountType
          when 'B'
          then
           TaxBaseAmountInRptgCrcy
          when 'T'
          then
          case TaxIsNotDeductible
          when 'X'
          then
          NonDeductibleInputTaxAmount
          else
          TaxAmountInRptgCrcy
          end 
          else 
          0
          end  as glo_amount_rptg_crcy )  as AmountInReportingCurrency,
      

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxBaseAmountInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxAmountInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxAmount,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CountryCurrency'
      TaxBaseAmountInCountryCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CountryCurrency'
      TaxAmountInCountryCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      TaxBaseAmtInAdditionalCrcy1,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      TaxBaseAmtInAdditionalCrcy2,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      TaxAmountInAdditionalCurrency1,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      TaxAmountInAdditionalCurrency2,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      DifferenceTaxAmtInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      DiffTaxBaseAmountInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TotalGrossAmountInCoCodeCrcy,
      
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TotalGrossAmount,
                        
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TotalGrossAmountInTransCrcy,

      TaxType,
      BPTaxNumber,
      ReportingVATRegistration,
      TaxNumber1, //Stock Transfer Scenario is handled


      Country                                                                              as ShippingPointCountry,
      
      TargetTaxCode,
      TaxNumber2,
      ActiveTaxType,
      TaxNumber3,
      TaxIsDeferredRelevant,
      TaxIsMossRelevant,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(case
      when TaxDeclnAmountType = 'T'
      then
      CalculatedTxAmtInCoCodeCrcy
      else 0
      end as glo_taxamount_calc_intrancrcy )                                               as
                                                                                              CalculatedTxAmtInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      cast(case
      when TaxDeclnAmountType = 'T'
      then
      CalculatedTaxAmountInTransCrcy
      else 0
      end as glo_taxamount_calc_intranscrcy )                                              as CalculatedTaxAmountInTransCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      cast(case
      when TaxDeclnAmountType = 'B'
      then
      CalculatedTxBaseAmtInTransCrcy
      else 0
      end as glo_baseamount_calc_intrancrcy )                                              as CalculatedTxBaseAmtInTransCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      cast(case
      when TaxDeclnAmountType = 'B'
      then CalculatedTxBaseAmtInTransCrcy
      when TaxDeclnAmountType = 'T'
      then
      CalculatedTaxAmountInTransCrcy
      else 0
      end as glo_amount_trans_crcy )                                                       as AmountInTransactionCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(case
      when TaxDeclnAmountType = 'B'
      then CalcdTxBaseAmtInCoCodeCrcy
      when TaxDeclnAmountType = 'T'
      then
      CalculatedTxAmtInCoCodeCrcy
      else 0
      end as glo_amount_compcode_crcy )                                                                as AmountInCompanyCodeCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'

      case
      when TaxDeclnAmountType = 'B'
      then
      CalcdTxBaseAmtInCoCodeCrcy
      else 0
      end                                                                                  as CalcdTxBaseAmtInCoCodeCrcy,
      
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(case
           when TaxDeclnAmountType = 'B'
            then TaxBaseAmtInAdditionalCrcy1

            when TaxDeclnAmountType = 'T'
            then TaxAmountInAdditionalCurrency1
         end as glo_amount_add_crcy1 )                          as AmountInAdditionalCurrency1,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(case
           when TaxDeclnAmountType = 'B'
            then TaxBaseAmtInAdditionalCrcy2

            when TaxDeclnAmountType = 'T'
            then TaxAmountInAdditionalCurrency2
         end as glo_amount_add_crcy2 )                          as AmountInAdditionalCurrency2,
      


      BusinessPartner,
      P_StRpCalTaxReturnBox.CAReconciliationKey,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      NonDeductibleInputTaxAmount,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      DcblVATIncrdCostInRptgCrcy,
      BusinessPartnerName,
      BusinessPartnerCountry,
      TaxTypeName,
      CustomerSupplierAddress,
      TaxIsNotDeductible,
      SenderCompanyCode,
      SenderAccountingDocument,
      SenderFiscalYear,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BalanceAmountInTransacCurrency,
      TaxBoxStructure,
      TaxBoxStructureName,
      TaxBoxName,
      TaxBoxCondition,
      TaxBoxAggregationOperation,
      TaxGroupOperation,
      ConditionType,

      case
      when ItelRelforReporting1 = 'X' and ItelRelforReporting2 = 'X' and ItelRelforReporting3 = 'X'
      then 'X'
      end                                                                                  as IsVATRelevant,
      
      IsNegativePosting,
      TaxCountry,
      TaxCntryOrCompanyCodeCntry,
      TaxGroupFreeClassification,
      
      TaxFulfillmentDate,
      JrnlEntryCntrySpecificRef4,
      JrnlEntryCntrySpecificRef5,
      TaxItemIsExternal,  
      
      _ReportedItemsLog,
      _ReportingCurrency,
      _OneTimeAccountBP,
      _JournalEntry,
      _AccountingDocument,
      _GLAccount,
      _TaxJurisdiction,
      _DebtorCreditorRblsPyblsItem,
      _ReceivablesPayablesItem,
      _TaxReceivablesPayablesItem,
      _CompanyCodeCountry,
      _TaxTypeText,
      _TaxCodeText,
      _CustomerSupplierLineItem 

}