I_SRVENTRYSHEETACCTASSGMTBASIC

@AbapCatalog.sqlViewName: 'ISRVETRSHTACCBSC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Srv Entry Sheet Account Assignment Basic'
@VDM.viewType : #BASIC

@ObjectModel: {
   representativeKey: 'AccountAssignment',
   updateEnabled,
   usageType.serviceQuality: #B,
   usageType.sizeCategory: #L,
   usageType.dataClass: #TRANSACTIONAL
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_SrvEntrySheetAcctAssgmtBasic
  as select from mmpur_ses_itm_ac as Document

  association [1..1] to I_ServiceEntrySheetBasic     as _ServiceEntrySheet         on  $projection.ServiceEntrySheet = _ServiceEntrySheet.ServiceEntrySheet
  association [1..1] to I_ServiceEntrySheetItemBasic as _ServiceEntrySheetItem     on  $projection.ServiceEntrySheet     = _ServiceEntrySheetItem.ServiceEntrySheet
                                                                                   and $projection.ServiceEntrySheetItem = _ServiceEntrySheetItem.ServiceEntrySheetItem

  association [0..1] to I_UnitOfMeasure              as _UnitValueHelp             on  $projection.quantityunit = _UnitValueHelp.UnitOfMeasure

  association [0..1] to I_REObjectByIntFinNumber     as _REObjectByIntFinNumber    on  $projection.REInternalFinNumber = _REObjectByIntFinNumber.REInternalFinNumber

{
      @ObjectModel.foreignKey.association: '_ServiceEntrySheet'
  key Document.serviceentrysheet                                            as ServiceEntrySheet,
      @ObjectModel.foreignKey.association: '_ServiceEntrySheetItem'
  key Document.serviceentrysheetitem                                        as ServiceEntrySheetItem,
      @ObjectModel.readOnly: true
  key Document.srvcentrshtitmacctglin                                       as AccountAssignment,
      Document.serviceentrysheetuuid                                        as ServiceEntrySheetUUID,
      Document.serviceentrysheetitemuuid                                    as ServiceEntrySheetItemUUID,
      Document.accountassignmentuuid                                        as AccountAssignmentUUID,
      @ObjectModel.readOnly: true
      Document.crea_date_time                                               as CreationDateTime,
      @ObjectModel.readOnly: true
      Document.crea_uname                                                   as CreatedByUser,
      @ObjectModel.readOnly: true
      Document.lchg_date_time                                               as LastChangeDateTime,
      @ObjectModel.readOnly: true
      Document.lchg_uname                                                   as LastChangeUser,
      Document.poitmaccassno                                                as RefDocAccountAssignment,
      Document.loekz                                                        as IsDeleted,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      @Aggregation.default: #NONE
      Document.menge                                                        as Quantity,
      @Semantics.amount.currencyCode: 'Currency'
      @Aggregation.default: #NONE
      Document.netwr                                                        as NetAmount,
      Document.vproz                                                        as MultipleAcctAssgmtDistrPercent,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.gsber                                                        as BusinessArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.kostl                                                        as CostCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.vbeln                                                        as SalesOrder,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.vbelp                                                        as SalesOrderItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.veten                                                        as SalesOrderScheduleLine,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.anln1                                                        as MasterFixedAsset,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.anln2                                                        as FixedAsset,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      Document.aufnr                                                        as OrderID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.kokrs                                                        as ControllingArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      Document.kstrg                                                        as CostObject,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.paobjnr                                                      as ProfitabilitySegment,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.prctr                                                        as ProfitCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.sakto                                                        as GLAccount,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ps_psp_pnr                                                   as WBSElementInternalID,
      cast( Document.ps_psp_pnr as ps_s4_pspnr preserving type ) as WBSElementInternalID_2, //no conv. exit

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.nplnr                                                        as ProjectNetwork,
      @ObjectModel.readOnly: true
      @Consumption.hidden: true
      Document.aufpl                                                        as ProjectNetworkInternalID,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'REInternalFinNumber'
      Document.imkey                                                        as RealEstateObject, //with conv exit

      cast( Document.imkey as recaimkeyfi preserving type )                 as REInternalFinNumber, // no conv exit



      @ObjectModel.readOnly: true
      @Consumption.hidden: true
      Document.aplzl                                                        as NetworkActivityInternalID,
      Document.vptnr                                                        as PartnerAccountNumber,

// new with CE 1911

      Document.lstar                                                        as CostCtrActivityType,
      Document.prznr                                                        as BusinessProcess,
      Document.dabrz                                                        as SettlementReferenceDate,
      Document.wempf                                                        as GoodsRecipientName,
      Document.ablad                                                        as UnloadingPointName,
      Document.aufpl_ord                                                    as OrderInternalID,
      Document.aplzl_ord                                                    as OrderIntBillOfOperationsItem,

// Public Sector Fields

      @ObjectModel.readOnly: 'undefined'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CommitmentItemShortID'
      Document.fipos                                                        as CommitmentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast( fipos as fmis_ci_internalname preserving type )                 as CommitmentItemShortID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.fistl                                                        as FundsCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.geber                                                        as Fund,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.fkber                                                        as FunctionalArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.kblnr                                                        as EarmarkedFundsDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.kblpos                                                       as EarmarkedFundsDocumentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.budget_pd                                                    as BudgetPeriod,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.grant_nbr                                                    as GrantID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.measure                                                      as FundedProgram,

// Service Order Fields

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.service_doc_type                                             as ServiceDocumentType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.service_doc_id                                               as ServiceDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.service_doc_item_id                                          as ServiceDocumentItem,

      @ObjectModel.foreignKey.association: '_UnitValueHelp'
      @Semantics.unitOfMeasure: true
      _ServiceEntrySheetItem.QuantityUnit,

      @Semantics.currencyCode:true
      _ServiceEntrySheetItem.Currency                                       as Currency,
      _ServiceEntrySheetItem.PurchasingOrganization                         as PurchasingOrganization,
      _ServiceEntrySheetItem.PurchasingGroup                                as PurchasingGroup,
      _ServiceEntrySheetItem.Plant                                          as Plant,

// Data Privacy and Protection

      @UI.hidden: true
      @Consumption.hidden: true
      @ObjectModel.readOnly: true
      _ServiceEntrySheetItem.IsEndOfPurposeBlocked,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _ServiceEntrySheet,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _ServiceEntrySheetItem,

      _UnitValueHelp,
      _REObjectByIntFinNumber
}