I_SPECVALASSGMTINSTANCE

CDS View

Specification Value Assignment Instance with Usages

I_SPECVALASSGMTINSTANCE is a CDS View in S/4HANA. Specification Value Assignment Instance with Usages. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_SpecCharByValueAssgmtInst view from COMPOSITE Specification Characteristic by VAI
I_SpecValAssgmtInstanceWthComp view from COMPOSITE Specification Value Assignment Instance with Composition 
@AbapCatalog.sqlViewName: 'ISPECVAINST'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE


@EndUserText.label: 'Specification Value Assignment Instance with Usages'
define view I_SpecValAssgmtInstance
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from    P_SpecValAssgmtInstanceNormal( P_KeyDate : $parameters.P_KeyDate ) as norm
    left outer join I_SpecValAssgmtUsage                                               as usg on  norm.SpecValAssgmtRootSpecIntID    = usg.SpecificationInternalID
                                                                                              and norm.SpecValAssgmtInheritanceRoot  = usg.MasterTableElementInternalID
                                                                                              and usg.SpecValAssgmtUsgeValdtyStrtDte <= $parameters.P_KeyDate
                                                                                              and usg.SpecValAssgmtUsgeValdtyEndDte  >= $parameters.P_KeyDate
                                                                                              and usg.SpecValAssgmtUsageIsDeleted != 'X'
  association [0..1] to I_SpecRating              as _Rating                  on $projection.SpecificationRating = _Rating.SpecificationRating
  association [0..1] to I_SpecValidityArea        as _ValidityArea            on $projection.SpecificationValidityArea = _ValidityArea.SpecificationValidityArea
  association [0..1] to I_SpecificationForKeyDate as _SpecificationForKeyDate on $projection.SpecificationInternalID = _SpecificationForKeyDate.SpecificationInternalID
{
  key norm.SpecValAssgmtHdr,
  key norm.SpecValAssgmt,
  key usg.SpecValAssgmtUsageInternalID,
      norm.SpecValAssgmtIsInhtncSource,
      norm.SpecificationInternalID,
      norm.InhtdSpecValAssgmtIsTmpChgd,
      norm.InhtdSpecValAssgmtIsPermChgd,
      norm.SpecInheritanceTemplate,
      norm.SpecValAssgmtInheritanceParent,
      norm.SpecValAssgmtInheritanceRoot,
      norm.SpecValAssgmtRootSpecIntID,
      norm.SpecValAssgmtType,
      norm.SpecValAssgmtChangeState,
      norm.SpecValAssgmtSortSequence,
      //norm.SpecValAssgmtHdrChangeState,

      norm.SpecValAssgmtUnitRefDimension,
      norm.ValueAssignmentSource,
      norm.SpecValAssgmtWithChangeState,

      norm.SpecValAssgmtHdrIsDeleted,
      norm.SpecValAssgmtIsDeleted,

      usg.SpecificationRating,
      usg.SpecificationValidityArea,
      usg.SpecValAssgmtUsageIsExcluded,
      usg.SpecValAssgmtUsageIsActive,
      usg.SpecValAssgmtUsageIsRelevant,

      _Rating,
      _ValidityArea,
      _SpecificationForKeyDate,
      _ValueAssignmentType
}

Learn More