I_SPECIDENTIFIER

CDS View

Specification Identifier

I_SPECIDENTIFIER is a CDS View in S/4HANA. Specification Identifier. It contains 2 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 2 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_SpecIdentifierForKeyDate view from COMPOSITE Specification on a Key Date
P_SpecIdfrBscByAppScore1 view from COMPOSITE Private view for basic idfr reading by app (score calc 1)

Fields (2)

KeyField CDS FieldsUsed in Views
SpecIdfgDescCategory SpecIdfgDescCategory 1
SpecIdfgDescType SpecIdfgDescType 1 
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISPECIDENT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY // TODO: change to disable access when it will be available


@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #BASIC

@EndUserText.label: 'Specification Identifier'
define view I_SpecIdentifier
  as select from estri
  association [0..1] to I_SpecIdentifierLongText     as _SpecIdentifierLongText     on  $projection.SpecIdfgDescInternalID  = _SpecIdentifierLongText.SpecIdfgDescInternalID
                                                                                    and $projection.SpecIdfgDescChangeState = _SpecIdentifierLongText.SpecIdfgDescChangeState
  association [1..1] to I_Language                   as _SpecIdfgDescLanguage       on  $projection.SpecIdfgDescLanguage = _SpecIdfgDescLanguage.Language
  association [0..1] to I_SpecIdentifierUsage        as _SpecIdentifierUsageOrigl   on  $projection.SpecIdfgDescInheritanceRoot          = _SpecIdentifierUsageOrigl.MasterTableElementInternalID
                                                                                    and $projection.SpecIdfgDescRootSpecIntID            = _SpecIdentifierUsageOrigl.SpecificationInternalID
  //$projection.SpecIdfgDescspecinternalidroot

                                                                                    and _SpecIdentifierUsageOrigl.SpecIdfgUsageIsDeleted = ''
  association [0..1] to I_SpecIdentifierUsage        as _SpecIdentifierUsageLocal   on  $projection.SpecIdfgDescInternalID               = _SpecIdentifierUsageLocal.MasterTableElementInternalID
                                                                                    and $projection.SpecificationInternalID              = _SpecIdentifierUsageLocal.SpecificationInternalID
                                                                                    and _SpecIdentifierUsageLocal.SpecIdfgUsageIsDeleted = ''
  association [0..1] to I_SpecInheritanceTemplateHdr as _SpecInheritanceTemplateHdr on  $projection.SpecInheritanceTemplate = _SpecInheritanceTemplateHdr.SpecInheritanceTemplate
{
  key recn          as SpecIdfgDescInternalID,
  key actn          as SpecIdfgDescChangeState,

      recnroot      as SpecificationInternalID,

      valfr         as SpecIdfgDescValidityStartDate,
      valto         as SpecIdfgDescValidityEndDate,
      aennr         as SpecIdfgDescChangeNumber,
      delflg        as SpecIdfgDescIsDeleted,
      //parkflg       as SpecIdfgDescIsInactive,


      crnam         as SpecIdfgDescCreatedByUser,

      crdat         as SpecIdfgDescCreationDate,
  
      updnam        as SpecIdfgDescLastChangedByUser,

      upddat        as SpecIdfgDescLastChangeDate,

      ord           as SpecIdfgDescSortSequence,
      /*  identnm       as NormedIdfgDescText,
        ltxtflg       as SpecIdfgDescHasLongtext,
        formatflg     as SpecIdfgDescHasFormatting,
        ,

        dokar         as SpecIdfgDescDocumentType,
        doknr         as SpecIdfgDescDocumentNumber,
        dokvr         as SpecIdfgDescDocumentVersion,
        doktl         as SpecIdfgDescDocumentPart,*/

      flg_inhsrc    as SpecIdfgDescIsInheritanceSrce,
      recntri_src   as SpecIdfgDescInheritanceParent,
      recntri_orig  as SpecIdfgDescInheritanceRoot,
      recnroot_orig as SpecIdfgDescRootSpecIntID,
      flg_inhovr    as InhtdSpecIdfgDescIsTmpChgd,
      flg_inhexcl   as InhtdSpecIdfgDescIsPermChgd,
      recn_tplh     as SpecInheritanceTemplate,
      tpl_ord       as SpecInheritanceTmplSortSeq,

      // This is not a mistake in the CDS model

      // Naming conflict between the CDS field name and DB field name cames from the wrong

      // DB design


      idtype        as SpecIdfgDescCategory,
      idcat         as SpecIdfgDescType,
      @ObjectModel.foreignKey.association: '_SpecIdfgDescLanguage'
      @Semantics.language: true
      langu         as SpecIdfgDescLanguage,

      ident         as SpecIdfgDescText,


      /* Associations */
      _SpecIdfgDescLanguage,
      _SpecIdentifierLongText,

      _SpecIdentifierUsageLocal,
      _SpecIdentifierUsageOrigl,
      _SpecInheritanceTemplateHdr
}

Learn More