I_SERVICEENTRYSHEETITEM
Service Entry Sheet Item
I_SERVICEENTRYSHEETITEM is a CDS View in S/4HANA. Service Entry Sheet Item. It contains 68 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_BSOrdItmProcFlwSrvcEntrSheet | view | from | CONSUMPTION | SES Item Attrib for BSOrd Prgrs |
| I_ServiceEntrySheetItemNote | view_entity | from | COMPOSITE | Service Entry Sheet Item Note |
| I_ServiceEntrySheetItemStdVH | view | from | COMPOSITE | Service Entry Sheet Item |
| I_ServiceEntrySheetItemTP | view | from | TRANSACTIONAL | Service Entry Sheet Item with Draft |
| I_SrvcEntrShtItmOpnAmtOrdCrcy | view | from | COMPOSITE | SES Item: Open Amount in PO Currency |
| I_SrvcEntrShtItmTotConfdAmt | view | from | COMPOSITE | SES Item: Total Confirmed Amount |
| I_SrvcEntrShtItmTotConfdQty | view | from | COMPOSITE | SES Item: Total Confirmed Quantity |
| I_SrvcEntrShtItmTotNetAmt | view | from | COMPOSITE | SES Item: Total Net Amount |
| P_PurOrdServiceEntryItem | view | from | CONSUMPTION | P_PurOrdServiceEntryItem |
| P_PurOrdServiceEntryItem1 | view | from | CONSUMPTION | P_PurOrdServiceEntryItem1 |
| P_SRVCENTRSHTITMTOTCONFDAMT | view | from | COMPOSITE | SES Item: Total Confirmed Amount |
| R_ServiceEntrySheetItemTP | view_entity | from | TRANSACTIONAL | Service Entry Sheet Item |
Fields (68)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | PurchaseOrder | PurchaseOrder | 2 |
| KEY | PurchaseOrderItem | PurchaseOrderItem | 2 |
| KEY | ServiceEntrySheet | ServiceEntrySheet | 2 |
| KEY | ServiceEntrySheetItem | ServiceEntrySheetItem | 2 |
| _DocumentCurrency | _DocumentCurrency | 1 | |
| _MaterialGroup | _MaterialGroup | 1 | |
| _MaterialGroupText | _MaterialGroupText | 1 | |
| _MaterialGroupValueHelp | _MaterialGroupValueHelp | 1 | |
| _SrvcEntrShtAcctAssgmtCat | _SrvcEntrShtAcctAssgmtCat | 1 | |
| _WorkItemText | _WorkItemText | 1 | |
| AccountAssignmentCategory | AccountAssignmentCategory | 1 | |
| ConfirmedQuantity | ConfirmedQuantity | 2 | |
| ConsumptionPosting | ConsumptionPosting | 1 | |
| CreationDateTime | CreationDateTime | 1 | |
| Currency | Currency | 2 | |
| ExpectedOverallLimitAmount | ExpectedOverallLimitAmount | 1 | |
| InventorySpecialStockType | InventorySpecialStockType | 1 | |
| IsDeleted | IsDeleted | 1 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 2 | |
| LastChangeDateTime | LastChangeDateTime | 1 | |
| MaterialGroup | MaterialGroup | 1 | |
| MaterialType | MaterialType | 1 | |
| MultipleAcctAssgmtDistribution | MultipleAcctAssgmtDistribution | 1 | |
| NetAmount | NetAmount | 1 | |
| NetAmountInPurchaseOrderCrcy | NetAmountInPurchaseOrderCrcy | 1 | |
| NetPriceAmount | NetPriceAmount | 1 | |
| NetPriceQuantity | NetPriceQuantity | 1 | |
| NonDeductibleInputTaxAmount | NonDeductibleInputTaxAmount | 1 | |
| OrderPriceUnit | OrderPriceUnit | 1 | |
| OrderPriceUnitToOrderUnitNmrtr | OrderPriceUnitToOrderUnitNmrtr | 1 | |
| OrdPriceUnitToOrderUnitDnmntr | OrdPriceUnitToOrderUnitDnmntr | 1 | |
| OriginObject | OriginObject | 1 | |
| OverallLimitAmount | OverallLimitAmount | 1 | |
| OverdelivTolrtdLmtRatioInPct | OverdelivTolrtdLmtRatioInPct | 1 | |
| PerformancePeriodEndDate | PerformancePeriodEndDate | 1 | |
| PerformancePeriodStartDate | PerformancePeriodStartDate | 1 | |
| Plant | Plant | 2 | |
| ProductType | ProductType | 1 | |
| PurchaseContract | PurchaseContract | 1 | |
| PurchaseContractItem | PurchaseContractItem | 1 | |
| PurchaseOrderCurrency | PurchaseOrderCurrency | 1 | |
| PurchaseOrderItemCategory | PurchaseOrderItemCategory | 1 | |
| PurchaseOrderItemCompanyCode | PurchaseOrderItemCompanyCode | 1 | |
| PurchaseOrderItemMaterialGroup | PurchaseOrderItemMaterialGroup | 1 | |
| PurchaseOrderItemNetAmount | PurchaseOrderItemNetAmount | 1 | |
| PurchaseOrderItemQuantity | PurchaseOrderItemQuantity | 1 | |
| PurchaseOrderItemQuantityUnit | PurchaseOrderItemQuantityUnit | 1 | |
| PurchasingGroup | PurchasingGroup | 2 | |
| PurchasingOrganization | PurchasingOrganization | 2 | |
| PurgDocItemExternalReference | PurgDocItemExternalReference | 1 | |
| PurgDocPriceDate | PurgDocPriceDate | 1 | |
| QtyInPurchaseOrderPriceUnit | QtyInPurchaseOrderPriceUnit | 1 | |
| QuantityUnit | QuantityUnit | 1 | |
| Service | Service | 1 | |
| ServiceEntrySheetItemDesc | ServiceEntrySheetItemDesc | 1 | |
| ServiceEntrySheetItemUniqueID | ServiceEntrySheetItemUniqueID | 1 | |
| ServicePerformanceDate | ServicePerformanceDate | 2 | |
| ServicePerformanceEndDate | ServicePerformanceEndDate | 1 | |
| ServicePerformer | ServicePerformer | 2 | |
| SESItemIsFinalEntry | SESItemIsFinalEntry | 1 | |
| SESNetAmountInclSalesTax | SESNetAmountInclSalesTax | 1 | |
| Supplier | Supplier | 1 | |
| TaxCalculationProcedure | TaxCalculationProcedure | 1 | |
| TaxCode | TaxCode | 1 | |
| TaxCountry | TaxCountry | 1 | |
| TaxDeterminationDate | TaxDeterminationDate | 1 | |
| TaxJurisdiction | TaxJurisdiction | 1 | |
| WorkItem | WorkItem | 1 |
@AbapCatalog.sqlViewName: 'ISRVCENTRSHTITM'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_SESPricingElement' ]
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Service Entry Sheet Item'
@VDM.viewType : #COMPOSITE
@ObjectModel: {
representativeKey: 'ServiceEntrySheetItem',
createEnabled,
updateEnabled,
usageType.serviceQuality: #C,
usageType.sizeCategory: #L,
usageType.dataClass: #MIXED
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_ServiceEntrySheetItem
as select from I_ServiceEntrySheetItemBasic as Document
association [1..1] to I_ServiceEntrySheet as _ServiceEntrySheet on $projection.ServiceEntrySheet = _ServiceEntrySheet.ServiceEntrySheet
association [1..*] to I_ServiceEntrySheetAcctAssgmt as _AccountAssignment on $projection.ServiceEntrySheet = _AccountAssignment.ServiceEntrySheet
and $projection.ServiceEntrySheetItem = _AccountAssignment.ServiceEntrySheetItem
association [0..1] to I_MaterialGroup as _MaterialGroupValueHelp on $projection.PurchaseOrderItemMaterialGroup = _MaterialGroupValueHelp.MaterialGroup //to de deleted
association [0..*] to I_MaterialGroupText as _MaterialGroupText on $projection.MaterialGroup = _MaterialGroupText.MaterialGroup
association [0..1] to I_AcctAssignmentCategoryText as _AcctAssignmentCategoryText on $projection.AccountAssignmentCategory = _AcctAssignmentCategoryText.AccountAssignmentCategory
and _AcctAssignmentCategoryText.Language = $session.system_language
association [0..1] to I_SrvcEntrShtAcctAssgmtCat as _SrvcEntrShtAcctAssgmtCat on _SrvcEntrShtAcctAssgmtCat.AccountAssignmentCategory = $projection.AccountAssignmentCategory
association [0..1] to I_PurchaseOrder as _PurchaseOrder on $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
association [0..1] to R_PurchaseOrderItem as _PurchaseOrderItem on $projection.PurchaseOrder = _PurchaseOrderItem.PurchaseOrder
and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
association [0..1] to I_ProductTypeCodeText as _ProductTypeText on _ProductTypeText.ProductTypeCode = $projection.ProductType
and _ProductTypeText.Language = $session.system_language
association [0..1] to I_PurgDocScheduleLine as _ScheduleLine on $projection.PurchaseOrder = _ScheduleLine.PurchasingDocument
and $projection.PurchaseOrderItem = _ScheduleLine.PurchasingDocumentItem
association [0..1] to I_Currency as _DocumentCurrency on $projection.Currency = _DocumentCurrency.Currency
association [0..*] to I_UnitOfMeasureText as _UnitText on $projection.QuantityUnit = _UnitText.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _PurOrdUnitOfMsrValHelp on $projection.PurchaseOrderItemQuantityUnit = _PurOrdUnitOfMsrValHelp.UnitOfMeasure
association [0..*] to I_UnitOfMeasureText as _PurOrdUnitOfMsrTxt on $projection.PurchaseOrderItemQuantityUnit = _PurOrdUnitOfMsrTxt.UnitOfMeasure
association [0..1] to I_WorkItemText as _WorkItemText on $projection.WorkItem = _WorkItemText.WorkItem
and _WorkItemText.Language = $session.system_language
association [0..*] to I_SESPricingElement as _SESPricingElement on $projection.ServiceEntrySheet = _SESPricingElement.ServiceEntrySheet
and $projection.ServiceEntrySheetItem = _SESPricingElement.ServiceEntrySheetItem
and $projection.ServiceEntrySheetItem is not initial
association [0..*] to I_ServiceEntrySheetItemNote as _ServiceEntrySheetItemNote on $projection.ServiceEntrySheet = _ServiceEntrySheetItemNote.ServiceEntrySheet
and $projection.ServiceEntrySheetItem = _ServiceEntrySheetItemNote.ServiceEntrySheetItem
and $projection.ServiceEntrySheetItem is not initial
----Extension Association
association [1..1] to E_ServiceEntrySheetItem as _ServiceEntrySheetItmExtension on $projection.ServiceEntrySheet = _ServiceEntrySheetItmExtension.ServiceEntrySheet
and $projection.ServiceEntrySheetItem = _ServiceEntrySheetItmExtension.ServiceEntrySheetItem
{
@ObjectModel.foreignKey.association: '_ServiceEntrySheet'
key Document.ServiceEntrySheet,
key Document.ServiceEntrySheetItem,
cast(concat(Document.ServiceEntrySheet, Document.ServiceEntrySheetItem) as purchasingdocumentitemuniqueid) as ServiceEntrySheetItemUniqueID,
@EndUserText.label: 'Reference Purchase Order'
Document.PurchaseOrder,
Document.PurchaseOrderItem,
Document.IsDeleted,
Document.Service,
Document.ServiceEntrySheetItemDesc,
Document.ServicePerformer,
@ObjectModel.text.association: '_AcctAssignmentCategoryText'
@ObjectModel.foreignKey.association: '_SrvcEntrShtAcctAssgmtCat'
Document.AccountAssignmentCategory,
Document.MultipleAcctAssgmtDistribution,
@ObjectModel.text.association: '_WorkItemText'
Document.WorkItem,
Document.ConfirmedQuantity,
@ObjectModel.text.association: '_UnitText'
Document.QuantityUnit,
Document.OrderPriceUnit,
Document.OrderPriceUnitToOrderUnitNmrtr,
Document.OrdPriceUnitToOrderUnitDnmntr,
Document.QtyInPurchaseOrderPriceUnit,
@Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
Document.NetPriceQuantity,
Document.ServicePerformanceDate,
Document.ServicePerformanceEndDate,
_ScheduleLine.PerformancePeriodStartDate,
_ScheduleLine.PerformancePeriodEndDate,
Document.OriginObject,
@Semantics.currencyCode:true
Document.Currency,
@Semantics.amount.currencyCode: 'Currency'
Document.NetPriceAmount,
@ObjectModel.text.association: '_MaterialGroupText'
Document.MaterialGroup,
Document.IsEndOfPurposeBlocked,
@ObjectModel.readOnly: true
cast(CreationDateTime as mmpur_ses_created_on preserving type ) as CreationDateTime,
Document.CreatedByUser,
Document.LastChangeDateTime,
Document.LastChangeUser,
Document.Plant,
Document.PurgDocItemExternalReference,
Document.PurchaseContract,
Document.PurchaseContractItem,
Document.PurchasingOrganization,
Document.PurchasingGroup,
Document.ParentObjectIsDeleted,
cast(' ' as ewerk) as PurOrderItemPlant, // to be deleted (as soon as possible)
cast(' ' as esart) as PurchaseOrderType, // to be deleted (as soon as possible)
@ObjectModel.readOnly: true
_PurchaseOrder.Supplier as Supplier,
_PurchaseOrderItem.MaterialGroup as PurchaseOrderItemMaterialGroup,
@ObjectModel.readOnly: true
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
@Aggregation.default: #NONE
_PurchaseOrderItem.OrderQuantity as PurchaseOrderItemQuantity,
@ObjectModel.readOnly: true
//@ObjectModel.text.association: '_PurOrdUnitOfMsrTxt'
@ObjectModel.foreignKey.association: '_PurOrdUnitOfMsrValHelp'
@Semantics.unitOfMeasure: true
_PurchaseOrderItem.PurchaseOrderQuantityUnit as PurchaseOrderItemQuantityUnit,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
@Aggregation.default: #NONE
_PurchaseOrderItem.NetAmount as PurchaseOrderItemNetAmount,
@EndUserText.label: 'Purchase Order Currency'
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_DocumentCurrency'
@Consumption.valueHelp: '_DocumentCurrency'
@Semantics.currencyCode:true
_PurchaseOrderItem.DocumentCurrency as PurchaseOrderCurrency,
@ObjectModel.readOnly: true
_PurchaseOrderItem.CompanyCode as PurchaseOrderItemCompanyCode,
@ObjectModel.readOnly: true
_PurchaseOrderItem.OverdelivTolrtdLmtRatioInPct,
_PurchaseOrderItem.PurchaseOrderItemCategory,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
@Aggregation.default: #NONE
_PurchaseOrderItem.ExpectedOverallLimitAmount,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
@Aggregation.default: #NONE
_PurchaseOrderItem.OverallLimitAmount,
@ObjectModel.readOnly: true
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
@Aggregation.default: #NONE
cast(0 as mmpur_ses_confirmedquantity) as TotalConfirmedQuantity,
@ObjectModel.readOnly: true
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
@Aggregation.default: #NONE
cast(0 as mmpur_ses_openquantity) as OpenQuantity,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
@Aggregation.default: #NONE
cast(0 as mmpur_ses_open_amount_po_crcy) as OpenAmountInPurchaseOrderCrcy,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'Currency'
@Aggregation.default: #NONE
Document.NetAmount,
// cast(
// case
// when _PurchaseOrderItem.PurchaseOrderItemCategory = 'A'
// then cast( round( Document.NetPriceAmount * Document.ConfirmedQuantity, 2) as mmpur_ses_confirmedvalue)
// else
// case
// when _PurchaseOrderItem.OrderQuantity = 0
// then cast(0 as mmpur_ses_confirmedvalue)
// else cast( round( division( (_PurchaseOrderItem.NetAmount * Document.ConfirmedQuantity), _PurchaseOrderItem.OrderQuantity, 6), 2) as mmpur_ses_confirmedvalue)
// end
// end as mmpur_ses_confirmedvalue) as NetAmount,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
@Aggregation.default: #NONE
Document.NetAmount as NetAmountInPurchaseOrderCrcy,
// cast(
// case
// when Currency <> _PurchaseOrderItem.DocumentCurrency
// then currency_conversion( amount => NetAmount,
// source_currency => Currency,
// round => 'X',
// target_currency => _PurchaseOrderItem.DocumentCurrency,
// exchange_rate_date => ServicePerformanceDate,
// error_handling => 'SET_TO_NULL' )
// else NetAmount
// end as mmpur_ses_netprice_purord_crcy) as NetAmountInPurchaseOrderCrcy,
@Semantics.amount.currencyCode: 'Currency'
Document.NonDeductibleInputTaxAmount,
@ObjectModel.readOnly: true
@Semantics.amount.currencyCode: 'Currency'
@Aggregation.default: #NONE
cast( (Document.NetAmount + Document.NonDeductibleInputTaxAmount ) as mmpur_ses_confirmedvalue_w_tax ) as SESNetAmountInclSalesTax,
Document.TaxCode,
Document.TaxCountry,
Document.TaxDeterminationDate,
Document.TaxJurisdiction,
Document.TaxCalculationProcedure,
Document.PurgDocPriceDate,
Document.SESItemIsFinalEntry,
@ObjectModel.readOnly: true
_Material.MaterialType,
@ObjectModel.readOnly: true
_AccountAssignmentCategory.ConsumptionPosting,
@ObjectModel.readOnly: true
_AccountAssignmentCategory.InventorySpecialStockType,
@ObjectModel.readOnly: true
_PurchaseOrderItem.ProductType as ProductType,
@ObjectModel.association.type: [ #TO_COMPOSITION_PARENT , #TO_COMPOSITION_ROOT ]
_ServiceEntrySheet,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_AccountAssignment,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_SESPricingElement,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_ServiceEntrySheetItemNote,
Document._Material,
Document._MaterialGroup,
Document._AccountAssignmentCategory,
Document._UnitValueHelp,
_MaterialGroupText,
_MaterialGroupValueHelp, //to de deleted
_AcctAssignmentCategoryText,
_SrvcEntrShtAcctAssgmtCat,
_DocumentCurrency,
_UnitText,
_PurOrdUnitOfMsrValHelp,
_PurOrdUnitOfMsrTxt,
_WorkItemText,
_ProductTypeText
}