I_SERVICEENTRYSHEETACCTASSGMT

@AbapCatalog.sqlViewName: 'ISRVCENTRSHTACCT'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Service Entry Sheet Account Assignment'
@VDM.viewType : #COMPOSITE

@ObjectModel: {
   semanticKey: ['ServiceEntrySheet', 'ServiceEntrySheetItem', 'AccountAssignment' ],
   updateEnabled,
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #L,
   usageType.dataClass: #MIXED
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_ServiceEntrySheetAcctAssgmt
  as select from I_SrvEntrySheetAcctAssgmtBasic as Document

  association [1..1] to I_ServiceEntrySheet     as _ServiceEntrySheet     on  _ServiceEntrySheet.ServiceEntrySheet = $projection.ServiceEntrySheet
  association [1..1] to I_ServiceEntrySheetItem as _ServiceEntrySheetItem on  _ServiceEntrySheetItem.ServiceEntrySheet     = $projection.ServiceEntrySheet
                                                                          and _ServiceEntrySheetItem.ServiceEntrySheetItem = $projection.ServiceEntrySheetItem

  association [0..*] to I_UnitOfMeasureText     as _UnitText              on  $projection.QuantityUnit = _UnitText.UnitOfMeasure
  association [0..1] to I_ControllingArea       as _ControllingArea       on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_GLAccount             as _GLAccount             on  $projection.GLAccount   = _GLAccount.GLAccount
                                                                          and $projection.CompanyCode = _GLAccount.CompanyCode
  association [0..*] to I_GLAccountText         as _GLAccountText         on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
                                                                          and $projection.GLAccount       = _GLAccountText.GLAccount
  association [0..1] to I_Currency              as _Currency              on  $projection.Currency = _Currency.Currency
  association [0..1] to I_CompanyCode           as _CompanyCode           on  $projection.CompanyCode = _CompanyCode.CompanyCode
{
  key Document.ServiceEntrySheet                                                                    as ServiceEntrySheet,
  key Document.ServiceEntrySheetItem                                                                as ServiceEntrySheetItem,

      @ObjectModel.readOnly: true
  key Document.AccountAssignment,

      Document.RefDocAccountAssignment,

      Document.IsDeleted,

      @ObjectModel.readOnly: true
      @ObjectModel.text.association: '_UnitText'
      @ObjectModel.foreignKey.association: '_UnitValueHelp'
      @Semantics.unitOfMeasure: true
      QuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      @Aggregation.default: #NONE
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Document.Quantity,

      @Semantics.amount.currencyCode: 'Currency'
      @Aggregation.default: #NONE
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.NetAmount,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostCenter,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      //@ObjectModel.mandatory: 'undefined'

      Document.MultipleAcctAssgmtDistrPercent,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GLAccount                                                                            as GLAccount,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BusinessArea,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.SalesOrder,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      SalesOrderItem,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.SalesOrderScheduleLine,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.MasterFixedAsset,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FixedAsset,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderID,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ControllingArea,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostObject,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProfitabilitySegment,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProfitCenter,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.WBSElementInternalID,

      Document.WBSElementInternalID_2,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProjectNetwork,

      @ObjectModel.readOnly: true
      Document.ProjectNetworkInternalID,

      // VDM Consistency (2108) - Focus Conversion Exits: Change cast from VORNR to PS_S4_VORNR

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast ('   ' as ps_s4_vornr)                                                                   as NetworkActivity,

      @ObjectModel.readOnly: true
      Document.NetworkActivityInternalID,

      Document.PartnerAccountNumber,

      cast( REInternalFinNumber as imkey )                                                          as RealEstateObject, //with conv exit


      @ObjectModel.foreignKey.association: '_REObjectByIntFinNumber'
      REInternalFinNumber, //without conv exit


      // new with CE 1911

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostCtrActivityType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BusinessProcess,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.SettlementReferenceDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GoodsRecipientName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.UnloadingPointName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderInternalID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderIntBillOfOperationsItem,

      // Public Sector Fields

      @ObjectModel.readOnly: 'undefined'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CommitmentItemShortID'
      Document.CommitmentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CommitmentItemShortID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FundsCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.Fund,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FunctionalArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.EarmarkedFundsDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.EarmarkedFundsDocumentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BudgetPeriod,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GrantID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FundedProgram,

      // Service Order Fields

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocumentType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocumentItem,

      @ObjectModel.readOnly: 'true'
      @ObjectModel.mandatory: 'false'
      cast(Document.CreationDateTime as mmpur_ses_created_on)                                       as CreationDateTime,

      Document.CreatedByUser,
      Document.LastChangeDateTime,
      Document.LastChangeUser,

      Document.PurchasingOrganization,
      Document.PurchasingGroup,
      Document.Plant,
      Document.IsEndOfPurposeBlocked,

      @ObjectModel.readOnly: 'true'
      @ObjectModel.mandatory: 'false'
      cast(substring( cast(tstmp_current_utctimestamp() as abap.char( 17 ) ), 1, 8 ) as abap.dats ) as ValidityDate,

      @ObjectModel.readOnly: true
      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_Currency'
      _ServiceEntrySheetItem.PurchaseOrderCurrency                                                  as Currency,

      @ObjectModel.readOnly: true
      @ObjectModel.foreignKey.association: '_CompanyCode'
      _ServiceEntrySheetItem.PurchaseOrderItemCompanyCode                                           as CompanyCode,

      @ObjectModel.readOnly: true
      _ControllingArea.ChartOfAccounts                                                              as ChartOfAccounts,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _ServiceEntrySheet,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _ServiceEntrySheetItem,

      Document._UnitValueHelp,

      _UnitText,
      _Currency,
      _CompanyCode,
      _REObjectByIntFinNumber
}