I_SERVICEENTRYSHEET

CDS View

Service Entry Sheet

I_SERVICEENTRYSHEET is a CDS View in S/4HANA. Service Entry Sheet. It contains 26 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 26 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_BSOrdProcFlwSrvcEntrSheet view from CONSUMPTION SES Attrib for BSOrd Prgrs
C_DspDocFlwSESAttrib view_entity from CONSUMPTION Service Entry Sheet Attributes for DDF
ESH_N_SERVICEENTRYSHEET view from Anchor view -SERVICEENTRYSHEET
I_ServiceEntrySheetNote view_entity from COMPOSITE Service Entry Sheet Note
I_ServiceEntrySheetTP view from TRANSACTIONAL Service Entry Sheet with Draft
I_SESPricingElement view from COMPOSITE Service Entry Sheet Pricing Element
R_ServiceEntrySheetTP view_entity from TRANSACTIONAL Service Entry Sheet Header

Fields (26)

KeyField CDS FieldsUsed in Views
KEY ServiceEntrySheet ServiceEntrySheet,UI5NetworkGraphAttributeValue 4
ApprovalDateTime ApprovalDateTime 1
ApprovalStatus ApprovalStatus 1
CreationDateTime CreationDateTime 1
Currency Currency 1
ExternalRevisionDateTime ExternalRevisionDateTime 1
IsDeleted IsDeleted 1
IsEndOfPurposeBlocked IsEndOfPurposeBlocked 2
LastChangeDateTime LastChangeDateTime 1
MaterialDocument MaterialDocument 1
MaterialDocumentYear MaterialDocumentYear 1
OriginObjectType OriginObjectType 1
PostingDate PostingDate 2
PricingDocument PricingDocument 1
PurchaseOrder PurchaseOrder 1
PurchaseOrderCurrency PurchaseOrderCurrency 1
PurchasingGroup PurchasingGroup 2
PurchasingOrganization PurchasingOrganization 2
PurgDocExternalReference PurgDocExternalReference 1
PurgDocExternalSystem PurgDocExternalSystem 1
ResponsiblePerson ResponsiblePerson 1
ServiceEntrySheetName ServiceEntrySheetName 1
SESWorkflowStatus SESWorkflowStatus 1
Supplier Supplier 1
TotalNetAmount TotalNetAmount 1
TotalSESNetAmountInclSalesTax TotalSESNetAmountInclSalesTax 1 
@AbapCatalog.sqlViewName: 'ISRVCENTRSHT'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_SESWorkflowStatus', '_WorkflowStatusText' ]
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType : #COMPOSITE
@EndUserText.label: 'Service Entry Sheet'

@ObjectModel: {
   compositionRoot: true,
   representativeKey: 'ServiceEntrySheet',
   createEnabled,
   deleteEnabled,
   updateEnabled: 'EXTERNAL_CALCULATION',
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #L,
   usageType.dataClass: #MIXED
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_ServiceEntrySheet
  as select from I_ServiceEntrySheetBasic as Document
  association [1..*] to I_ServiceEntrySheetItem      as _ServiceEntrySheetItem      on $projection.ServiceEntrySheet = _ServiceEntrySheetItem.ServiceEntrySheet
//  association [0..1] to I_SrvcEntrShtItmTotNetAmt    as _SrvcEntrShtItmTotNetAmt    on $projection.ServiceEntrySheet = _SrvcEntrShtItmTotNetAmt.ServiceEntrySheet

  association [0..*] to I_SrvcEntrShtApprvlStsTxt    as _ApprovalStatusText         on $projection.ApprovalStatus = _ApprovalStatusText.ApprovalStatus
  association [1..1] to I_SESWorkflowStatus          as _SESWorkflowStatus          on  $projection.ServiceEntrySheet = _SESWorkflowStatus.ServiceEntrySheet
  association [0..1] to I_SESWorkflowStatusValueHelp as _WorkflowStatusValueHelp    on  $projection.sesworkflowstatus = _WorkflowStatusValueHelp.SESWorkflowStatus
  association [0..*] to I_SESWorkflowStatusText      as _WorkflowStatusText         on $projection.sesworkflowstatus = _WorkflowStatusText.SESWorkflowStatus
  association [0..*] to I_SrvcEntrShtPurOrdValueHelp as _SrvcEntrShtPurOrdValueHelp on _SrvcEntrShtPurOrdValueHelp.PurchaseOrder = $projection.PurchaseOrder
  association [0..1] to I_PurchaseOrder              as _PurchaseOrder              on $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [0..1] to I_Currency                   as _DocumentCurrency           on $projection.Currency = _DocumentCurrency.Currency

  ----Extension Association
  association [1..1] to E_ServiceEntrySheet          as _ServiceEntrySheetExtension on $projection.ServiceEntrySheet = _ServiceEntrySheetExtension.ServiceEntrySheet

{
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: true
  key Document.ServiceEntrySheet,

      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceEntrySheetName,

      @ObjectModel.readOnly: true
      @ObjectModel.text.element: [ 'SupplierName' ]
      Document.Supplier,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      cast(_Supplier.SupplierName as bu_name1tx)                                                       as SupplierName,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      //@ObjectModel.foreignKey.association: '_SrvcEntrShtPurOrdValueHelp'

      @Consumption.valueHelp: '_SrvcEntrShtPurOrdValueHelp'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.PurchaseOrder,

      @Semantics.currencyCode:true
      @ObjectModel.readOnly: true
      @ObjectModel.foreignKey.association: '_PurchaseOrderCurrency'
      @Consumption.valueHelp: '_PurchaseOrderCurrency'
      _PurchaseOrder.DocumentCurrency                                                                  as PurchaseOrderCurrency,

      Document.IsDeleted,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_ApprovalStatusText'
      @ObjectModel.foreignKey.association: '_ApprovalStatusValueHelp'
      Document.ApprovalStatus,


      @ObjectModel.readOnly: true
      @ObjectModel.text.association: '_WorkflowStatusText'
      @ObjectModel.foreignKey.association: '_WorkflowStatusValueHelp'
      _SESWorkflowStatus.SESWorkflowStatus,

      Document.ApprovalDateTime,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Document.ResponsiblePerson,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OriginObjectType,

      @Semantics.currencyCode:true
      @ObjectModel.readOnly: true
      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      @Consumption.valueHelp: '_DocumentCurrency'
      Document.Currency,

      Document.MaterialDocument,
      Document.MaterialDocumentYear,

      @ObjectModel.readOnly: true
      cast(CreationDateTime as mmpur_ses_created_on)                                                   as CreationDateTime,

      @ObjectModel.readOnly: true
      @Semantics.user.createdBy: true
      Document.CreatedByUser,

      @ObjectModel.readOnly: true
      cast(Document.LastChangeDateTime as mmpur_ses_changed_on)                                        as LastChangeDateTime,

      @ObjectModel.readOnly: true
      @Semantics.user.lastChangedBy: true
      Document.LastChangeUser,

      @ObjectModel.readOnly: true
      Document.PurchasingOrganization,

      @ObjectModel.readOnly: true
      Document.PurchasingGroup,

      Document.IsEndOfPurposeBlocked,
      Document.PurgDocExternalSystem,
      Document.PurgDocExternalReference,
      Document.ExternalRevisionDateTime,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.PostingDate,
      Document.PricingDocument,

      @Semantics.amount.currencyCode: 'Currency'
      @ObjectModel.readOnly: true
      @Aggregation.default: #NONE
      cast( 0 as mmpur_ses_confirmedvalue )                      as TotalNetAmount,

      @Semantics.amount.currencyCode: 'Currency'
      @ObjectModel.readOnly: true
      @Aggregation.default: #NONE
      cast( 0 as mmpur_ses_total_conf_val_w_tax ) as TotalSESNetAmountInclSalesTax,

      Document._ApprovalStatusValueHelp,
      Document._ResponsiblePersonValueHelp,
      Document._Supplier,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ServiceEntrySheetItem,
      _CreatedByUser,
      _LastChangeUser,

      _DocumentCurrency,
      _PurchaseOrder._DocumentCurrency                                                                 as _PurchaseOrderCurrency,
      _SrvcEntrShtPurOrdValueHelp,
      _ApprovalStatusText,
//      _SrvcEntrShtItmTotNetAmt,


      _SESWorkflowStatus,
      _WorkflowStatusValueHelp,
      _WorkflowStatusText
}

Learn More