I_SECURITYSWAP

CDS View

Security Swap

I_SECURITYSWAP is a CDS View in S/4HANA. Security Swap. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_SecuritySwapTP view_entity from TRANSACTIONAL Security Swap 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Security Swap'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #M,
  dataClass: #MASTER
}
@VDM.viewType: #COMPOSITE
define view entity I_SecuritySwap
  as select from I_ExecutableRightHeader as Header
    inner join   I_ExecutableRightItem   as Item on  Header.ExecutableRight         = Item.ExecutableRight
                                                 and Item.ExecutableRightItemNumber = '00000002'

  association [1..1] to I_SecurityClass as _SecurityClass on $projection.ScrtyClSwapOldSecurityClass = _SecurityClass.SecurityClass
{
  key cast(Item.ReferenceSecurityClass as ftr_sc_swap_old_ranl preserving type )          as ScrtyClSwapOldSecurityClass,
  key cast(Item.SecurityClassToBeTransferred as ftr_sc_swap_new_ranl preserving type )    as ScrtyClSwapNewSecurityClass,
      cast(Header.ExerciseOptionRatioNumerator as ftr_sc_swap_bovza preserving type )     as ScrtyClSwapRatioNumerator,
      cast(Header.ExerciseOptionRatioDenominator as ftr_sc_swap_bovne preserving type )   as ScrtyClSwapRatioDenominator,
      @Semantics.amount.currencyCode: 'ScrtyClSwapPayInAmountCurrency'
      cast( Header.ExecutableRightExercisePrice as ftr_sc_swap_bbasprei preserving type ) as SecurityClassSwapPayInAmount,
      cast(Header.ExectblRghtExercisePriceCrcy as ftr_sc_swap_rwhrbas preserving type )   as ScrtyClSwapPayInAmountCurrency,
      cast(Header.ExecutableRightTermFromDate as ftr_sc_swap_dlavo preserving type )      as ScrtyClSwapEffectiveFromDate,
      cast(Header.ExecutableRightTermToDate as ftr_sc_swap_dlabi preserving type )        as ScrtyClSwapEffectiveToDate,
      cast(Header.ExecutableRightDescription as ftr_sc_swap_kurztext preserving type )    as SecurityClassSwapDescription,

      _SecurityClass
}
where
  Header.ExecutableRightCategory = '10'

Learn More