I_SECURITYCLASSCONDITIONHEADER

CDS View

Security Class Condition Header

I_SECURITYCLASSCONDITIONHEADER is a CDS View in S/4HANA. Security Class Condition Header. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
R_ScrtyClConditionHeaderTP_2 view_entity from TRANSACTIONAL Security Class Condition Header
R_SecurityClConditionHeaderTP view_entity from TRANSACTIONAL Security Class Condition Header 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Security Class Condition Header'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@VDM.viewType: #COMPOSITE
define view entity I_SecurityClassConditionHeader
  as select from           I_StockSubscrpnRghtInvmtCert   as StockSubscrpnRghtInvmtCert
    left outer to one join P_MaxStkCndnEffctvFromDate     as MaxStkCndnEffctvFromDate     on MaxStkCndnEffctvFromDate.SecurityClass = StockSubscrpnRghtInvmtCert.SecurityClass
    inner join             I_StkSubscrpnRghtInvmtCertCndn as StkSubscrpnRghtInvmtCertCndn on StkSubscrpnRghtInvmtCertCndn.SecurityClass                = StockSubscrpnRghtInvmtCert.SecurityClass
                                                                                          and(
                                                                                            StkSubscrpnRghtInvmtCertCndn.StockPartlyPaytEffctvFromDate = MaxStkCndnEffctvFromDate.MaxStkPartlyPaytEffctvFromDate
                                                                                            or MaxStkCndnEffctvFromDate.MaxStkPartlyPaytEffctvFromDate is null
                                                                                          )

  association [1..1] to I_SecurityClass as _SecurityClass on $projection.SecurityClass = _SecurityClass.SecurityClass

{
  key StockSubscrpnRghtInvmtCert.SecurityClass,
      StockSubscrpnRghtInvmtCert.ScrtyClDvdndRightsPerUnitInPct,
      cast('' as tpm_rounding_rule )                             as ScrtyClCalculationRoundingRule,
      cast('000' as batrt preserving type )                      as ScrtyClIntrstCalcCuttingDays,
      StkSubscrpnRghtInvmtCertCndn.ScrtyClDvdndEntlmntStartDate,
      @Semantics.booleanIndicator
      StkSubscrpnRghtInvmtCertCndn.ScrtyClDistrIsReinvested,
      StkSubscrpnRghtInvmtCertCndn.DistrReinvestmentDiscInPct,
      cast('' as szbmeth preserving type  )                      as InterestCalculationMethod,
      @Semantics.booleanIndicator
      cast('' as ftr_sc_interest_discount_ind preserving type  ) as ScrtyClInterestIsDiscounted,
      cast('0' as seffmeth_new preserving type )                 as EffectiveInterestMethod,
      cast('000' as vvzvrhyeff preserving type )                 as ScrtyClInterestSettlementFrqcy,
      cast(0 as  tb_eff_rate  )                                  as EffectiveInterestRate,
      cast('0' as ftr_sc_repayment_type preserving type )        as SecurityClassRepaymentType,

      _SecurityClass
}

union all select from I_SecurityClassBond   as Bond
  inner join          I_BondConditionHeader as BondCondition on BondCondition.SecurityClass = Bond.SecurityClass

association [1..1] to I_SecurityClass as _SecurityClass on $projection.SecurityClass = _SecurityClass.SecurityClass

{
  key Bond.SecurityClass,
      cast(0 as pdivber )                as ScrtyClDvdndRightsPerUnitInPct,
      Bond.ScrtyClCalculationRoundingRule,
      Bond.ScrtyClIntrstCalcCuttingDays,
      cast('00000000' as ddbab  )        as ScrtyClDvdndEntlmntStartDate,
      cast('' as sthes preserving type ) as ScrtyClDistrIsReinvested,
      cast(0 as pwarb  )                 as DistrReinvestmentDiscInPct,
      BondCondition.InterestCalculationMethod,
      BondCondition.ScrtyClInterestIsDiscounted,
      BondCondition.EffectiveInterestMethod,
      BondCondition.ScrtyClInterestSettlementFrqcy,
      BondCondition.EffectiveInterestRate,
      BondCondition.SecurityClassRepaymentType,

      _SecurityClass
}

Learn More