I_SALESORDERFLFMTISSUEBASIC

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S

@EndUserText.label: 'SOFM Issue Without Details'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISOFISSUEBASIC'

-- Description:
--   the difference of this view  to the similar view I_SalesOrderFulfillmentIssue is:
--      - this has no parameters
--      - this does not provide additional sales document attributes




define view I_SalesOrderFlfmtIssueBasic
//with parameters

//    @Consumption.hidden: true

//    @Environment.systemField: #SYSTEM_DATE

//    P_ReferenceDate : sydate

as 
select --distinct AT28.7.2020 issue union ensures no duplicates, so no need for distinct (=in theory one group by less !)
from P_SalesOrderFlfmtIssueUnion  as Union_Issues --(P_ReferenceDate: $parameters.P_ReferenceDate) as Union_Issues 
//inner join

//I_SlsOrdFlfmtSalesOrder as SOFSalesOrder

//on 

//      Union_Issues.SalesOrder             = SOFSalesOrder.SalesOrder  and

//      Union_Issues.SalesOrganization      = SOFSalesOrder.SalesOrganization and

//      Union_Issues.DistributionChannel    = SOFSalesOrder.DistributionChannel and

//      Union_Issues.OrganizationDivision   = SOFSalesOrder.OrganizationDivision

association[0..1] to I_Issue               as _Issue          on $projection.Issue = _Issue.Issue 
association[0..1] to I_IssueCategory       as _IssueCategory  on $projection.IssueCategory = _IssueCategory.IssueCategory  
association[0..1] to I_DueDateStatus       as _DueDateStatus  on $projection.DueDateStatus = _DueDateStatus.DueDateStatus
association[0..1] to I_IsPotentialFutureIssue as _IsPotentialFutureIssue on $projection.IsPotentialFutureIssue = _IsPotentialFutureIssue.IsPotentialFutureIssue
association[0..1] to I_SalesDocumentType   as _SalesOrderType on  $projection.SalesOrderType = _SalesOrderType.SalesDocumentType
association[0..1] to I_SalesOrganization   as _SalesOrganization      on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
association[0..1] to I_DistributionChannel as _DistributionChannel    on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
association[0..1] to I_Division            as _OrganizationDivision   on  $projection.OrganizationDivision = _OrganizationDivision.Division


{
   //Key

   key Union_Issues.SalesOrder,
   key DeliveryDocument,
   key BillingDocument,
   key PurchasingDocument,
   key ManufacturingOrder,
      
   //Issue

   @ObjectModel.foreignKey.association: '_Issue'
   key Issue,
   _Issue,
   @ObjectModel.foreignKey.association: '_IssueCategory'
   IssueCategory,
   _IssueCategory,   
   @Semantics.text: true
   _IssueCategory._Text[1: Language=$session.system_language].IssueCategoryName as IssueCategoryName, --AT 7.8.19: needed to be used in C_Customer360_Issues
   @DefaultAggregation: #MIN
   cast(DueDays as due_days) as DueDays,   
   @ObjectModel.foreignKey.association: '_DueDateStatus'
   cast(  case when DueDays < 0 
             then 'A' 
             else
                case when DueDays = 0 
                then 'B' 
                else 'C' 
                end
          end as due_date_status )
    as DueDateStatus,
   _DueDateStatus,
   
   @ObjectModel.foreignKey.association: '_IsPotentialFutureIssue'   
   cast( case  when DueDays > 0  and ( Issue = 'SO05' or Issue = 'DE05' or Issue = 'IN02' or Issue = 'SU01'  )
          then '1'
          else '0'
         end as pot_future_issue )
   as IsPotentialFutureIssue,    
   _IsPotentialFutureIssue,
      
   //Counter

   @DefaultAggregation: #SUM
   NmbrOfIssuesInOrder,
   @DefaultAggregation: #SUM
   NmbrOfIssuesInDelivery,
   @DefaultAggregation: #SUM
   NmbrOfIssuesInInvoice,
   @DefaultAggregation: #SUM
   NmbrOfIssuesInSupply,
   @DefaultAggregation: #SUM                    
   NmbrOfAllIssues,
   @DefaultAggregation: #SUM
   cast(NmbrOfItemsInOrder as item_issues) as NmbrOfItemsInOrder,
   @DefaultAggregation: #SUM
   cast(NmbrOfItemsInDelivery as items_in_delivery) as NmbrOfItemsInDelivery,
   @DefaultAggregation: #SUM
   cast(NmbrOfItemsInSupply as items_in_supply) as NmbrOfItemsInSupply,
   
   //Issue Counter

    @DefaultAggregation: #SUM
    NmbrOfIssuesIncomplete, 
    @DefaultAggregation: #SUM
    NmbrOfIssuesDeliveryBlkd, 
    @DefaultAggregation: #SUM
    NmbrOfIssuesCreditBlocked, 
    @DefaultAggregation: #SUM
    NmbrOfIssuesBillingBlocked,
    @DefaultAggregation: #SUM
    NmbrOfIssuesOverdueDelivery,
    @DefaultAggregation: #SUM
    NmbrOfIssuesUnconfirmedQts,
    @DefaultAggregation: #SUM
    NmbrOfIssuesShippingBlocked,
    @DefaultAggregation: #SUM
    NmbrOfIssuesTradeCmplncIssue,
    @DefaultAggregation: #SUM
    NmbrOfIssuesMisgPurgOrder,    --AT1.2.2021 added for CE2108
    @DefaultAggregation: #SUM
    NmbrOfIssuesIncompleteInDeliv,
    @DefaultAggregation: #SUM
    NmbrOfIssuesCreditBlkdInDeliv,
    @DefaultAggregation: #SUM
    NmbrOfIssuesShippingIssue,
    @DefaultAggregation: #SUM
    NmbrOfIssuesNotTransferred,
    @DefaultAggregation: #SUM
    NmbrOfIssuesInvoicingIssue,
    @DefaultAggregation: #SUM
    NmbrOfIssuesPurchasingIssue,
    @DefaultAggregation: #SUM
    NmbrOfIssuesMfgIssue   ,
            
    //Category

    @ObjectModel.foreignKey.association: '_SalesOrderType'
    SalesOrderType,
    _SalesOrderType,
    ManufacturingOrderCategory, 
             
    //Organization  

    @ObjectModel.foreignKey.association: '_SalesOrganization'
    SalesOrganization,
    _SalesOrganization,
    @ObjectModel.foreignKey.association: '_DistributionChannel'
    DistributionChannel,
    _DistributionChannel,
    @ObjectModel.foreignKey.association: '_OrganizationDivision'   
    OrganizationDivision,
    _OrganizationDivision, 
    
    //Misc

    RequestedDeliveryDate,
    --OverallSDProcessStatus,  --AT14.2.2020 no longer needed after vbap enhancement
    SalesDocumentDate,
    SalesGroup,
    SalesOffice,
    SoldToParty--,
    --PurchaseOrderByCustomer --AT11.08.2020 VBKD-BSTKD no longer provided by issues (no true hdr attribute & too expensive)

    
};