I_ROUTINGHEADER

CDS View

Routing Header Details

I_ROUTINGHEADER is a CDS View in S/4HANA. Routing Header Details. It contains 22 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 22 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_ProductionRoutingHeaderTP view_entity from TRANSACTIONAL Transaction View for Production Routing Header
I_RoutingSequence view inner BASIC Routing Sequence Details
R_ProductionRoutingHeaderTP_2 view_entity from TRANSACTIONAL Production Routing Header

Fields (22)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup ProductionRoutingGroup 2
KEY BillOfOperationsVariant ProductionRouting 2
KEY BOOInternalVersionCounter BOOInternalVersionCounter,ProductionRoutingInternalVers 3
BillOfOperationsDesc BillOfOperationsDesc 2
BillOfOperationsStatus BillOfOperationsStatus 2
BillOfOperationsUnit BillOfOperationsUnit 3
BillOfOperationsUsage BillOfOperationsUsage 2
ChangeNumber ChangeNumber 2
CreatedByUser CreatedByUser 2
CreationDate CreationDate 2
LastChangeDate LastChangeDate 2
LastChangedByUser LastChangedByUser 2
MaximumLotSizeQuantity MaximumLotSizeQuantity 2
MinimumLotSizeQuantity MinimumLotSizeQuantity 2
PlainLongText PlainLongText 2
Plant Plant 2
ReplacedBillOfOperations ReplacedBillOfOperations 1
ResponsiblePlannerGroup ResponsiblePlannerGroup 2
ValidityEndDate ValidityEndDate 2
ValidityStartDate ValidityStartDate 2
WorkCenterInternalID WorkCenterInternalID 1
WorkCenterTypeCode WorkCenterTypeCode 1 
//@AbapCatalog.sqlViewName: 'IRTGHDR'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
//@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'BOOInternalVersionCounter'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Routing Header Details'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
//define view I_RoutingHeader

define view entity I_RoutingHeader
  as select from I_MfgBillOfOperationsChgSt
  association [0..1] to I_TaskListLongText as _LongText on  $projection.BillOfOperationsType      = _LongText.TaskListType
                                                        and $projection.BillOfOperationsGroup     = _LongText.TaskListGroup
                                                        and $projection.BillOfOperationsVariant   = _LongText.TaskListGroupCounter
                                                        and $projection.BOOInternalVersionCounter = _LongText.TaskListVersionCounter
                                                        and $projection.LongTextLanguageCode      is not null
{
  key BillOfOperationsType,
  key BillOfOperationsGroup,
  key BillOfOperationsVariant,
  key BOOInternalVersionCounter,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Semantics.businessDate.to: true
      ValidityEndDate,
      ChangeNumber,
      IsMarkedForDeletion, //DELKZ

      IsDeleted,           //LOEKZ

      IsImplicitlyDeleted, //LOEKZ_INHERITED

      @Semantics.text: true
      BillOfOperationsDesc,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      LongTextLanguageCode,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      BillOfOperationsUsage,
      @ObjectModel.foreignKey.association: '_BillOfOperationsStatus'
      BillOfOperationsStatus,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MIN
      MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MAX
      MaximumLotSizeQuantity,
      //      @Semantics.unitOfMeasure: true

      BillOfOperationsUnit,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      ChangedDateTime,
      //      @Consumption.hidden: true

      _LongText.PlainLongText,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      ResponsiblePlannerGroup,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      WorkCenterInternalID,
      ReplacedBillOfOperations,

      /*    Associations    */
      _BillOfOperations,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsUsage,
      _BillOfOperationsStatus,
      _BillOfOperationsUnit,
      _Plant,
      _LongTextLanguage,
      _ChangeMaster,
      _ResponsiblePlannerGroup,
      /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
      _WorkCenter,
      /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
      _WorkCenterType
}
where
      BillOfOperationsType =  'N'
  and ValidityEndDate      >= ValidityStartDate

Learn More