I_RECIPEPROCESSPARAMVALUETXTTP

CDS View

Recipe Process Parameter Value Description (Tr Proc)

I_RECIPEPROCESSPARAMVALUETXTTP is a CDS View in S/4HANA. Recipe Process Parameter Value Description (Tr Proc). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeProcessParamValueTxt view_entity from CONSUMPTION Recipe Process Parameter Value Descriptions 
@AbapCatalog.sqlViewName: 'IRPRPARAMVALTXTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'RecipeProcessParamValUUID'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe Process Parameter Value Description (Tr Proc)'
define view I_RecipeProcessParamValueTxtTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessParamValueText

  association        to parent I_RecipeProcessParamValueTP as _RecipeProcessParamValueTP on $projection.RecipeProcessParamValUUID = _RecipeProcessParamValueTP.RecipeProcessParamValUUID
  association [1..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language

{
  key RecipeProcessParamValUUID,
  key Language,

      RecipeProcessUUID,
      RecipeProcessParamValueDesc,

      // for ETag handling

      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeUUID,

      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessEquipRqmtPosNmbr,
      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessStagePosNmbr,
      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessOperationPosNmbr,
      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessActionPosNmbr,
      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessParamSqncNmbr,

      /* Associations */
      _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP as _RcpForKeyDateTP,
      _RecipeProcessParamValueTP,
      _Language
}
where
  _RecipeProcessParamValueTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime is not null

Learn More