I_RECIPEPROCESSPARAMVALUETP

CDS View

Recipe Process Parameter Value (Transactional Processing)

I_RECIPEPROCESSPARAMVALUETP is a CDS View in S/4HANA. Recipe Process Parameter Value (Transactional Processing). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeProcessParamValue view_entity from CONSUMPTION Recipe Process Parameter Values 
@AbapCatalog.sqlViewName: 'IRPRPARAMVALTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'RecipeProcessParamValUUID'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Recipe Process Parameter Value (Transactional Processing)'

define view I_RecipeProcessParamValueTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessParamValue
  association        to parent I_RecipeForKeyDateTP    as _RecipeForKeyDateTP       on $projection.RecipeUUID = _RecipeForKeyDateTP.RecipeUUID
  association [0..1] to I_RecipeProcessParam           as _RecipeProcessParam       on $projection.RecipeProcessParamUUID = _RecipeProcessParam.RecipeProcessParamUUID
  association [0..1] to I_RecipeProcessElementTP       as _RecipeProcessElementTP   on $projection.RecipeProcessElementUUID = _RecipeProcessElementTP.RecipeProcessElementUUID
  association [0..1] to I_RecipeProcessEquipRqmtTP     as _RecipeProcessEquipRqmtTP on $projection.RecipeProcessEquipRqmtUUID = _RecipeProcessEquipRqmtTP.RecipeProcessEquipRqmtUUID

  // Texts

  composition [0..*] of I_RecipeProcessParamValueTxtTP as _RecipeProcessParamValueTxtTP

{
  key RecipeProcessParamValUUID,

      RecipeProcessUUID,

      RecipeProcessElementUUID,
      RecipeProcessParamUUID,
      RecipeProcessEquipRqmtUUID,

      RecipeProcessParamUnit,
      RecipeProcessParamTgtVal,
      RecipeProcessParamMinVal,
      RecipeProcessParamMaxVal,
      RecipeProcessParamSqncNmbr,

      // for ETag handling

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      RecipeUUID,

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      _RecipeProcessParam.RecipeProcessParam,
      _RecipeProcessEquipRqmtTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessEquipRqmtPosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessStagePosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessOperationPosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessActionPosNmbr,

      _RecipeProcessParam,
      _RecipeForKeyDateTP,
      _RecipeProcessParamValueTxtTP
}
where
  _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime is not null

Learn More