I_RECIPEPROCESSEQUIPRQMTTP

CDS View

Recipe Process Equipment Requirement (Transactional Proc)

I_RECIPEPROCESSEQUIPRQMTTP is a CDS View in S/4HANA. Recipe Process Equipment Requirement (Transactional Proc). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeProcessEquipRqmt view_entity from CONSUMPTION Recipe Equipment Requirements 
@AbapCatalog.sqlViewName: 'IRPREQUIPRQMTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'RecipeProcessEquipRqmtUUID'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Recipe Process Equipment Requirement (Transactional Proc)'

define view I_RecipeProcessEquipRqmtTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessEquipRqmt
  association        to parent I_RecipeForKeyDateTP    as _RecipeForKeyDateTP           on $projection.RecipeUUID = _RecipeForKeyDateTP.RecipeUUID
  association [0..1] to I_RecipeProcessElementTP       as _RecipeProcessElementTP       on $projection.RecipeProcessElementUUID = _RecipeProcessElementTP.RecipeProcessElementUUID

  // Texts

  composition [0..*] of I_RecipeProcessEquipRqmtTextTP as _RecipeProcessEquipRqmtTextTP
  association [0..*] to I_RecipeProcessParamValueTP    as _RecipeProcessEQRParamValueTP on $projection.RecipeProcessUUID = _RecipeProcessEQRParamValueTP.RecipeProcessUUID
{
  key RecipeProcessEquipRqmtUUID,
      RecipeProcessUUID,
      RecipeProcessElementUUID,
      RecipeProcessEquipRqmtPosNmbr,
      RecipeProcEquipRqmtIsPrimRsce,

      // for ETag handling

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      RecipeUUID,

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessStagePosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessOperationPosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessActionPosNmbr,

      _RecipeForKeyDateTP,
      _RecipeProcessEQRParamValueTP,

      // Texts

      _RecipeProcessEquipRqmtTextTP
}
where
  _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime is not null

Learn More