I_RECIPEPROCESSELEMENTTEXTTP

CDS View

Recipe Process Element Description (Transactional Proc)

I_RECIPEPROCESSELEMENTTEXTTP is a CDS View in S/4HANA. Recipe Process Element Description (Transactional Proc). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeProcessElementText view_entity from CONSUMPTION Recipe Process Element Descriptions 
@AbapCatalog.sqlViewName: 'IRPRELMNTTEXTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'RecipeProcessElementUUID'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe Process Element Description (Transactional Proc)'
define view I_RecipeProcessElementTextTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessElementText
  association to parent I_RecipeProcessElementTP as _RecipeProcessElementTP on $projection.RecipeProcessElementUUID = _RecipeProcessElementTP.RecipeProcessElementUUID
{

      @ObjectModel.foreignKey.association: '_RecipeProcessElementTP'
  key RecipeProcessElementUUID,

      @ObjectModel.foreignKey.association: '_Language'
  key Language,

      RecipeProcessUUID,

      RecipeProcessElementDesc,

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      // for ETag handling

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      //_RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeUUID,

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeUUID          as RecipeUUID,


      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessStagePosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessOperationPosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessActionPosNmbr,

      /* Associations */
      _Language,
      _RecipeProcessElementTP,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP as _RcpForKeyDateTP //max. 16 chars

}

Learn More