I_RECIPEPROCESSELEMENTTP

CDS View

Recipe Process Element (Transactional Proc)

I_RECIPEPROCESSELEMENTTP is a CDS View in S/4HANA. Recipe Process Element (Transactional Proc). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeProcessElement view_entity from CONSUMPTION Recipe Process Elements 
@AbapCatalog.sqlViewName: 'IRPROCELMNTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'RecipeProcessElementUUID'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe Process Element (Transactional Proc)'
define view I_RecipeProcessElementTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessElement
  composition [0..*] of I_RecipeProcessElementTextTP as _RecipeProcessElementText
  association        to parent I_RecipeForKeyDateTP         as _RecipeForKeyDateTP    on $projection.RecipeUUID = _RecipeForKeyDateTP.RecipeUUID

  association [0..*] to I_RecipeProcessParamValueTP  as _RecipeProcessElmntParamValTP on $projection.RecipeProcessElementUUID = _RecipeProcessElmntParamValTP.RecipeProcessElementUUID
  association [0..*] to I_RecipeProcessEquipRqmtTP   as _RecipeProcessEquipRqmt       on $projection.RecipeProcessElementUUID = _RecipeProcessEquipRqmt.RecipeProcessElementUUID
{
  key RecipeProcessElementUUID,

      RecipeProcessUUID,

      RecipeProcessElementPosNmbr,
      RecipeProcessElementType,
      RecipeProcessElementParentUUID,

      RecipeProcessStagePosNmbr,
      RecipeProcessOperationPosNmbr,
      RecipeProcessActionPosNmbr,
      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      // for ETag handling

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      RecipeUUID,

      _RecipeForKeyDateTP,
      _RecipeProcessElementText,
      _RecipeProcessElmntParamValTP,
      _RecipeProcessEquipRqmt
}

Learn More