I_RECIPEFMLAITEMFORKEYDATETP

CDS View

Recipe Formula Item for Key Date (Transactional Processing)

I_RECIPEFMLAITEMFORKEYDATETP is a CDS View in S/4HANA. Recipe Formula Item for Key Date (Transactional Processing). 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeFormulaItem view from COMPOSITE Recipe Formula Items 
@AbapCatalog.sqlViewName: 'IRCPRFOKDTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@Consumption.semanticObject: 'Recipe'

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'RcpFmlaItemUUID'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe Formula Item for Key Date (Transactional Processing)'
define view I_RecipeFmlaItemForKeyDateTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate )

  association [0..1] to I_SpecificationForKeyDate   as _SpecificationForKeyDate on $projection.SpecificationInternalID = _SpecificationForKeyDate.SpecificationInternalID
  association        to parent I_RecipeForKeyDateTP as _RecipeForKeyDateTP      on $projection.RecipeUUID = _RecipeForKeyDateTP.RecipeUUID

{
  key RcpFmlaItemUUID,
      RcpFmlaUUID,
      RcpFmlaItemSourceFmlaItemUUID,
      RcpFmlaItemPosition,
      RcpFmlaItemAlternativeItemPos,
      RcpFmlaItemType,
      SpecificationInternalID,
      _SpecificationForKeyDate(P_KeyDate:$parameters.P_KeyDate ).Specification,

      Material,
      RcpFmlaStreamUUID,
      RcpFmlaItemComponentType,
      RcpFmlaItemLowerLimit,
      RcpFmlaItemUpperLimit,
      RcpFmlaItemQuantity,
      RcpFmlaItemUnit,
      RcpFmlaItemExceptionCode,
      RcpFmlaItemScrapInPercent,
      RcpFmlaItemOverrunInPercent,
      RcpFmlaItemAlternativeItemUUID,
      RcpFmlaItemQuantityInKilogram,
      RcpFmlaItemZeroSign,
      RcpFmlaItemIsSelectedForCalc,
      RcpFmlaItemExplosionRecipeUUID,
      RcpFmlaCalculationType,
      RcpFmlaItemIsBalancingItem,
      RecipeFmlaItemAltvIsUsed,

      _SpecificationForKeyDate(P_KeyDate:$parameters.P_KeyDate).SpecificationType,
      _SpecificationForKeyDate(P_KeyDate:$parameters.P_KeyDate).SpecificationAuthznGroup,

      RecipeUUID,

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      _RecipeProcessElementAssgmt.RecipeProcessElementUUID,

      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessStageUUID,
      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessOperationUUID,
      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessActionUUID,

      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessStagePosNmbr,
      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessOperationPosNmbr,
      _RecipeProcessElementAssgmt._RecipeProcessElement.RecipeProcessActionPosNmbr,

      // for ETag handling

      _RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      /* Associations */
      _ComponentType,

      _RecipeForKeyDateTP,
      _SpecificationForKeyDate,
      _RecipeProcessElementAssgmt,
      _Product
}

Learn More