I_RECIPECHARCVALUETP

CDS View

TP for Recipe Charc Valuation

I_RECIPECHARCVALUETP is a CDS View in S/4HANA. TP for Recipe Charc Valuation. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeCharcValue view from CONSUMPTION Recipe Characteristic Values 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IRECCHRVALTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP for Recipe Charc Valuation'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view I_RecipeCharcValueTP 
  with parameters
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate:sydate
  as select from I_ClfnObjectCharcValForKeyDate( P_KeyDate:$parameters.P_KeyDate ) as Valuation
       join I_RecipeForKeyDateTP( P_KeyDate: $parameters.P_KeyDate ) as Recipe on
         Valuation.ClfnObjectID = bintohex( Recipe.RecipeUUID )
    
    association [1..1] to I_RecipeForKeyDateTP as _Recipe on
      $projection.RecipeUUID = _Recipe.RecipeUUID 
  {
    key Recipe.RecipeUUID,
    key Valuation.ClassType,
    key Valuation.CharcInternalID,
    key Valuation.CharcValuePositionNumber,
          
    $parameters.P_KeyDate as KeyDate,
    Valuation.CharcValueDependency,
    Valuation.CharcValue,
    Valuation.CharcFromNumericValue,  
    Valuation.CharcFromNumericValueUnit,
    Valuation.CharcToNumericValue,     
    Valuation.CharcToNumericValueUnit,
    Valuation.CharcFromDecimalValue,
    Valuation.CharcToDecimalValue,
    @Semantics.amount.currencyCode: 'Currency'
    Valuation.CharcFromAmount,
    @Semantics.amount.currencyCode: 'Currency'
    Valuation.CharcToAmount,
    @Semantics.currencyCode: true
    Valuation.Currency,
    Valuation.CharcFromDate,
    Valuation.CharcToDate,
    Valuation.CharcFromTime,
    Valuation.CharcToTime, 
    Valuation.CharacteristicAuthor,
    Valuation.ValidityStartDate,   
    Valuation.ValidityEndDate,
            
    _Recipe,
    Valuation._Characteristic
  }
    where
      Valuation.ClfnObjectTable = '/PLMB/RCP_RECIPE' and 
      Valuation.ClfnObjectType = 'O'

Learn More