I_RBLSITMFORKEYDTEDUEPERD

CDS View

Receivables for Key Date

I_RBLSITMFORKEYDTEDUEPERD is a CDS View in S/4HANA. Receivables for Key Date. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_RblsItmForKeyDteDuePerd view from CONSUMPTION Receivables for Key Date
I_ARCashCollTrackerOvwCube view from COMPOSITE AR Cash Collection Tracker Card - Cube
P_CollMgmtRblsItmForKeyDte view from COMPOSITE Collection Management Receivables items for key date 
@ObjectModel.usageType.sizeCategory: #XXL //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.serviceQuality: #X //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'IRBLSKDATDUE'
@VDM.viewType: #COMPOSITE
@Analytics: { dataCategory: #CUBE }
@Search.searchable: false // I_Region is annotated as true, hence this new must have an annotation for searchable

@EndUserText.label: 'Receivables for Key Date'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER, #CDS_MODELING_DATA_SOURCE ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
//@AbapCatalog.dbHints: [ {dbSystem: #HDB, hint: 'PREAGGR_BEFORE_UNION'},

//                        {dbSystem: #HDB, hint: 'JOIN_THRU_AGGR'},

//                        {dbSystem: #HDB, hint: 'USE_OLAP_PLAN'}

//                      ]

@AbapCatalog.viewEnhancementCategory: [ #PROJECTION_LIST , #GROUP_BY ]
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
//@Consumption.dbHints: [ 'NO_USE_HEX_PLAN' ]


define view I_RblsItmForKeyDteDuePerd
  with parameters
    P_KeyDate               : sydate,
    P_DisplayCurrency       : vdm_v_display_currency,
    P_ExchangeRateType      : kurst_curr,
    P_PeriodType            : fis_period_type

  as select from P_RblsItmForKeyDteRepConv( P_KeyDate: :P_KeyDate,
                                            P_DisplayCurrency: :P_DisplayCurrency,
                                            P_ExchangeRateType: :P_ExchangeRateType,
                                            P_PeriodType: :P_PeriodType  )

  association [0..1] to I_SpecialGLCode              as _SpecialGLCode         on  _SpecialGLCode.SpecialGLCode        = $projection.SpecialGLCode
                                                                               and _SpecialGLCode.FinancialAccountType = 'D' 
  association [0..1] to I_FinancialAccountType       as _FinancialAccountType on _FinancialAccountType.FinancialAccountType = $projection.FinancialAccountType                                                                     

  association [0..1] to I_GLAccountInChartOfAccounts as _GLAccount             on  _GLAccount.ChartOfAccounts = $projection.ChartOfAccounts
                                                                               and _GLAccount.GLAccount       = $projection.GLAccount

  association [0..1] to I_GLAccountInChartOfAccounts as _ReconciliationAccount on  _ReconciliationAccount.ChartOfAccounts = $projection.ChartOfAccounts
                                                                               and _ReconciliationAccount.GLAccount       = $projection.ReconciliationAccount

  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts       on  _ChartOfAccounts.ChartOfAccounts = $projection.ChartOfAccounts

  association [0..1] to I_AccountingClerk            as _AccountingClerk       on  _AccountingClerk.CompanyCode     = $projection.CompanyCode
                                                                               and _AccountingClerk.AccountingClerk = $projection.AccountingClerk

  association [0..1] to I_CustomerCompany            as _CustomerCompany       on  _CustomerCompany.CompanyCode = $projection.CompanyCode
                                                                               and _CustomerCompany.Customer    = $projection.Customer

  association [0..1] to I_Currency                   as _DisplayCurrency       on  _DisplayCurrency.Currency = $projection.DisplayCurrency
  
  association [0..1] to I_CompanyCode                as _Company               on  _Company.CompanyCode = $projection.CompanyCode
                                                                               
  association [0..1] to I_Customer                   as _Customer              on  _Customer.Customer = $projection.Customer
  
  association [0..1] to I_Country                    as _CustomerCountry            on  _CustomerCountry.Country = $projection.CustomerCountry
  
  association [0..1] to I_Region                     as _CustomerRegion             on  _CustomerRegion.Region  = $projection.CustomerRegion
                                                                                    and _CustomerRegion.Country = $projection.CustomerCountry  
  
  association [0..*] to P_RblsItmForKeyDteRepPeriod as _ReportingPeriod on _ReportingPeriod.CompanyCode = $projection.CompanyCode                                                                                                                                                            
  
{     
      @ObjectModel.foreignKey.association: '_Company'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_Customer'
  key Customer,      
      @ObjectModel.foreignKey.association: '_SpecialGLCode'
  key SpecialGLCode,      
      @ObjectModel.foreignKey.association: '_GLAccount'
  key GLAccount,
  
      @ObjectModel.foreignKey.association: '_CustomerCountry'
      cast( _Customer._AddressRepresentation.Country as farp_land1 )               as CustomerCountry,
      @ObjectModel.foreignKey.association: '_CustomerRegion'
      _Customer._AddressRepresentation.Region                                       as CustomerRegion,
      @ObjectModel.foreignKey.association: '_AccountingClerk'
      cast( _CustomerCompany.AccountingClerk as farp_busab )                          as AccountingClerk,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      cast( _Company.ChartOfAccounts as fis_ktopl )                                   as ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_ReconciliationAccount'
      cast( _CustomerCompany.ReconciliationAccount as farp_akont )                    as ReconciliationAccount,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      cast( 'D' as fis_koart ) as FinancialAccountType,
      
      _Customer.AuthorizationGroup,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_DisplayCurrency'
      DisplayCurrency,

//      ReportingPeriodStartDate,

//      ReportingPeriodEndDate,

      
      cast(_ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriod as fis_reporting_period) as ReportingPeriod,
      cast(_ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingYear as fis_reporting_year) as ReportingYear,
      cast(_ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriodStartDate as fis_rep_period_start_date) as ReportingPeriodStartDate,
      cast(_ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriodEndDate as fis_rep_period_end_date) as ReportingPeriodEndDate,
      
//      cast('2021' as fis_reporting_year) as ReportingYear, 

//      cast('001' as fis_reporting_period) as ReportingPeriod, 

//      cast(ReportingPeriodStartDate as fis_rep_period_start_date) as ReportingPeriodStartDate,

//      cast(ReportingPeriodEndDate as fis_rep_period_end_date) as ReportingPeriodEndDate,


      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(NetDueIntvl1AmtInDspCrcy) as NetDueIntvl1AmtInDspCrcy,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(NetDueIntvl2AmtInDspCrcy) as NetDueIntvl2AmtInDspCrcy,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(NetDueIntvl3AmtInDspCrcy) as NetDueIntvl3AmtInDspCrcy,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(PartialPaymentAmtInDspCrcy) as PartialPaymentAmtInDspCrcy,

      _Company,
      _Customer,
      _CustomerRegion,
      _CustomerCountry,
      _CustomerCompany,
      _AccountingClerk,
      _SpecialGLCode,
      _GLAccount,
      _ReconciliationAccount,
      _ChartOfAccounts,
      _FinancialAccountType,
      _DisplayCurrency
//      _ReportingPeriod

}
group by
  CompanyCode,
  Customer,
  SpecialGLCode,
  GLAccount,
  DisplayCurrency,
  _CustomerCompany.ReconciliationAccount,
  _CustomerCompany.AccountingClerk,
  _Customer.AuthorizationGroup,
  _Customer._AddressRepresentation.Country,
  _Customer._AddressRepresentation.Region,
  _Customer.AuthorizationGroup,
  _Company.ChartOfAccounts,
//  FinancialAccountType,

//  DisplayCurrency,

  _ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriod,
  _ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingYear,
  _ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriodStartDate,
  _ReportingPeriod( P_KeyDate: :P_KeyDate, P_PeriodType: :P_PeriodType ).ReportingPeriodEndDate
//  ReportingYear,

//  ReportingPeriodStartDate,

//  ReportingPeriodEndDate

Learn More