I_RECONTRCONDITIONCALCULATION

CDS View

RE Condition Calculation Factors

I_RECONTRCONDITIONCALCULATION is a CDS View in S/4HANA. RE Condition Calculation Factors. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REContractConditionCalc view from CONSUMPTION RE Contract Condition Calculation 
//@AbapCatalog.sqlViewName: 'IRECNDNCALC'

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@VDM.viewType: #BASIC
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction.enabled: true,
  technicalName: 'IRECNDNCALC'
}
@ObjectModel: {
  representativeKey: 'RECndnCalculationUUID',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #L
  },
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [
    #ANALYTICAL_DIMENSION, 
    #CDS_MODELING_ASSOCIATION_TARGET,
    #EXTRACTION_DATA_SOURCE
  ],
  sapObjectNodeType.name: 'REContractConditionCalculation'
}
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@EndUserText.label: 'RE Condition Calculation Factors'

define view entity I_REContrConditionCalculation
  as select from vicdcondcalc
  association [1..1] to I_REContract      as _REContract      on $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [0..1] to I_Currency        as _Currency        on $projection.REConditionCurrency = _Currency.Currency
  association [1..1] to I_REConditionType as _REConditionType on $projection.REConditionType = _REConditionType.REConditionType
{
  key calcguid                                                 as RECndnCalculationUUID,
      condguid                                                 as REConditionUUID,
      intreno                                                  as InternalRealEstateNumber,
      objnr                                                    as REStatusObjectCalculation,
      @ObjectModel.foreignKey.association: '_REConditionType'
      condtype                                                 as REConditionType,
      condvalidfrom                                            as REConditionValidityStartDate,
      @Semantics.businessDate.from: true
      cast(valuevalidfrom as rebdvdmvalidfrom preserving type) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(valuevalidto as rebdvdmvalidto preserving type)     as ValidityEndDate,
      calcvalue                                                as REConditionCalculationFactor,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvalue                                                as REConditionItemAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      taxvalue                                                 as REConditionItemTaxAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluenet                                             as REConditionNetAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluegross                                           as REConditionGrossAmount,
      condcurr                                                 as REConditionCurrency,
      calcnumber                                               as RENumberOfCalculation,
      partner                                                  as BusinessPartner,
      partnerobjnr                                             as REPartnerStatusObject,
      duedate                                                  as REConditionDueDate,

      _REContract,
      _REConditionType,
      _Currency
} where intreno like 'IS%'

Learn More