I_RECIPEPROCESSELEMENT

CDS View

Recipe Process Element

I_RECIPEPROCESSELEMENT is a CDS View in S/4HANA. Recipe Process Element. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_RecipeProcessElementTP view from TRANSACTIONAL Recipe Process Element (Transactional Proc)
I_RecipeProcessElmntForKeyDate view from COMPOSITE Recipe Process Element for Key Date 
@AbapCatalog.sqlViewName: 'IRPRELEMENT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_ALLOWED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'RecipeProcessElementUUID'

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Recipe Process Element'

define view I_RecipeProcessElement
  as select from P_RecipeProcessElement
  // Texts

  association [0..*] to I_RecipeProcessElementText as _RecipeProcessStageDescription on $projection.RecipeProcessStageUUID = _RecipeProcessStageDescription.RecipeProcessElementUUID
  association [0..*] to I_RecipeProcessElementText as _RecipeProcessOperationDesc    on $projection.RecipeProcessOperationUUID = _RecipeProcessOperationDesc.RecipeProcessElementUUID
  association [0..*] to I_RecipeProcessElementText as _RecipeProcessActionDesc       on $projection.RecipeProcessActionUUID = _RecipeProcessActionDesc.RecipeProcessElementUUID
  association [0..*] to I_RecipeProcessElementText as _RecipeProcessElementText      on $projection.RecipeProcessUUID = _RecipeProcessElementText.RecipeProcessUUID

  association [0..*] to I_RecipeProcessParamValue  as _RecipeProcessElementParamVal  on $projection.RecipeProcessElementUUID = _RecipeProcessElementParamVal.RecipeProcessElementUUID
  association [0..*] to I_RecipeProcessEquipRqmt   as _RecipeProcessEquipRqmt        on $projection.RecipeProcessElementUUID = _RecipeProcessEquipRqmt.RecipeProcessElementUUID
{
  key RecipeProcessElementUUID,

      RecipeProcessElementType,

      RecipeProcessStageUUID,
      RecipeProcessOperationUUID,
      RecipeProcessActionUUID,

      RecipeProcessUUID,

      RecipeProcessStagePosNmbr,
      RecipeProcessOperationPosNmbr,
      RecipeProcessActionPosNmbr,
      RecipeProcessElementPosNmbr,
      RecipeProcessElementParentUUID,

      _Recipe.RecipeUUID,

      /* Associations */
      _Recipe,

      // Texts

      _RecipeProcessStageDescription,
      _RecipeProcessOperationDesc,
      _RecipeProcessActionDesc,
      _RecipeProcessElementText,

      _RecipeProcessElementParamVal,
      _RecipeProcessEquipRqmt
}

Learn More