I_QLTYNOTIFICATIONTASK
Quality Notification Task
I_QLTYNOTIFICATIONTASK is a CDS View in S/4HANA. Quality Notification Task. It contains 38 fields. 2 CDS views read from this table.
CDS Views using this table (2)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| ESH_N_QUALITYNOTIFTASK | view | from | Anchor view -QUALITYNOTIFTASK | |
| R_QltyNotificationTaskTP | view_entity | from | TRANSACTIONAL | Quality Notification Task - TP |
Fields (38)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | NotificationTask | NotificationTask | 1 |
| KEY | QualityNotification | QualityNotification | 1 |
| _ContactPerson | _ContactPerson | 1 | |
| _Customer | _Customer | 1 | |
| _Employee | _Employee | 1 | |
| _PartnerFunction | _PartnerFunction | 1 | |
| _Supplier | _Supplier | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationDate | CreationDate | 1 | |
| CreationTime | CreationTime | 1 | |
| IsBusinessPurposeCompleted | IsBusinessPurposeCompleted | 1 | |
| IsDeleted | IsDeleted | 1 | |
| LastChangeDate | LastChangeDate | 1 | |
| LastChangedByUser | LastChangedByUser | 1 | |
| LastChangeTime | LastChangeTime | 1 | |
| NotificationCauseID | NotificationCauseID | 1 | |
| NotificationItem | NotificationItem | 1 | |
| NotificationTaskSortNumber | NotificationTaskSortNumber | 1 | |
| NotificationTaskText | NotificationTaskText | 1 | |
| NotificationType | NotificationType | 1 | |
| NotifTaskCompletedByUser | NotifTaskCompletedByUser | 1 | |
| NotifTaskCompletionDate | NotifTaskCompletionDate | 1 | |
| NotifTaskCompletionTime | NotifTaskCompletionTime | 1 | |
| NotifTaskPlannedEndDate | NotifTaskPlannedEndDate | 1 | |
| NotifTaskPlannedEndTime | NotifTaskPlannedEndTime | 1 | |
| NotifTaskPlannedStartDate | NotifTaskPlannedStartDate | 1 | |
| NotifTaskPlannedStartTime | NotifTaskPlannedStartTime | 1 | |
| NotifTaskResubmissionDate | NotifTaskResubmissionDate | 1 | |
| NotifTaskResubmissionTime | NotifTaskResubmissionTime | 1 | |
| NotifTaskTimeZone | NotifTaskTimeZone | 1 | |
| Plant | Plant | 1 | |
| QltyTaskTimeBasedEffort | QltyTaskTimeBasedEffort | 1 | |
| QltyTaskTimeBasedEffortUoM | QltyTaskTimeBasedEffortUoM | 1 | |
| QualityTaskCode | QualityTaskCode | 1 | |
| QualityTaskCodeCatalog | QualityTaskCodeCatalog | 1 | |
| QualityTaskCodeGroup | QualityTaskCodeGroup | 1 | |
| ResponsiblePerson | PersonResponsible | 1 | |
| StatusObject | StatusObject | 1 |
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL' ]
@VDM: {
viewType: #COMPOSITE,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@EndUserText.label: 'Quality Notification Task'
@ObjectModel: {
representativeKey: 'NotificationTask',
supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
usageType: {
dataClass: #TRANSACTIONAL,
sizeCategory: #L,
serviceQuality: #A }
}
@Analytics.technicalName: 'IQNOTIFTSK'
@Metadata.ignorePropagatedAnnotations: true
define view entity I_QltyNotificationTask
as select from I_NotificationTask
inner join I_QltyNotification on I_NotificationTask.Notification = I_QltyNotification.QualityNotification
association [0..1] to I_QltyNotification as _Notification on $projection.QualityNotification = _Notification.QualityNotification
association [0..1] to I_QltyTskCodeGroup as _QltyTskCodeGroup on $projection.QualityTaskCodeGroup = _QltyTskCodeGroup.QualityTaskCodeGroup
association [0..1] to I_QltyTskCode as _QltyTskCode on $projection.QualityTaskCodeGroup = _QltyTskCode.QualityTaskCodeGroup
and $projection.QualityTaskCode = _QltyTskCode.QualityTaskCode
association [0..*] to I_QltyNotificationTaskLongText as _QltyNotificationTaskLongText on $projection.QualityNotification = _QltyNotificationTaskLongText.QualityNotification
and $projection.NotificationTask = _QltyNotificationTaskLongText.NotificationTask
////=== Unit
association [0..1] to I_UnitOfMeasure as _QltyTskProcTimeUnit on $projection.QltyTaskTimeBasedEffortUoM = _QltyTskProcTimeUnit.UnitOfMeasure
and _QltyTskProcTimeUnit.UnitOfMeasureDimension = 'TIME'
// === Extension
association [1..1] to E_NotificationTask as _Extension on $projection.QualityNotification = _Extension.Notification
and $projection.NotificationTask = _Extension.NotificationTask
{
//=== Key Fields
@ObjectModel.foreignKey.association: '_Notification'
key I_NotificationTask.Notification as QualityNotification,
key I_NotificationTask.NotificationTask,
// I_NotificationTask.QualityTask,
//@API.element.releaseState: #DEPRECATED
cast( ' ' as char16 preserving type ) as QualityTask,
//=== Common Fields
@ObjectModel.foreignKey.association: '_QualityTaskOrigin'
I_NotificationTask.QualityTaskOrigin,
@Semantics.text: true
I_NotificationTask.NotificationTaskText,
@Semantics.booleanIndicator: true
I_NotificationTask.IsDeleted,
I_QltyNotification.NotifProcessingPhase,
I_NotificationTask.NotifTaskPlannedStartDate,
I_NotificationTask.NotifTaskPlannedStartTime,
I_NotificationTask.NotifTaskPlannedEndDate,
I_NotificationTask.NotifTaskPlannedEndTime,
I_NotificationTask.StatusObject,
I_NotificationTask.NotifTaskTimeZone,
I_NotificationTask.NotifTaskCompletedByUser,
I_NotificationTask.NotifTaskCompletionDate,
I_NotificationTask.NotifTaskCompletionTime,
I_NotificationTask.NotifTaskResubmissionDate,
I_NotificationTask.NotifTaskResubmissionTime,
//Unfortunately we have to stay compliant with conversion exit
@ObjectModel.foreignKey.association: '_PartnerFunction'
cast(I_NotificationTask.ResponsiblePersonFunctionCode as qmsm_parvw preserving type ) as ResponsiblePersonFunctionCode,
I_NotificationTask.ResponsiblePerson,
I_NotificationTask.NotificationTaskSortNumber,
I_NotificationTask.NotificationItem,
I_NotificationTask.NotificationCauseID,
I_QltyNotification.NotificationType,
I_QltyNotification.Plant,
@Semantics.booleanIndicator: true
I_QltyNotification.IsBusinessPurposeCompleted,
cast( I_NotificationTask.NotificationTaskCatalog as vdm_qn_makat preserving type ) as QualityTaskCodeCatalog,
@ObjectModel.foreignKey.association: '_QltyTskCodeGroup'
cast( I_NotificationTask.NotificationTaskCodeGroup as vdm_qn_magrp preserving type ) as QualityTaskCodeGroup,
@ObjectModel.foreignKey.association: '_QltyTskCode'
I_NotificationTask.NotificationTaskCode as QualityTaskCode,
//====Time Recording for Task
@Semantics.quantity.unitOfMeasure: 'QltyTaskTimeBasedEffortUoM'
I_NotificationTask.QltyTaskTimeBasedEffort,
@ObjectModel.foreignKey.association: '_QltyTskProcTimeUnit'
I_NotificationTask.QltyTaskTimeBasedEffortUoM,
//=== Administrative Data
I_NotificationTask.ChangedDateTime,
@ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
I_NotificationTask.CreatedByUser,
@Semantics.systemDate.createdAt: true
I_NotificationTask.CreationDate,
I_NotificationTask.CreationTime,
@ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
I_NotificationTask.LastChangedByUser,
@Semantics.systemDate.lastChangedAt: true
I_NotificationTask.LastChangeDate,
I_NotificationTask.LastChangeTime,
//=== Expose Associations
_Notification,
I_NotificationTask._QualityTaskOrigin,
_QltyTskCodeGroup,
_QltyTskCode,
I_QltyNotification._Plant,
_QltyNotificationTaskLongText,
I_NotificationTask._CreatedByUserContactCard,
I_NotificationTask._LastChangedByUserContactCard,
I_NotificationTask._StsObjConcatActiveStsILL,
_QltyTskProcTimeUnit,
//Only included because of authorization check with DPP
@Consumption.hidden: true
I_NotificationTask._PartnerFunction,
@Consumption.hidden: true
I_NotificationTask._ContactPerson,
@Consumption.hidden: true
I_NotificationTask._Employee,
@Consumption.hidden: true
I_NotificationTask._Customer,
@Consumption.hidden: true
I_NotificationTask._Supplier
}