I_PURCHASEREQUISITIONTYPE

CDS View

Purchase Requisition Document Type

I_PURCHASEREQUISITIONTYPE is a CDS View in S/4HANA. Purchase Requisition Document Type. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_PurchaseRequisitionTypeDP view_entity from CONSUMPTION Purchase Requisition Type 
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PurchaseRequisitionType'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@AbapCatalog.sqlViewName: 'IPURREQNTYPE'
@EndUserText.label: 'Purchase Requisition Document Type'
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName:#LOCAL
@AccessControl.authorizationCheck:#NOT_REQUIRED
@ObjectModel.sapObjectNodeType.name: 'PurchaseRequisitionType'
@VDM.viewType : #BASIC
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, #SEARCHABLE_ENTITY,
                                     #EXTRACTION_DATA_SOURCE,
                                     #ANALYTICAL_DIMENSION ]
@Search.searchable: true
@Analytics.dataExtraction.enabled: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_PurchaseRequisitionType
  as select from I_PurchasingDocumentType

  association [0..*] to I_PurchasingDocumentTypeText as _Text on  $projection.PurchaseRequisitionType    = _Text.PurchasingDocumentType
                                                              and _Text.PurchasingDocumentCategory = 'B'

{

      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key PurchasingDocumentType as PurchaseRequisitionType,
      @EndUserText.label: 'Control Indicator'
      PurchasingDocumentSubtype,
      PurgHasFlxblWorkflowApproval,
      @EndUserText.label: 'Is Overall Release Enabled'
      IsPurReqnOvrlRel,
      _Text
}
where
  PurchasingDocumentCategory = 'B'

Learn More