I_PURCHASECONTRACTHISTORY

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'IRELEASEDOC'
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Purchase Contract Release Documentation'
@VDM.viewType : #BASIC
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view I_PurchaseContractHistory
  as select from ekab
  
  association [1..1] to I_PurchaseOrder    as _PurchaseOrder                on $projection.ReleaseOrder = _PurchaseOrder.PurchaseOrder


  association [0..1] to I_Currency         as _ReleaseOrderCurrency         on $projection.ReleaseOrderCurrency = _ReleaseOrderCurrency.Currency

  association [0..1] to I_UnitOfMeasure    as _ReleaseOrderItemQuantityUnit on $projection.ReleaseOrderItemQuantityUnit = _ReleaseOrderItemQuantityUnit.UnitOfMeasure

  --Added for DCL
  association [1..1] to I_PurchaseContract as _PurchaseContract             on $projection.PurchaseContract = _PurchaseContract.ActivePurchasingDocument

{

  key  konnr                                               as PurchaseContract,

  key  ktpnr                                               as PurchaseContractItem,

  key  cast ( ebeln as vdm_ebeln )                         as ReleaseOrder,

  key  ebelp                                               as ReleaseOrderItem,

       @Semantics.quantity.unitOfMeasure: 'ReleaseOrderItemQuantityUnit'
       @DefaultAggregation: #NONE
       menge                                               as ReleaseOrderItemOrderQuantity,

       @Semantics.amount.currencyCode: 'ReleaseOrderCurrency'
       @DefaultAggregation: #NONE
       netwr                                               as ReleaseOrderItemNetAmount,

       loekz                                               as ReleaseOrderItemIsDeleted,

       @Semantics.businessDate.at
       cast (bedat as mm_oa_rel_ord_date)                  as ReleaseOrderDate,

       @Semantics.unitOfMeasure: true
       meins                                               as ReleaseOrderItemQuantityUnit,

       @Semantics.currencyCode:true
       waers                                               as ReleaseOrderCurrency,

       @Semantics.businessDate.lastChangedAt: true
       aedat                                               as ReleaseOrderItemLastChgDate,

       // wkurs                              as  ExchangeRate,

       cast ( wkurs as fis_exchange_rate preserving type ) as ExchangeRate,


       bukrs                                               as CompanyCode,

       werks                                               as Plant,

       ekorg                                               as PurchasingOrganization,
       
       _PurchaseOrder,
       _ReleaseOrderCurrency,
       _ReleaseOrderItemQuantityUnit,
       --Added for DCL
       _PurchaseContract

}