I_PROJECTDEMANDTP

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AbapCatalog: {
 //   sqlViewName: 'IPROJECTDEMANDTP',

//    compiler.compareFilter: true,

    dataMaintenance: #RESTRICTED
 //   preserveKey:true

}

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

//@ClientHandling.algorithm: #SESSION_VARIABLE


@ObjectModel: {
   transactionalProcessingEnabled: true,

   sapObjectNodeType:{name: 'ProjectDemand'},
   semanticKey:       [ 'ProjectDemand' ],
   representativeKey: 'ProjectDemandUUID',

   usageType: {
     serviceQuality:  #B,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@AbapCatalog.extensibility : {
                              extensible    : true,
                              elementSuffix : 'PDM',
                              quota.maximumFields:  300 ,
                              quota.maximumBytes  : 45000 ,
                              dataSources : [ '_ProjectDemandExtension' ] 
                             }


@EndUserText.label: 'Project Demand - TP'
define root view entity I_ProjectDemandTP
  as select from R_ProjectDemand as ProjectDemand

  composition [0..1] of I_ProjectDemandMaterialTP      as _Material // will be limited by coding, validation required


  composition [0..1] of I_ProjectDemandServiceTP       as _Service  // will be limited by coding, validation required


  composition [0..1] of I_ProjectDemandWorkTP          as _Work     // will be limited by coding, validation required


  composition [0..1] of R_ProjectDemandExpenseTP       as _Expense

  // Cross-BO

  association [0..1] to I_EnterpriseProjectElementTP_2 as _ProjectElement on  _ProjectElement.ProjectElementUUID = $projection.ReferencedObjectUUID    
  
  //RAP migration changes . Bringing assocoation 1 level down

  association [0..1] to I_ProjectDemandWorkPackageText as _ProjectElementData           on $projection.ReferencedObjectUUID = _ProjectElementData.ProjectElementUUID
  association [0..1] to I_MngProjDmndSrvcPurReqnOrd    as _MngProjDmndSrvcPurReqnOrd    on $projection.ProjectDemandUUID = _MngProjDmndSrvcPurReqnOrd.ProjectDemandUUID
  association [0..1] to I_MngProjDmndMatlPurReqnOrd    as _ProjDmndMatlPurReqnOrd       on $projection.ProjectDemandUUID = _ProjDmndMatlPurReqnOrd.ProjectDemandUUID
  association [1]    to I_ProjDmndCalcdCatSpcfcFields  as _ProjDmndCalcCatSpecFields    on $projection.ProjectDemandUUID = _ProjDmndCalcCatSpecFields.ProjectDemandUUID
  association [1..1] to E_ProjectDemand                as _ProjectDemandExtension       on $projection.ProjectDemandUUID = _ProjectDemandExtension.ProjectDemandUUID
  // do NOT add the childrens children here, only put them into their parents especially this is then no composition!


{
      //I_ProjectDemand


  key ProjectDemandUUID,


      ProjectDemand,



      ProjectDemandName,


      ProjectDemandDescription,

      // this is derived from the Type and set implicitly!

      ProjectDemandCategory, // category not mandatory as being set by determination


      // can be changed only when created usually


      ProjectDemandType,
      
      ProjectUUID,

      // can only be changed until transfer


      ReferencedObjectUUID,

      // can only be changed until transfer

      ProjectDemandStatus,


      ProjectDemandDateMaintenance,
      // can be changed only when not synched

      // required before transfer

      ProjectDemandStartDate,
      // can be changed only when not synched

      // required before transfer

      ProjectDemandEndDate,

      ProjectDemandReleasedDateTime,

      ProjDmndActualSupplyDate,

      // can be changed only when created usually

      ProjectDemandPerUnitAmount,
      // can be changed only when created usually

      ProjectDemandRequestCurrency,

      // can be changed only when created usually

      ProjDmndRequestedQuantityUnit,
      // can be changed only when created usually

      PriceUnitQty,

      // can be changed only when created usually

      // can be changed only when created usually

      ProjectDemandRequestNetAmount,

      // can be changed only when created usually

      ProjDmndReqNetAmountCurrency,


      // can be changed only when created usually

      ProjectDemandOverallAmount,


      ProjDmndRequestedQuantity,

      // Mandatory before requested

      Plant,

      // Mandatory before requested

      PurchasingGroup,


      PurchasingOrganization,

      ProjectDemandLastUpdateSource,

      CreatedByUser,

      CreationDateTime,

      LastChangedByUser,

      LastChangeDateTime,

      ProjectDemandLastChangedByUser,

      ProjDemandLastChangeDateTime,
      
      ProjDmndExternalReferenceUUID,
      
      ProjectDemandOverallRevenue,
      
      ProjDmndOverallRevenueCurrency,
      
      ProjDmndDataModelVersion,
      
      /* Associations */
      // BO internal associations


      _Material,

      _Service,

      _Work,
      _Expense,

      // external associations


      //I_ProjectDemand

      _ProjectDemandCategory,
      _ProjectDemandType,
      _Project,
      _WorkPackage,
      _ProjectDemandStatus,
      _ProjDmndLastUpdateSource,

      _ProjectDemandCurrency,
      _ProjectDemandNetCurrency,
      _ProjDmndQuantityUnit,
      _ProjectElementData,
      _Plant,
      _PurchasingGroup,
      _PurchasingOrganisation,
      _MngProjDmndSrvcPurReqnOrd,
      _ProjDmndMatlPurReqnOrd,
      _ProjDmndCalcCatSpecFields,
      _ProjectDemandVH,
      @Consumption.hidden: true
      _EnterpriseProjectForUser,
      
      // Cross BO

      _ProjectElement
//      _ProjectdemandExtension

}