I_PRODSPECNONHISTORIC

CDS View

Product Specification Non Historic

I_PRODSPECNONHISTORIC is a CDS View in S/4HANA. Product Specification Non Historic. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_ProdSpecDescNonHistoric view inner COMPOSITE Product Specification Desc. Non Hist.
I_ProdSpecDescription view inner COMPOSITE Product Specification Description
I_ProdSpecNonHistoricTP view_entity from TRANSACTIONAL Product Specification Non Historic (TP)
R_ProdSpecCmpstnHdrWithUsage view inner COMPOSITE Product Spec. Comp. Header with Usage 
@AbapCatalog.sqlViewName: 'IPRODSPECNONHIS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Product Specification Non Historic'
define view I_ProdSpecNonHistoric
  as select distinct from I_Specification           as _Specification
    inner join            I_ProdSpecType            as _ProdSpecType            on _Specification.SpecificationType = _ProdSpecType.SpecificationType
    inner join            I_SpecificationLastChange as _SpecificationLastChange on _Specification.SpecificationInternalID = _SpecificationLastChange.SpecificationInternalID

  // Association to historical views

  association [1..*] to I_ProductSpecification         as _ProductSpecification         on $projection.ProductSpecificationInternalID = _ProductSpecification.ProductSpecificationInternalID

  // Association to non-historical views

  association [0..*] to I_ProdSpecDescNonHistoric      as _ProdSpecDescNonHistoric      on $projection.ProductSpecificationInternalID = _ProdSpecDescNonHistoric.ProductSpecificationInternalID

  association [0..*] to I_PrSpAllgnCmpstnHdrNonHist    as _PrSpAllgnCmpstnHdrNonHist    on $projection.ProductSpecificationInternalID = _PrSpAllgnCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_ProdSpecStdCmpstnHdrNonHist  as _ProdSpecStdCmpstnHdrNonHist  on $projection.ProductSpecificationInternalID = _ProdSpecStdCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_PrSpNtrntCmpstnHdrNonHist    as _PrSpNtrntCmpstnHdrNonHist    on $projection.ProductSpecificationInternalID = _PrSpNtrntCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_ProdSpecCmpstnHdrNonHist     as _ProdSpecCmpstnHdrNonHist     on $projection.ProductSpecificationInternalID = _ProdSpecCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_PrSpQtytvCmpstnHdrNonHist    as _PrSpQtytvCmpstnHdrNonHist    on $projection.ProductSpecificationInternalID = _PrSpQtytvCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_PrSpQltatvCmpstnHdrNonHist   as _PrSpQltatvCmpstnHdrNonHist   on $projection.ProductSpecificationInternalID = _PrSpQltatvCmpstnHdrNonHist.ProductSpecificationInternalID

  association [0..*] to I_ProdSpecLstgCmpstnHdrNonHist as _ProdSpecLstgCmpstnHdrNonHist on $projection.ProductSpecificationInternalID = _ProdSpecLstgCmpstnHdrNonHist.ProductSpecificationInternalID

{
  key _Specification.SpecificationInternalID                                  as ProductSpecificationInternalID,

      cast( Specification as /plmb/spc_prod_spec_ext_id_api preserving type ) as ProductSpecification,

      _Specification.SpecificationType                                        as ProdSpecType,

      _SpecificationLastChange.SpecLastChangeDateTime                         as ProdSpecRootLastChgDteTmeTxt,
      // Associations

      _ProductSpecification,
      _ProdSpecDescNonHistoric,
      _PrSpAllgnCmpstnHdrNonHist,
      _ProdSpecStdCmpstnHdrNonHist,
      _PrSpNtrntCmpstnHdrNonHist,
      _ProdSpecCmpstnHdrNonHist,
      _PrSpQtytvCmpstnHdrNonHist,
      _PrSpQltatvCmpstnHdrNonHist,
      _ProdSpecLstgCmpstnHdrNonHist
}

Learn More