I_PRODSPECCOMPONENTBASEUOM

CDS View

Prod Specification Component Base UoM

I_PRODSPECCOMPONENTBASEUOM is a CDS View in S/4HANA. Prod Specification Component Base UoM. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_ProdSpecComponentBaseUoM view from COMPOSITE Base UoM for Specification Type 
@AbapCatalog.sqlViewName: 'IPRSPCOMPUOM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER


@EndUserText.label: 'Prod Specification Component Base UoM'
define view I_ProdSpecComponentBaseUoM
  with parameters
    @Semantics.businessDate.at: true
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_SpecCharByValueAssgmtInst( P_KeyDate : $parameters.P_KeyDate ) as speccharbyvalueassgmtinst
    inner join   I_ProdSpecComponent                                              as prodspecomponent          on speccharbyvalueassgmtinst.SpecificationInternalID = prodspecomponent.ProdSpecComponentInternalID
    inner join   I_SpecTypeBaseUnitOfMeasure                                      as spectypebaseunitofmeasure on  spectypebaseunitofmeasure.ProdSpecCmpstnSpecType         = prodspecomponent.SpecificationType
                                                                                                               and spectypebaseunitofmeasure.ProdSpecBaseUnitValAssgmtType  = speccharbyvalueassgmtinst.SpecValAssgmtType
                                                                                                               and spectypebaseunitofmeasure.ProdSpecBaseUnitCharacteristic = speccharbyvalueassgmtinst.Characteristic
                                                                                                               and spectypebaseunitofmeasure.ProdSpecCmpstnHdrRating        = speccharbyvalueassgmtinst.SpecificationRating
                                                                                                               and spectypebaseunitofmeasure.ProdSpecCmpstnHdrValidityArea  = speccharbyvalueassgmtinst.SpecificationValidityArea
                                                                                                               and speccharbyvalueassgmtinst.SpecValAssgmtUsageIsExcluded   = ''
                                                                                                               and speccharbyvalueassgmtinst.SpecValAssgmtUsageIsActive     = 'X'
  association [1..1] to I_ProdSpecComponent as _ProdSpecComponent on $projection.ProdSpecComponentInternalID = _ProdSpecComponent.ProdSpecComponentInternalID
{
  key prodspecomponent.ProdSpecComponentInternalID,

      cast( CharacteristicValue as /plmb/spc_nutr_base_uom preserving type ) as ProdSpecCompBaseUnitOfMeasure,

      @Consumption.hidden: true
      speccharbyvalueassgmtinst.Characteristic,

      @Consumption.hidden: true
      speccharbyvalueassgmtinst.SpecValAssgmtType,
      @Consumption.hidden: true
      speccharbyvalueassgmtinst.SpecificationRating,
      @Consumption.hidden: true
      speccharbyvalueassgmtinst.SpecificationValidityArea,

      _ProdSpecComponent

}
where
      SpecValAssgmtUsageIsActive   = 'X'
  and SpecValAssgmtUsageIsExcluded = ''

Learn More