I_PROBSOLVINGPROCCAUSE

CDS View

Problem-Solving Process Cause

I_PROBSOLVINGPROCCAUSE is a CDS View in S/4HANA. Problem-Solving Process Cause. It contains 13 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 13 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ProbSolvingProcCauseTP view from TRANSACTIONAL Problem-Solving Process Cause

Fields (13)

KeyField CDS FieldsUsed in Views
KEY ProbSolvingProc ProbSolvingProc 1
KEY ProbSolvingProcCause ProbSolvingProcCause 1
_CreatedByUserContactCard _CreatedByUserContactCard 1
_DefectCauseCode _DefectCauseCode 1
_DefectCauseCodeGroup _DefectCauseCodeGroup 1
_LastChangedByUserContactCard _LastChangedByUserContactCard 1
CreatedByUser CreatedByUser 1
DefectCauseCode DefectCauseCode 1
DefectCauseCodeGroup DefectCauseCodeGroup 1
LastChangedByUser LastChangedByUser 1
ProbSolvingCauseCrtedDateTime ProbSolvingCauseCrtedDateTime 1
ProbSolvingCauseLastChgdDteTme ProbSolvingCauseLastChgdDteTme 1
ProbSolvingProcCauseDesc ProbSolvingProcCauseDesc 1 
@EndUserText.label: 'Problem-Solving Process Cause'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #A },
    representativeKey: 'ProbSolvingProcCause',
    semanticKey:  [ 'ProbSolvingProc', 'ProbSolvingProcCause' ]
}
@Analytics.technicalName: 'IPRSOLPROCCAUSE'

define view entity I_ProbSolvingProcCause as select from qprbslvprccause

  association [1..1] to I_ProbSolvingProc as _ProbSolvingProc on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
  association [0..*] to I_ProbSolvingProcCauseLongT as _ProbSolvingProcCauseLongT on $projection.ProbSolvingProc = _ProbSolvingProcCauseLongT.ProbSolvingProc

// Code Group/ Code

  association [0..1] to I_DefectCauseCodeGroup as _DefectCauseCodeGroup        on  $projection.DefectCauseCodeGroup    = _DefectCauseCodeGroup.DefectCauseCodeGroup
  association [0..1] to I_DefectCauseCode      as _DefectCauseCode             on  $projection.DefectCauseCodeGroup    = _DefectCauseCode.DefectCauseCodeGroup
                                                                               and $projection.DefectCauseCode         = _DefectCauseCode.DefectCauseCode

// Contact card

  association [0..1] to I_UserContactCard      as _CreatedByUserContactCard     on $projection.CreatedByUser     = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard      as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID

{
      @ObjectModel.foreignKey.association: '_ProbSolvingProc'
  key probsolvingprocess       as ProbSolvingProc,
      @ObjectModel.text.element: ['ProbSolvingProcCauseDesc']
  key prbobsolvproccause       as ProbSolvingProcCause,
  
      @Semantics.text: true
      description              as ProbSolvingProcCauseDesc,

      @ObjectModel.foreignKey.association: '_DefectCauseCodeGroup'
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_DefectCauseCodeGroupStdVH',
                     element: 'DefectCauseCodeGroup' }
        }]
      codegroup                as DefectCauseCodeGroup,

      @ObjectModel.foreignKey.association: '_DefectCauseCode'
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_DefectCauseCodeStdVH',
                     element: 'DefectCauseCode' },
          additionalBinding: [{ localElement: 'DefectCauseCodeGroup',
                                element: 'DefectCauseCodeGroup' }]
        }]
      code                     as DefectCauseCode,

//    Admin Data

      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      @Semantics.user.createdBy: true
      created_by               as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      created_on               as ProbSolvingCauseCrtedDateTime,

      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      @Semantics.user.lastChangedBy: true
      changed_by               as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      changed_on               as ProbSolvingCauseLastChgdDteTme,

//=== exposed associations      

      _ProbSolvingProc,
      _ProbSolvingProcCauseLongT,
      _DefectCauseCodeGroup,
      _DefectCauseCode,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard
      
}

Learn More