I_PROBSOLVINGPROC

CDS View

Problem-Solving Process

I_PROBSOLVINGPROC is a CDS View in S/4HANA. Problem-Solving Process. It contains 16 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 16 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_ProbSolvingProcStp view inner BASIC Problem-Solving Process Step
I_ProbSolvingProcTP view from TRANSACTIONAL Problem-Solving Process
I_ProbSolvingProcVH view_entity from COMPOSITE Problem-Solving Process

Fields (16)

KeyField CDS FieldsUsed in Views
KEY ProbSolvingProc ProbSolvingProc 1
_CreatedByUserContactCard _CreatedByUserContactCard 1
_LastChangedByUserContactCard _LastChangedByUserContactCard 1
_ProbSolvingProcType _ProbSolvingProcType 1
ChangedDateTime ChangedDateTime 1
CreatedByUser CreatedByUser 1
LastChangedByUser LastChangedByUser 1
MasterLanguage MasterLanguage 1
Material Material 1
Plant Plant 1
ProbSolvingProcCreatedDateTime ProbSolvingProcCreatedDateTime 1
ProbSolvingProcDesc ProbSolvingProcDesc 1
ProbSolvingProcLastChgdDteTme ProbSolvingProcLastChgdDteTme 1
ProbSolvingProcLifecycleStatus ProbSolvingProcLifecycleStatus 1
ProbSolvingProcTsksArchivedSts ProbSolvingProcTsksArchivedSts 1
ProbSolvingProcType ProbSolvingProcType 2 
@EndUserText.label: 'Problem-Solving Process'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #A },
    representativeKey: 'ProbSolvingProc',
    semanticKey:  [ 'ProbSolvingProc' ]
}
@Analytics.technicalName: 'IPRSOLPROC'

define view entity I_ProbSolvingProc as select from qprobsolvproc 

//=== associations to other views

   association [0..1] to I_Product as _Product on $projection.Material = _Product.Product 
   association [1..1] to I_ProbSolvingProcType as _ProbSolvingProcType on $projection.ProbSolvingProcType = _ProbSolvingProcType.ProbSolvingProcType
   association [0..1] to I_ProbSolvingProcLfcycSts as _ProbSolvingProcLfcycSts on $projection.ProbSolvingProcLifecycleStatus = _ProbSolvingProcLfcycSts.ProbSolvingProcLifecycleStatus
   association [0..1] to I_Plant    as _Plant                                  on $projection.Plant = _Plant.Plant  

//=== contact card

    association [0..1] to I_UserContactCard         as _CreatedByUserContactCard     on $projection.CreatedByUser     = _CreatedByUserContactCard.ContactCardID
    association [0..1] to I_UserContactCard         as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID

 //=== other views

    association [1..1] to I_Language as _Language on $projection.MasterLanguage = _Language.Language
    
{
  @ObjectModel.text.element: ['ProbSolvingProcDesc']
  key probsolvingprocess  as ProbSolvingProc,
      
      @Semantics.text: true
      description             as ProbSolvingProcDesc,
      @ObjectModel.foreignKey.association: '_ProbSolvingProcType'
      processtype             as ProbSolvingProcType,
      @ObjectModel.foreignKey.association: '_Product'
      material                as Material,
      @ObjectModel.foreignKey.association: '_Plant'
      plant                   as Plant,
      @ObjectModel.foreignKey.association: '_Language'
      cast( masterlanguage    as vdm_j_masterlanguage )  as MasterLanguage,
      
//=== status

      @ObjectModel.foreignKey.association: '_ProbSolvingProcLfcycSts'
      @ObjectModel.readOnly: true
      @Consumption: {
              valueHelpDefinition: [ 
                          { entity:  { name:    'I_ProbSolvingProcLfcycSts',
                                       element: 'ProbSolvingProcLifecycleStatus' }
                          }]   
      }
      statlcycle              as ProbSolvingProcLifecycleStatus,
      stattasksarch           as ProbSolvingProcTsksArchivedSts,

//=== administrative data

      @ObjectModel.readOnly: true
      changeddatetime         as ChangedDateTime,

      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      @ObjectModel.readOnly: true
      @Semantics.user.createdBy: true
      @Consumption.valueHelpDefinition: [{ entity.name: 'I_ProbSolvingProcUserVH', entity.element: 'UserID' }]
      created_by              as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      created_on              as ProbSolvingProcCreatedDateTime,

      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      @ObjectModel.readOnly: true
      @Semantics.user.lastChangedBy: true
      @Consumption.valueHelpDefinition: [{ entity.name: 'I_ProbSolvingProcUserVH', entity.element: 'UserID' }]
      changed_by              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      changed_on              as ProbSolvingProcLastChgdDteTme,
  
//=== exposed associations

      _Product,
      _Plant,
      _ProbSolvingProcLfcycSts,
      _Language,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _ProbSolvingProcType
}

Learn More