I_PRICINGDATECONTROLTXT

CDS View

Pricing Date Control - Text

I_PRICINGDATECONTROLTXT is a CDS View in S/4HANA. Pricing Date Control - Text. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_MM_PriceDateCatValueHelp view from CONSUMPTION Price date category
C_PricingDateControlTextDP view_entity from CONSUMPTION Pricing Date Control - Text 
@AbapCatalog.sqlViewName: 'IMMPRCDATCNTRLT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.dataCategory: #TEXT
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PricingDateControl'
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@VDM.viewType: #BASIC
@Search.searchable: true
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Pricing Date Control - Text'
@ObjectModel.sapObjectNodeType.name: 'PricingDateControlText'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT

define view I_PricingDateControlTxt
  as select from dd07t
  association        to parent I_PricingDateControl as _PricingDateControl on $projection.PricingDateControl = _PricingDateControl.PricingDateControl
  association [0..1] to I_Language                  as _Language           on $projection.Language = _Language.Language
{

      @ObjectModel.foreignKey.association: '_PricingDateControl'
      @ObjectModel.text.element: ['PricingDateControlText']
  key cast ( substring( domvalue_l, 1, 1 ) as meprf )   as PricingDateControl,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,

      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      dd07t.ddtext                                      as PricingDateControlText,

      _PricingDateControl,

      _Language
}
where
      domname        = 'MEPRF'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More