I_PROJECTBILLINGREQUEST

CDS View

Project Billing Request

I_PROJECTBILLINGREQUEST is a CDS View in S/4HANA. Project Billing Request. It contains 15 fields. 11 CDS views read from this table.

Used by 11 CDS view(s) 15 fields

CDS Views using this table (11)

ViewTypeJoinVDMDescription
I_PrjBlgReqWrkflwLdngObj view_entity from BASIC Project Billing WF Leading Object
I_ProjectBillingRequestTP view_entity from TRANSACTIONAL Details of Project Billing Request
I_TmpProjectBillingRequest view_entity inner COMPOSITE Temporary Project Billing Request
P_BillgDocProcFlowPrjBlgReq view_entity from BASIC Project billing request in process flow
P_PrjBlgElmBillingReqRevnAmt view_entity inner COMPOSITE Billing Requested Amt for Billing Elmnt
P_PrjBlgElmntEntrMnlSeldToBill view_entity from COMPOSITE PrjBlgElmntEntr manually sel. for Billg
P_ProjBillgReqDetails view_entity from TRANSACTIONAL P view for Proj Billing Request details
P_ProjBillingInProcessDetails view_entity inner TRANSACTIONAL P view for Billing in Process details
P_PROJECTBILLINGREQUESTWF view_entity from COMPOSITE Project Billing Object - WF Leading Object
P_SlsOrdProcFlowPrjBlgReq view_entity from CONSUMPTION Sales Order Process Flow: Project Billing Request
R_ProjectBillingRequestTP view_entity from TRANSACTIONAL Details of Project Billing Request

Fields (15)

KeyField CDS FieldsUsed in Views
KEY ProjectBillingRequest ProjectBillingRequest 6
KEY ProjectBillingRequestUUID ProjectBillingRequestUUID 5
_EnterpriseProject _EnterpriseProject 1
_ProjectBillingRequestItem _ProjectBillingRequestItem 1
_SalesDocument _SalesDocument 1
ProjBillgReqApprovalStatus ProjBillgReqApprovalStatus 3
ProjBillgReqCreatedAtDteTme ProjBillgReqCreatedAtDteTme 2
ProjBillgReqCreatedBy ProjBillgReqCreatedBy 2
ProjBillgReqLastChgdAtDteTme ProjBillgReqLastChgdAtDteTme 2
ProjBillgReqLastChgdBy ProjBillgReqLastChgdBy 2
ProjectBillingCategory ProjectBillingCategory 3
ProjectBillingRequestStatus ProjectBillingRequestStatus 4
ProjectBillingRequestType ProjectBillingRequestType 2
ProjectInternalID ProjectInternalID 3
SalesDocument SalesDocument 4 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Project Billing Request'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataExtraction.enabled: true
@Analytics.dataExtraction.delta.changeDataCapture.automatic: true
@ObjectModel: {
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE, #UI_PROVIDER_PROJECTION_SOURCE ],
    usageType: {
        sizeCategory: #L,
        dataClass:  #TRANSACTIONAL,
        serviceQuality: #A
    },
    representativeKey: 'ProjectBillingRequestUUID'
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name: 'ProjectBillingRequest'

define view entity I_ProjectBillingRequest
  as select from projbillgreq
  association [0..*] to I_ProjectBillingRequestItem    as _ProjectBillingRequestItem    on $projection.ProjectBillingRequestUUID = _ProjectBillingRequestItem.ProjectBillingRequestUUID
  association [0..1] to I_ProjectBillingRequestStatus  as _ProjectBillingRequestStatus  on $projection.ProjectBillingRequestStatus = _ProjectBillingRequestStatus.ProjectBillingRequestStatus
  association [1..*] to I_ProjectBillingReqStatusText  as _ProjectBillingReqStatusText  on $projection.ProjectBillingRequestStatus = _ProjectBillingReqStatusText.ProjectBillingRequestStatus
  association [0..1] to I_ProjBillgReqApprovalStatus   as _ProjBillgReqApprovalStatus   on $projection.ProjBillgReqApprovalStatus = _ProjBillgReqApprovalStatus.ProjBillgReqApprovalStatus
  association [1..*] to I_ProjBillgReqApprvlStatusText as _ProjBillgReqApprvlStatusText on $projection.ProjBillgReqApprovalStatus = _ProjBillgReqApprvlStatusText.ProjBillgReqApprovalStatus
  association [0..1] to I_ProjectBillingCategory       as _ProjectBillingCategory       on $projection.ProjectBillingCategory = _ProjectBillingCategory.ProjectBillingCategory
  association [1..*] to I_ProjectBillingCategoryText   as _ProjectBillingCategoryText   on $projection.ProjectBillingCategory = _ProjectBillingCategoryText.ProjectBillingCategory
  association [0..1] to I_ProjectBillingRequestType    as _ProjectBillingRequestType    on $projection.ProjectBillingRequestType = _ProjectBillingRequestType.ProjectBillingRequestType
  association [1..*] to I_ProjectBillingRequestTypeTxt as _ProjectBillingRequestTypeTxt on $projection.ProjectBillingRequestType = _ProjectBillingRequestTypeTxt.ProjectBillingRequestType
  association [0..1] to I_SalesDocument                as _SalesDocument                on $projection.SalesDocument = _SalesDocument.SalesDocument
  association [1..1] to I_EnterpriseProject            as _EnterpriseProject            on $projection.ProjectInternalID = _EnterpriseProject.ProjectInternalID
//association [1..1] to I_ProjectBasicData             as _ProjectBasicData             on $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID

{ 
  key projectbillingrequestuuid                                   as ProjectBillingRequestUUID,
      projectbillingrequest                                       as ProjectBillingRequest,
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_ProjectBillingRequestStatus',
             element: 'ProjectBillingRequestStatus' }
      }]
      @ObjectModel.foreignKey.association: '_ProjectBillingRequestStatus'
      projectbillingrequeststatus                                 as ProjectBillingRequestStatus,
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_ProjBillgReqApprovalStatus',
             element: 'ProjBillgReqApprovalStatus' }
      }]
      @ObjectModel.foreignKey.association: '_ProjBillgReqApprovalStatus'
      projbillgreqapprovalstatus                                  as ProjBillgReqApprovalStatus,
      @Consumption.valueHelpDefinition: [
       { entity:  { name:    'I_ProjectBillingRequestType',
                   element: 'ProjectBillingRequestType' }
      }]
      @ObjectModel.foreignKey.association: '_ProjectBillingRequestType'
      projectbillingrequesttype                                   as ProjectBillingRequestType,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesDocumentStdVH',
                     element: 'SalesDocument' }
        }]
      @ObjectModel.foreignKey.association: '_SalesDocument'
      salesdocument                                               as SalesDocument,
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_ProjectBillingCategory',
                   element: 'ProjectBillingCategory' }
      }]
      @ObjectModel.foreignKey.association: '_ProjectBillingCategory'
      projectbillingcategory                                      as ProjectBillingCategory,
      @Semantics.user.lastChangedBy: true
      projbillgreqlastchgdby                                      as ProjBillgReqLastChgdBy,
      @Semantics.systemDateTime.lastChangedAt: true
      projbillgreqlastchgdatdtetme                                as ProjBillgReqLastChgdAtDteTme,
      @Semantics.user.createdBy: true
      projbillgreqcreatedby                                       as ProjBillgReqCreatedBy,
      @Semantics.systemDateTime.createdAt: true
      projbillgreqcreatedatdtetme                                 as ProjBillgReqCreatedAtDteTme,
      projectinternalid                                           as ProjectInternalID,
//    projectbasicdata                                            as ProjectBasicData,

      _EnterpriseProject,
      
      _ProjectBillingRequestItem,
      _ProjectBillingRequestType,
      _ProjectBillingRequestStatus,
      _ProjBillgReqApprovalStatus,
      _SalesDocument,
      _ProjectBillingCategory,
      @Consumption.hidden: true
      _ProjectBillingReqStatusText,
      @Consumption.hidden: true
      _ProjBillgReqApprvlStatusText,
      @Consumption.hidden: true
      _ProjectBillingCategoryText,
      @Consumption.hidden: true
      _ProjectBillingRequestTypeTxt
//      _ProjectInternalID,

//     @Consumption.hidden: true

//      _ProjectInternalID._ProjectShortText.LanguageBasedShortText as ProjectInternalIDText,

//      _ProjectBasicData

      
}

Learn More