I_PMNOTIFICATIONTYPE

CDS View

Maintenance Notification Types

I_PMNOTIFICATIONTYPE is a CDS View in S/4HANA. Maintenance Notification Types. It contains 7 fields. 10 CDS views read from this table.

Used by 10 CDS view(s) 7 fields

CDS Views using this table (10)

ViewTypeJoinVDMDescription
C_MaintNotificationTypeVH view_entity from CONSUMPTION Maintenance Notification Type Value Help
C_MaintNotifOrdTypeAssgdObjPg view_entity from CONSUMPTION Assignment of Order Type to Notification Type
C_MaintNotifPriorityVH view_entity inner CONSUMPTION Maintenance Notification Priority values
C_MaintWorkRequestPriority view_entity from CONSUMPTION Consumption View for Maintenance Work Request Priority
C_Malfunctionreporttype view_entity from CONSUMPTION Malfunction Report Types
C_PMNotificationType view_entity from CONSUMPTION Notification Type
C_ProjectClaimTypeValueHelp view from CONSUMPTION Project Claim Type
I_MaintenanceNotificationType view_entity from BASIC Maintenance Notification Types
I_MaintEvtPrioznProfileMapAll view_entity inner COMPOSITE Prioritization Profile of a Maint Event
I_PMNotificationTypeStdVH view_entity from COMPOSITE Notification Type

Fields (7)

KeyField CDS FieldsUsed in Views
KEY NotificationType NotificationType 6
_Text _Text 2
IsExternalNumberRange IsExternalNumberRange 1
MaintPriorityType MaintPriorityType 3
NotifiedUserCanBeDeleted NotifiedUserCanBeDeleted 1
UserCanBeNotified UserCanBeNotified 1
UserMustBeNotified UserMustBeNotified 1 
@AbapCatalog: { compiler.compareFilter: true, sqlViewName: 'IPMNOTIFTYPE', preserveKey }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Notification Types'
@Analytics: { dataExtraction : { enabled: true , delta.changeDataCapture.automatic: true } }

@VDM.viewType: #BASIC

@ObjectModel: {
  representativeKey: 'NotificationType',
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S },
    supportedCapabilities: [#EXTRACTION_DATA_SOURCE,#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET] }

@Metadata: { allowExtensions, ignorePropagatedAnnotations }
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

@ObjectModel.sapObjectNodeType.name:'MaintenanceNotificationType'
define view I_PMNotificationType
  as select from tq80
  association [0..*] to I_PMNotificationTypeText as _Text                 on  _Text.NotificationType = $projection.NotificationType
  association [0..1] to tpaer                    as _PartnerRoles         on  _PartnerRoles.pargr = tq80.pargr
                                                                          and _PartnerRoles.parvw = 'IT'
  association [0..1] to nriv                     as _NumberRangeIntervals on  _NumberRangeIntervals.nrrangenr = $projection.NumberRange
                                                                          and _NumberRangeIntervals.object    = 'QMEL_NR'
                                                                          and _NumberRangeIntervals.subobject = ''
                                                                          and _NumberRangeIntervals.toyear    = '0000'
{

      @ObjectModel.text.association: '_Text'
  key qmart                               as NotificationType,

      // @ObjectModel.foreignKey.association: '_NumberRangeIntervals'

      tq80.qmnuk                          as NumberRange,

      herkz                               as NotificationOrigin,

      _NumberRangeIntervals.externind     as IsExternalNumberRange,

      artpr                               as MaintPriorityType,

      qmtyp                               as NotificationCategory,

      qmltxt02                            as LongTextIsNotChangeable,

      case when _PartnerRoles.parvw is not null then 'X'
      else '' end                         as UserCanBeNotified,


      case when  _PartnerRoles.papfl = 'X' then 'X'
      else '' end                         as UserMustBeNotified,

      case when  _PartnerRoles.aendb = 'X' then ''
      else 'X' end                        as NotifiedUserCanBeDeleted,

      tq80.reqmaintapp_use                as IsNotificationCreationType,

      tq80.rbnr                           as CatalogProfile,

      // Default catalogs for respective Notification Type

      tq80.otkat                          as MaintNotifObjPrtCodeCatalog,
      tq80.fekat                          as MaintNotifDamageCodeCatalog,
      tq80.urkat                          as MaintNotifCauseCodeCatalog,
      tq80.makat                          as MaintNotifTaskCodeCatalog,
      tq80.mfkat                          as MaintNotifActivityCodeCatalog,

      tq80.parvw_vera                     as MaintNotifRespPartnerFunction,

      tq80.auart                          as MaintenanceOrderType,
      tq80.sakat                          as MaintNotifCodgCatalogTypeCode,
      tq80.maintnotiftypehasactvphsemodel as MaintNotifTypeHasActvPhseModel,
      // Propagate association

      _Text
}

Learn More