I_ORDERSEQUENCEBYSEMKEY

CDS View

Order Sequence by Semantic Key

I_ORDERSEQUENCEBYSEMKEY is a CDS View in S/4HANA. Order Sequence by Semantic Key. It contains 24 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 24 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_ManufacturingOrderSequence view from COMPOSITE Manufacturing Order Sequence
I_ProductionOrderSequence view_entity from COMPOSITE Production Order Sequence

Fields (24)

KeyField CDS FieldsUsed in Views
_BillOfOperationsGroup _BillOfOperationsGroup 2
_BillOfOperationsType _BillOfOperationsType 2
_BillOfOperationsUnit _BillOfOperationsUnit 2
_Language _Language 2
_LongText _LongText 1
_OrderInternalID _OrderInternalID 2
_OrderSequence _SequenceInternalID 2
_Plant _Plant 2
_SequenceCategory _SequenceCategory 2
_SequenceSchedulingAlignment _SequenceSchedulingAlignment 2
BillOfOperations BillOfOperationsVariant 2
BillOfOperationsGroup BillOfOperationsGroup 2
BillOfOperationsType BillOfOperationsType 2
BillOfOperationsUnit BillOfOperationsUnit 2
MaximumLotSizeQuantity MaximumLotSizeQuantity 2
MinimumLotSizeQuantity MinimumLotSizeQuantity 2
ObjectInternalID ObjectInternalID 2
OrderInternalID OrderInternalID 2
ProductionPlant ProductionPlant 2
ReferenceSequence BillOfOperationsSequence,ReferenceSequence 2
SequenceCategory MfgOrderSequenceCategory,SequenceCategory 2
SequenceHasLongText MfgOrderSequenceHasLongText,SequenceHasLongText 2
SequenceInternalID SequenceInternalID 2
SequenceSchedulingAlignment SequenceSchedulingAlignment 2 
@AbapCatalog.sqlViewName: 'IORDSEQBYSEMKEY'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_ProductionSupervisor', '_StatusObject', '_LongText']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'Sequence'
@ObjectModel.semanticKey: ['OrderID', 'Sequence']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Sequence by Semantic Key'
// Basic view on Sequences using semantic key without determining branch and return operations


/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_OrderSequenceBySemKey
  as select from I_OrderSequence as affl

  association [1..1] to I_OrderSequence as _OrderSequence on  $projection.OrderInternalID    = _OrderSequence.OrderInternalID
                                                          and $projection.SequenceInternalID = _OrderSequence.SequenceInternalID
  {
      // Semantic key

      @ObjectModel.foreignKey.association: '_Order'
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
  key affl.OrderID,
      @ObjectModel.text.element: ['SequenceText']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key affl.Sequence,

      // Technical Key (by internal ID)

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      affl.OrderInternalID,
      @ObjectModel.foreignKey.association: '_OrderSequence' 
      affl.SequenceInternalID,

      // Short Text

      @Semantics.text: true
      affl.SequenceText,
      affl.SequenceHasLongText,
      @ObjectModel.foreignKey.association: '_Language'
      affl.Language,

      // Assignments

      @ObjectModel.foreignKey.association: '_OrderCategory'
      affl.OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      affl.OrderType,
      @ObjectModel.foreignKey.association: '_SequenceCategory'
      affl.SequenceCategory,
      @ObjectModel.foreignKey.association: '_Plant'
      affl.ProductionPlant,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      affl.ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      affl.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      affl.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperationsVariant'
      affl.BillOfOperationsVariant as BillOfOperations,
      @ObjectModel.foreignKey.association: '_SequenceSchedulingAlignment'   
      affl.SequenceSchedulingAlignment,
      @ObjectModel.foreignKey.association: '_ReferenceSequence'     
      affl.ReferenceSequence,
      @ObjectModel.foreignKey.association: '_StatusObject'
      affl.ObjectInternalID,
      affl.BranchOperationInternalID,
      affl.ReturnOperationInternalID,

      // Quantities and UoM

      @ObjectModel.foreignKey.association: '_BillOfOperationsUnit'
      @Semantics.unitOfMeasure: true
      affl.BillOfOperationsUnit,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @Aggregation.default: #SUM
      affl.MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @Aggregation.default: #SUM
      affl.MaximumLotSizeQuantity,

      // Associations

      _OrderSequence,
      affl._Order,
      affl._OrderCategory,
      affl._OrderType,
      affl._SequenceCategory,
      affl._SequenceSchedulingAlignment,
      affl._ReferenceSequence,
      affl._OrderInternalID,
      affl._Plant,
      affl._ProductionSupervisor,
      affl._BillOfOperationsType,
      affl._BillOfOperationsGroup,
      affl._BillOfOperationsVariant,
      affl._BillOfOperationsUnit,
      affl._StatusObject,
      affl._LongText,
      affl._Language
  };

Learn More