I_OPERATIONACTIVITYTEXT

CDS View

Operation Activity Text

I_OPERATIONACTIVITYTEXT is a CDS View in S/4HANA. Operation Activity Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ProdnModOperationActivity view_entity inner COMPOSITE Production Model Operation Activity 
@AbapCatalog.sqlViewName: 'IMPEOATEXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  serviceQuality: #A,
  sizeCategory:   #M,
  dataClass:      #META
}
@ObjectModel: {
  dataCategory:      #TEXT,
  semanticKey:       ['OperationActivity','OperationActyVersionCounter'],
  representativeKey: 'OperationActyVersionCounter'
}
@EndUserText.label: 'Operation Activity Text'
define view I_OperationActivityText
  as select from mpe_oa_t as OperationActivityText

  -- Operation Activity Internal Id
  association [1..1] to I_OperationActivityInternalID as _OperationActivityInternalId on  $projection.OperationActivity = _OperationActivityInternalId.OperationActivity

  -- Operation Activity
  association [1..1] to I_OperationActivity           as _OperationActivity           on  $projection.OperationActivity           = _OperationActivity.OperationActivity
                                                                                      and $projection.OperationActyVersionCounter = _OperationActivity.OperationActyVersionCounter
  -- Language
  association [0..1] to I_Language                    as _Language                    on  $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_OperationActivityInternalId'
  key OperationActivityText.id                      as OperationActivity,

      @ObjectModel.foreignKey.association: '_OperationActivity'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_OperationActivityStdVH', element: 'OperationActyVersionCounter' } } ] 
  key OperationActivityText.version_no              as OperationActyVersionCounter,
  
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key OperationActivityText.spras                   as Language,

      @Semantics.text: true
      OperationActivityText.text                    as OperationActivityName,

      @Semantics.user.createdBy: true
      OperationActivityText.created_by              as CreatedByUser,

      // @Semantics.systemDateTime.createdAt: true

      OperationActivityText.created_at              as CreationDateTime,

      @Semantics.user.lastChangedBy: true
      OperationActivityText.changed_by              as ChangedBy,

      // @Semantics.systemDateTime.lastChangedAt: true

      OperationActivityText.changed_at              as LastChangeDateTime,

      -- Associations
      _OperationActivityInternalId,
      _Language,
      _OperationActivity
      
}

Learn More